Topic: How to find out where Acad reads font files from?

[T.Willey]

I want to be able to populate a list box in a dcl with all the font's that show up when a user is in the styles command.  I'm trying to improve one of my routines that I just did to merge text styles.  I want to be able to create text styles from the dialog, but I don't see where one can find out where Acad reads it's font files from.

One thought was looking at all paths within the preferences, and searching for anything that has the extension of a font file, but I don't see how it knows where to find the true type (window) fonts.

Thanks in advance.

[Guest]

C:\Windows\Fonts is the only location a TTF can be installed as far as I know.

[T.Willey]

C:\Windows\Fonts is the only location a TTF can be installed as far as I know.

Thanks Matt.  Didn't know that.

[Guest]

You're welcome!

[CaddmannQ]

This is because C:/windows/fonts is not a folder. It's a program that just looks like a folder. It serves the fonts up to the O/S when they're called for without the fonts having to reside in memory. (I believe. Windows gurus please correct me if I'm wrong here)

To see this just copy a true type font from Fonts to any other location, and the name will change. What you now see is the true file name. What you see in the Fonts folder is what the font tells the program to display as the name.

Outside of the Fonts folder it cannot do so.

For instance the font Impress BT will display the actual name TT0209M_.TTF once you copy it out of the Fonts folder.

[Kerry]

Tim, Does the Fonts Folder in the Acad folder help ?

Personally, I cheat ...

[CaddmannQ]

AFAICT it's got to be in the Windows fonts folder. Putting it in the Autocad fonts folder won't do it.

[MP]

If I pretend to know what you're looking for perhaps this --

Code: [Select]

(defun _GetSpecialFolder ( name / wshShell specialFolders result )
   
    (vl-catch-all-apply
       '(lambda (  )
            (setq
                wshShell       (vlax-create-object "WScript.Shell")
                specialFolders (vlax-get wshShell 'SpecialFolders)
                result         (vlax-invoke specialFolders 'Item name)
            )             
        )
    )

    (if specialFolders (vlax-release-object specialFolders))
    (if wshShell (vlax-release-object wshShell))
   
    result

)
(_GetSpecialFolder "fonts")

=> "C:\\Windows\\Fonts"

Is that what you're looking for Tim?

[MP]

In case anyone is curious about other 'special folders' that are available --

Code: [Select]

(defun _GetSpecialFolders ( / wshShell specialFolders result )
   
    (vl-catch-all-apply
       '(lambda ( )
            (setq
                wshShell       (vlax-create-object "WScript.Shell")
                specialFolders (vlax-get wshShell 'SpecialFolders)
            )
            (setq result
                (mapcar
                   '(lambda ( name )
                        (list
                            name
                            (vlax-invoke specialFolders 'Item name)
                        )                       
                    )
                   '(
                        "AllUsersDesktop"
                        "AllUsersStartMenu"
                        "AllUsersPrograms"
                        "AllUsersStartup"
                        "Desktop"
                        "Favorites"
                        "Fonts"
                        "MyDocuments"
                        "NetHood"
                        "PrintHood"
                        "Programs"
                        "Recent"
                        "SendTo"
                        "StartMenu"
                        "Startup"
                        "Templates"
                    )               
                )
            )             
        )
    )

    (if specialFolders (vlax-release-object specialFolders))
    (if wshShell (vlax-release-object wshShell))
   
    result

)
(GetSpecialFolders) <Vista Ultra> ...

("AllUsersDesktop"   "C:\\Users\\Public\\Desktop")
("AllUsersStartMenu" "C:\\ProgramData\\Microsoft\\Windows\\Start Menu")
("AllUsersPrograms"  "C:\\ProgramData\\Microsoft\\Windows\\Start Menu\\Programs")
("AllUsersStartup"   "C:\\ProgramData\\Microsoft\\Windows\\Start Menu\\Programs\\Startup")
("Desktop"           "C:\\Users\\UserName\\Desktop")
("Favorites"         "C:\\Users\\UserName\\Favorites")
("Fonts"             "C:\\Windows\\Fonts")
("MyDocuments"       "C:\\Users\\UserName\\Documents")
("NetHood"           "C:\\Users\\UserName\\AppData\\Roaming\\Microsoft\\Windows\\Network Shortcuts")
("PrintHood"         "C:\\Users\\UserName\\AppData\\Roaming\\Microsoft\\Windows\\Printer Shortcuts")
("Programs"          "C:\\Users\\UserName\\AppData\\Roaming\\Microsoft\\Windows\\Start Menu\\Programs")
("Recent"            "C:\\Users\\UserName\\AppData\\Roaming\\Microsoft\\Windows\\Recent")
("SendTo"            "C:\\Users\\UserName\\AppData\\Roaming\\Microsoft\\Windows\\SendTo")
("StartMenu"         "C:\\Users\\UserName\\AppData\\Roaming\\Microsoft\\Windows\\Start Menu")
("Startup"           "C:\\Users\\UserName\\AppData\\Roaming\\Microsoft\\Windows\\Start Menu\\Programs\\Startup")
("Templates"         "C:\\Users\\UserName\\AppData\\Roaming\\Microsoft\\Windows\\Templates")

If you want additional info ... looky. There are typos on the linked page, can you find them?

/Later dudes.

[T.Willey]

Thanks guys.  I will look into this more on monday when I'm not busy, and have Acad with me.  This is how I did it in my code for now.

Code: [Select]

(foreach path (cons "C:\\Windows\\Fonts" (StrParse (getenv "ACAD") ";"))
 (foreach font (append (vl-directory-files path "*.shx" 1) (vl-directory-files path "**.ttf" 1))
  (if (not (assoc font FontList))
   (setq FontList (cons (cons font path) FontList))
  )
 )
)

I think I like the way Michael did it with the special folder, and looking for the font within them.  I like that way as it is not hard coded anywhere.

Tim, Does the Fonts Folder in the Acad folder help ?

It didn't look like any true type fonts were within those folders.  I could have be wrong.  Maybe on others computers there are in there, but mine didn't seem to have any.

[T.Willey]

Thanks again Michael.  This seems to be the best way to do what I want.

[MP]

My pleasure Tim, thanks.

[CAB]

 There should be a way to retrieve the font name along with the file name like you see when using the file browser & viewing the Font Folder.  Because you cant tell fron the file name the actual Font Name.

[Keith™]

This is because C:/windows/fonts is not a folder. It's a program that just looks like a folder. It serves the fonts up to the O/S when they're called for without the fonts having to reside in memory. (I believe. Windows gurus please correct me if I'm wrong here)

To see this just copy a true type font from Fonts to any other location, and the name will change. What you now see is the true file name. What you see in the Fonts folder is what the font tells the program to display as the name.

Outside of the Fonts folder it cannot do so.

For instance the font Impress BT will display the actual name TT0209M_.TTF once you copy it out of the Fonts folder.

The windows font folder is simply another folder, just like all other folders. The only difference is the context handler is different for that specific folder.

By looking into the directory from the command window you will see the fonts are listed just like any other file. The long names you see are the names defined in the font file as retrieved by the context handler.

Every "special" folder has a context handler and you can remove that context handler if you wish, but it is not advisable as system instability can occur.

[CaddmannQ]

The windows font folder is simply another folder, just like all other folders. The only difference is the context handler is different for that specific folder.

By looking into the directory from the command window you will see the fonts are listed just like any other file. The long names you see are the names defined in the font file as retrieved by the context handler.

Every "special" folder has a context handler and you can remove that context handler if you wish, but it is not advisable as system instability can occur.

OK, that seems a little clearer. So I take it that these "context handlers" are programs called by a folder based on some properties given it? In any event, when you click a typical folder, you are activating the default behavior of Explorer, because it has the "default" context handler assigned to it? When you dump a new TTF into the Fonts folder, it's this context handler that "installs" it as an available font?

[Keith™]

Correct ... if you browse to the Windows\Font folder and set the attributes of desktop.ini to -h -r -s, you will be able to copy it to another location and view the class id of the shell handler. You could then cross reference that in the registry to see what libraries are actually being used to give the folder the functionality you see.

Usually you can set your own context handlers for special folders, but the problem with the fonts folder is that windows allows only 1 to be active at any given time, therefore unless you change the default folder (and cause instability in Windows) you will not be able to create a second font folder, not that you would want to ...

Many folders have context handlers and you can actually create your own special folders if you create the context handler properly.

[CaddmannQ]

... if you browse to the Windows\Font folder and set the attributes of desktop.ini to -h -r -s, you will be able to copy it to another location and view the class id of the shell handler. You could then cross reference that in the registry to see what libraries are actually being used to give the folder the functionality you see....

Errrr... I think I'd rather poke myself with a sharp stick, but thanks anyway. 

[Maverick®]

I think I'd rather poke myself with a sharp stick, but thanks anyway. 

*adjusts scorecard, polishes up the "exit only" sign*

[CaddmannQ]

I think I'd rather poke myself with a sharp stick, but thanks anyway. 

*adjusts scorecard, polishes up the "exit only" sign*

OK, call me dense, but I don't get the implications of that at all. 

[MP]

Kinda back on topic (no flame) ... Tim: If you want the actual font names just iterate the registry and create a reverse index of the keys / data:

HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows NT\CurrentVersion\Fonts

The key is the font name, the data is the font file.

[T.Willey]

Thanks Michael.  Not sure yet if I want to go this route, but it's nice to have the option and knowledge.

[CAB]

Try this:

Code: [Select]

;;  Get the Windows Installed Fonts & the font file name
(defun get-fontList (/ dev reg)
  (if (or
        (setq dev "HKEY_LOCAL_MACHINE\\SOFTWARE\\Microsoft\\Windows\\CurrentVersion\\Fonts"
              reg (vl-registry-descendents dev "*")
        )
        (setq dev "HKEY_LOCAL_MACHINE\\SOFTWARE\\Microsoft\\Windows NT\\CurrentVersion\\Fonts"
              reg (vl-registry-descendents dev "*")
        )
      )
    (mapcar '(lambda(x) (list x (vl-registry-read dev x))) reg)
    )
)

;|  Returns a list
(("Caesar Regular (TrueType)" "C:\\WINDOWS\\Fonts\\caesar.TTF")
  ("Metro Regular (TrueType)" "C:\\WINDOWS\\Fonts\\metro.TTF")
  ("Zurich Extended BT (TrueType)" "C:\\WINDOWS\\Fonts\\ZURCHE.TTF")
  ("Arcitectura (TrueType)" "archtura.ttf")
  ("AMGDT (TrueType)" "AMGDT___.TTF")
  ("AmdtSymbols (TrueType)" "AMDT_Symbols.ttf")
  ("AIGDT (TrueType)" "AIGDT___.TTF")
  ("AcadEref (TrueType)" "AcadEref.ttf")
  ("ISOCTEUR Italic (TrueType)" "isocteui.ttf")
  ("ISOCTEUR (TrueType)" "isocteur.ttf")
  ("ISOCPEUR Italic (TrueType)" "isocpeui.ttf")
  ("ISOCPEUR (TrueType)" "isocpeur.ttf")
  ("Proxy 9 (TrueType)" "mtproxy9.ttf")
  ("Proxy 8 (TrueType)" "mtproxy8.ttf")
  ("Proxy 7 (TrueType)" "mtproxy7.ttf")
  ("Proxy 6 (TrueType)" "mtproxy6.ttf")
  ("Proxy 5 (TrueType)" "mtproxy5.ttf")
  ("Proxy 4 (TrueType)" "mtproxy4.ttf")
  )
  |:
 

[T.Willey]

The problem with going this way Alan is, when you try and set the FontFile property of the newly created style, you have to have the full path of the font.  Notice in some of the fonts listed they don't have the full path.  And you can't use 'findfile' on them.

I guess if they don't have a path, then you can see if they are located within the folder returned by Michael's code.  It's an idea I'm willing to play with, but I don't have time to test today, but should have some tomorrow.

Thanks Alan. 

Quick example.

Command: (findfile "browa.ttf")
nil

Command: (findfile (strcat (_GetSpecialFolder "Fonts") "\\" "Browa.ttf"))
"C:\\WINDOWS\\Fonts\\Browa.ttf"

[CAB]

Exactly!
And a modified version of MP's code: (please forgive the hack)

Code: [Select]

(defun _GetSpecialFolders ( / wshShell specialFolders result )
    (vl-catch-all-apply
       '(lambda ( )
            (setq
                wshShell       (vlax-create-object "WScript.Shell")
                specialFolders (vlax-get wshShell 'SpecialFolders)
            )
            (setq result (vlax-invoke specialFolders 'Item "Fonts"))
        )
    )
    (if specialFolders (vlax-release-object specialFolders))
    (if wshShell (vlax-release-object wshShell))
    result
)

[MP]

Code: [Select]

(defun _GetFontIndex ( / folder header footer result )

    (setq
        folder (_GetSpecialFolder "Fonts")
        header "HKEY_LOCAL_MACHINE\\SOFTWARE\\Microsoft\\"
        footer "\\CurrentVersion\\Fonts"
    )

    (vl-some
       '(lambda ( windows / key names paths )
            (and
                (setq
                    key   (strcat header windows footer)
                    names (vl-registry-descendents key "*")
                )
                (setq paths
                    (mapcar
                       '(lambda ( name / path )
                            (if
                                (eq ""
                                    (vl-filename-directory
                                        (setq path
                                            (vl-registry-read key name)
                                        )
                                    )
                                )
                                (strcat folder "\\" path)
                                path
                            )                           
                        )
                        names
                    )
                )
                (setq result
                    (mapcar 'cons
                        names
                        paths
                    )
                )
            )
        )
       '( "Windows NT" "Windows" )
    )
   
    (vl-sort
        result
       '(lambda ( a b ) (< (car a) (car b)))
    )
   
)
("AIGDT (TrueType)" . "C:\\Windows\\Fonts\\AIGDT___.TTF")
("AMGDT (TrueType)" . "C:\\Windows\\Fonts\\AMGDT___.TTF")
("AcadEref (TrueType)" . "C:\\Windows\\Fonts\\AcadEref.ttf")
...
("MT Extra (TrueType)" . "C:\\Program Files\\Common Files\\Microsoft Shared\\EQUATION\\MTEXTRA.TTF")
...
("Wingdings (TrueType)" . "C:\\Windows\\Fonts\\wingding.ttf")
("Wingdings 2 (TrueType)" . "C:\\Windows\\Fonts\\WINGDNG2.TTF")
("Wingdings 3 (TrueType)" . "C:\\Windows\\Fonts\\WINGDNG3.TTF")

[CaddmannQ]

I think I'd rather poke myself with a sharp stick, but thanks anyway. 

*adjusts scorecard, polishes up the "exit only" sign*

OK, call me dense, but I don't get the implications of that at all. 

...and evidently nobody's going to bother to explain it either.

*sigh*

[Maverick®]

 Believe me.  It's better that way. 

[MP]

...and evidently nobody's going to bother to explain it either.

*sigh*

Dude it's all spelled out pretty clear here.

[CaddmannQ]

Oh, great! Next you'll be telling me the significance of the Time Kube and the Spork. 

[Keith™]

... the Spork. ...

Any self respecting geek will maintain posession of a titanium spork

[MP]

Ha ha! You foon! You fell victim to one of the classic blunders! The most famous is never get involved in a land war in Asia, but only slightly less well-known is ...

[CaddmannQ]

... the Spork. ...

Any self respecting geek will maintain posession of a titanium spork

Yeah, thanks, but sporks are evil. I discovered this when one attacked my giant plush microbe.

[T.Willey]

Ha ha! You foon! You fell victim to one of the classic blunders! The most famous is never get involved in a land war in Asia, but only slightly less well-known is ...

I know where that is from, but I just can't think of the next line right now.  I know kind of what it has to do with, put can't say it exactly.

On track:  Michael I think that code will work for what I want.  I haven't tested it yet, but will soon.  I might change it, so that it will get the fonts in the default Acad folders also.  Thanks.

[MP]

I know where that is from, but I just can't think of the next line right now.

Princess Bride: "... never go in against a Sicilian when death is on the line! Ha ha ha ha ha ha ha! Ha ha ha ha ha ha ha! Ha ha ha ..."

{ plonk }

Michael I think that code will work for what I want.  I haven't tested it yet, but will soon.  I might change it, so that it will get the fonts in the default Acad folders also.  Thanks.

Use / Abuse / Hope it helps / My pleasure.

[David Hall]

C:\Windows\Fonts is the only location a TTF can be installed as far as I know.

I have TTF fonts in my Autocad\fonts folder

[CaddmannQ]

C:\Windows\Fonts is the only location a TTF can be installed as far as I know.

I have TTF fonts in my Autocad\fonts folder

You can put them there, but they won't work unless they are in the Windows Font folder as well.