Topic: "Enhanced" Fillet

[Guest]

A while back there was a LSP (I think it was called something along the lines of 'enhanced fillet') that would allow you to fillet two lines like in the attached picture.  Does anyone have a copy of that floating around they could post?

Thanks in advance!

[Maverick®]

  Like a "Curved Fillet?"

[Guest]

Yeah, I think so....but I don't see how SoftPlan is going to help me. 

[Maverick®]

Just checking.

[LE]

A while back there was a LSP (I think it was called something along the lines of 'enhanced fillet') that would allow you to fillet two lines like in the attached picture.  Does anyone have a copy of that floating around they could post?

Thanks in advance!

Matt;

I remember seeing that routine and I think I wrote something similar, but cannot find it in here....

For now, maybe you can set the option in the fillet command to No Trim, and select your fillet radius and just trim the portion(s) you don't want....

[Adesu]

Hi Matt,
test this code

Code: [Select]

(defun c:test (/ ep pt1 pt2 rad sp ss1 ss2 sse ssx)
  (setq ss1 (entsel "\nSelect a line vertical"))
  (setq pt1 (cadr ss1))
  (setq ss2 (entsel "\nSelect a line horizontal"))
  (setq pt2 (cadr ss2))
  (setq ssx (car ss2))
  (setq sse (entget ssx))
  (setq sp (cdr (assoc 10 sse)))
  (setq ep (cdr (assoc 11 sse)))
  (if
    (and pt1 pt2)
    (progn
      (setq rad 2)
      (command "_fillet" "r" rad "_fillet" pt1 pt2)
      (command "_erase" ssx "")
      ) ; progn
    )   ; if
  (command "_line" sp ep "")
  (princ)
  )


[Guest]

Thanks, I'll take a look.

[t-bear]

I can see this as a handy little routine with some polishing.  It needs to allow for input of a radius and then return to the old radius when the proggy ends.  Unfortunatly, I'm no coder....just an interested observer.  Let me know what you end up with Matt............ :whistle:

[CAB]

Here is a start, quick and dirty.

Code: [Select]

(defun c:efillet (/ e1 e2 elst rad)
  (if
    (and
      (or (not (zerop (getvar "filletrad")))
           (prompt "\nRadius must be > 0."))
      (setq e1 (entsel "\nSelect line to fillet"))
      (setq e2 (entsel "\nSelect line to keep"))
      (setq elst (entget (car e2)))
      (not (command "_fillet" e1 e2))
      (equal (assoc 0 (entget (entlast))) '(0 . "ARC"))
    )
     (entmod elst)
  )
  (princ)
)
<edit: added error message>

[A_LOTA_NOTA]

Made a few changes.... still needs work!

Code: [Select]

(defun c:efillet (/ e1 e2 elst OldRad Entz)
  (if (not (zerop (getvar "filletrad")))
    (progn
      (while (not e1)
(initget 1 "Radius")
(setq e1 (entsel "Select first object or [Radius]:"))
(if (or (= e1 "Radius") (= e1 "R"))
  (progn
    (setq OldRad (rtos (getvar "filletrad")))
    (setq NewRad (getreal (strcat "\nSpecify fillet radius < " OldRad " > : ")))
    (if (/= NewRad nil)
      (setvar "filletrad" NewRad)
      )
    (setq e1 nil)
    )
  )
)
      (setq Entz (car e1))
      (redraw Entz 3)
      (while (not e2)
(setq e2 (entsel "\nSelect line to keep"))
)
      (setq elst (entget (car e2)))
      (not (command "_fillet" e1 e2))
      (equal (assoc 0 (entget (entlast))) '(0 . "ARC"))
      (entmod elst)
      )
    (progn
      (prompt "\nRadius must be > 0.")
      )
    )
  (princ)
  )

[CAB]

Welcome to TheSwamp.

[A_LOTA_NOTA]

Thanks! Hope you don't mind me adding to your code! I'm learning & figured I could post some code & someone would tell me the correct way to program!

[CAB]

That's what we are here for.

Here is another version.

Code: [Select]

;;  CAB 07.09.07
(defun c:efillet1 (/ e1 e2 elst rad)
  (defun set_radius (/ NewRad)
    (if
      (and
        (not (initget 6))
        (setq NewRad (getdist (strcat "\nSpecify fillet radius < "
                                      (rtos (getvar "filletrad"))
                                      " > : ")))
      )
       (setvar "filletrad" NewRad)
    )
    nil
  )

  (if (zerop (getvar "filletrad"))
    (set_radius)
  )

  (while
    (progn
      (initget "Radius")
      (setq e1 (entsel "\nSelect line to fillet or [Radius]:"))
      (if (= e1 "Radius")
        (set_radius)
      )
      (/= (type e1) 'list)
    )
  )
  (while (not (setq e2 (entsel "\nSelect line to keep"))))
  (setq elst (entget (car e2)))
  (command "_fillet" e1 e2)
  (if (> (getvar "CMDACTIVE") 0)
    (progn
      (command)
      (princ "\nCannot fillet between these two entities.")
    )
    (if (equal (assoc 0 (entget (entlast))) '(0 . "ARC"))
      (entmod elst)
    )
  )
  (princ)
)
<edit: changed initget from 7 to 6>

[A_LOTA_NOTA]

I like this one! But if I pick the "Radius" option then don't want to change it so I just press "enter" it doesn't like it!

[CAB]

Oops
I fixed it in the code above by changing initget from 7 to 6.