Topic: WHAT IS THE VARIABLE FOR "DISPLAY LOCKED"

[STEVEDALLAS]

In Autocad 2004, what is the variable for the viewport being "display locked"?
I am trying to write a lisp that toggles it on or off.

[T.Willey]

; IAcadPViewport2: AutoCAD Paperspace Viewport Object
; Property values:
;   Application (RO) = #<VLA-OBJECT IAcadApplication 00c2eb8c>
;   ArcSmoothness = 1000
;   Center = (4.9068 4.28198 0.0)
;   Clipped (RO) = 0
;   CustomScale = 0.531946
;   Direction = (0.0 0.0 1.0)
;   DisplayLocked = -1
<snip>

??

You could use ':vlax-true' or ':vlax-false' to set this also.

[CAB]

I don't think there is a system variable for that.
If you are in paper space & had 5 viewports, how would the variable differentiate between them?

You would have to approach it as Tim has suggested.


Not sure I understood the question though.

[Maverick®]

there is no sysvar for that as far as I know... try to follow up what Tim recommended. have fun

This post was quoted from the OP in 1 pt. font which I quoted so that the people who are reading this thread would be able to see it.  The post that I quoted was later deleted by the OP.  That is all. Go on about your business. Nothing to see here.....

[STEVEDALLAS]

OK, Here is my explanation.
We have a guy here that creates his viewports, locks the layer, then under properties selects "displaylocked yes".

So, If I need to do anything with it. I need to unlock and thaw the viewport layer, then select it, hit properties, scroll down to display locked, change that to "no".

Then fix it back when done.
The layer locking and thawing is no problem.
The layer lock takes more time than I wish to spend doing it.

Bottom line, That is what I am trying to write a routine to do.

[ronjonp]

Give this a try:

http://www.theswamp.org/index.php?topic=15525.msg188134#msg188134

Ron

[T.Willey]

This is how I would do it.  I would use 'ssget' to select all the viewports active in the layout.  I would gather their layers, while I step through them and unlock them all.  Then I would unlock all the layers that the viewports are on.  You can make a list that will save all the information so that it can be put back after you are done.

[STEVEDALLAS]

These are great, however.
I get ---"Error: Automation Error. On locked layer",   when I try vpunlockall

Question: What is with the color changing?

[ronjonp]

No error checking for locked layers......the color changing is just for visual aid to see if the viewport is locked or unlocked. This can be taken out fairly easy.

Ron

[STEVEDALLAS]

How do I get rid of the automation error?

[STEVEDALLAS]

ok, That is strange.
The routine by CAB now started working fine, no error.

THANKS EVERYONE!

[ronjonp]

FWIW,

This should fix the locked layer error:

Code: [Select]

(defun unlock_all_layers (/)
  (vlax-map-collection
    (vla-get-layers
      (vla-get-activedocument (vlax-get-acad-object))
    )
    '(lambda (x)
       (cond ((eq (vla-get-lock x) :vlax-true)
      (setq lock (cons x lock))
      (vla-put-lock x :vlax-false)
     )
       )
     )
  )
 (princ)
)
(defun restore_locked_layers (/)
  (if lock
    (mapcar '(lambda (x)
       (vla-put-lock x :vlax-true)
     )
    lock
    )
  )
  (setq lock nil)
  (princ)
)
(defun c:vplockall (/ X lck prmpt ent clr clr2 obj)
  (vl-load-com)
  (unlock_all_layers)
  (initget 0 "Lock Unlock")
  (if (not *default*)
    (setq *default* "Lock")
  )
  (setq
    X (cond
((getkword
   (strcat
     "\n (L)ock or (U)nlock all viewports?  <<Hit Enter for "
     *default*
     ">>: "
   )
)
)
(*default*)
      )
  )
  (setq *default* X)
  (cond ((= X "Lock")
(setq lck   :vlax-true
       prmpt "locked..."
       clr   5
       clr2  acBlue
)
)
((= X "Unlock")
(setq lck   :vlax-false
       prmpt "unlocked..."
       clr   1
       clr2  acRed
)
)
  )
  (vlax-for lay (vla-get-layouts
  (vla-get-activedocument
    (vlax-get-acad-object)
  )
)
    (if (eq :vlax-false (vla-get-modeltype lay))
      (vlax-for ent (vla-get-block lay)
(if (= (vla-get-objectname ent) "AcDbViewport")
  (progn
    (vla-put-displaylocked ent lck)
    (vla-put-color ent clr)
    (if (setq
  obj (assoc 340 (entget (vlax-vla-object->ename ent)))
)
      (vla-put-color (vlax-ename->vla-object (cdr obj)) clr2)
    )
  )
)
      )
    )
  )
  (restore_locked_layers)
  (princ (strcat "\n All viewports have been " prmpt))
  (princ)
)

[STEVEDALLAS]

That did it.
Thanks again.