Topic: Please check your brain at the door

[David Hall]

Im having a huge brain fart today.  We had a fatality at work today, and I cant seem to make my brain think about code.  If Im using Utility.GetPoint, how do I use a While or DoWhile to continue picking points til nil?

Code: [Select]

Private Sub cmdLayoutLines_Click()
      Me.Hide
      Dim intBusSpacing As Integer, strLayer As AcadLayer, objLine As AcadLine
      Set strLayer = ThisDrawing.Layers.Add("3d-Layout-Lines")
      strLayer.color = 173
      ThisDrawing.ActiveLayer = strLayer
      With ThisDrawing.Utility
            Dim pt1 As Variant, pt2 As Variant
            pt1 = .GetPoint(, "Pick Starting Point: ")
            pt2 = .GetPoint(pt1, "Pick Next Point: ")
            ThisDrawing.ModelSpace.AddLine pt1, pt2
            While pt2 <> Empty
                  pt1 = pt2
                  pt2 = .GetPoint(pt1, "Pick Next Point: ")
                  ThisDrawing.ModelSpace.AddLine pt1, pt2
            Wend
      End With
      Me.Show
End Subthis is not working

[David Hall]

For some strange reason, after the first line is drawn, Intellisense tells me pt2=Empty, thus the check

[David Hall]

ok, Im making progress

Code: [Select]

Private Sub cmdLayoutLines_Click()
      Me.Hide
      Dim intBusSpacing As Integer, strLayer As AcadLayer, objLine As AcadLine
      Set strLayer = ThisDrawing.Layers.Add("3d-Layout-Lines")
      strLayer.color = 173
      ThisDrawing.ActiveLayer = strLayer
      With ThisDrawing.Utility
            Dim pt1 As Variant, pt2 As Variant
            pt1 = .GetPoint(, "Pick Starting Point: ")
            pt2 = .GetPoint(pt1, "Pick Next Point: ")
            ThisDrawing.ModelSpace.AddLine pt1, pt2
            While Not pt2(0)
                  pt1 = pt2
                  pt2 = .GetPoint(pt1, "Pick Next Point: ")
                  ThisDrawing.ModelSpace.AddLine pt1, pt2
            Wend
      End With
      Me.Show
End SubNow it keeps picking points, but crashes on Enter key

[Guest]

Im having a huge brain fart today.  We had a fatality at work today, and I cant seem to make my brain think about code.  If Im using Utility.GetPoint, how do I use a While or DoWhile to continue picking points til nil?

Whoa! Whoa! Whoa!  Back up.... a FATALITY??!?    Wha....??

Here's what I came up with..

Code: [Select]

Private Sub cmdLayoutLines_Click()
    Me.Hide
    Dim intBusSpacing As Integer, strLayer As AcadLayer, objLine As AcadLine
    Set strLayer = ThisDrawing.Layers.Add("3d-Layout-Lines")
    strLayer.color = 173
    ThisDrawing.ActiveLayer = strLayer
   
    On Error Resume Next
    Do
        With ThisDrawing.Utility
            Dim pt1 As Variant, pt2 As Variant
            pt1 = .GetPoint(, "Pick Starting Point: ")
            pt2 = .GetPoint(pt1, "Pick Next Point: ")
            ThisDrawing.ModelSpace.AddLine pt1, pt2
            While Not pt2(0)
                pt1 = pt2
                If Err.Number <> 0 Then
                    Exit Do
                Else
                    pt2 = .GetPoint(pt1, "Pick Next Point: ")
                    ThisDrawing.ModelSpace.AddLine pt1, pt2
                End If
            Wend
        End With
    Loop
    Me.Show
End Sub

[David Hall]

thanks Matt, I'll give that a spin

[Bryco]

This is a way without On error resume next.
(I use Randall's autoerrorhandler function so it's quick.

Code - Visual Basic: [Select]

1. Sub Lines()
2.     Dim Pt1, Pt2
3.     Dim Util As AcadUtility
4.     On Error GoTo Err_Control
5.     Set Util = ThisDrawing.Utility
6.    
7.     With Util
8.         Pt1 = .GetPoint(, "Pick Starting Point: ")
9.         Do
10.             Pt2 = .GetPoint(Pt1, "Pick Next Point: ")
11.             ThisDrawing.ModelSpace.AddLine Pt1, Pt2
12.             Pt1 = Pt2
13.         Loop
14.     End With
15.  
16. Exit_Here:
17.     Exit Sub
18. Err_Control:
19.     Select Case Err.Number
20.         Case -2147352567, -2145320928
21.         'Method 'GetPoint' of object 'IAcadUtility2' failed
22.        'User input is a keyword
23.            Err.Clear
24.             Resume Exit_Here
25.         Case Else
26.             MsgBox Err.Description
27.             Err.Clear
28.             Resume Exit_Here
29.     End Select
30. End Sub

kdub->formatting code=vb

[Fatty]

Bryco,

Ya da man!
I've got an enjoy with your code
Regards,

Oleg