Topic: Trim Fence

[Biscuits]

Anyone got any ideas how to change this mini-routine so that the fence line is not limited to a specific number of pics?
I've been able to do this but only if I remove the "(COMMAND "OSMODE" "47")"


Thanks

(defun c:TRIMFNC ()

(COMMAND "OSMODE" "0")
(COMMAND "trim" "" "F" PAUSE PAUSE  "" "")
(COMMAND "OSMODE" "47")

)

[David Hall]

Off the top of my head, I would say you need to collect points til nil, then feed the trim command points

[Kerry]

Try

Code: [Select]

(COMMAND "trim" "" "F")
(WHILE (/= (GETVAR "cmdactive") 0) (COMMAND PAUSE))

[Biscuits]

Thanks Kerry, worked perfect!

[CAB]

Here is one I use a lot. It allows multiple trim objects with a 2 point fence.

Code: [Select]

(defun c:tmm (/ ss pt1 pt2 usercmd *error*)
  ;vvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvv
  ;; error function & Routine Exit
  (defun *error* (msg)
    (if
      (not
        (member
          msg
          '("console break" "Function cancelled" "quit / exit abort" "")
        )
      )
       (princ (strcat "\nError: " msg))
    )

    ;;reset all variables here
    (setvar "osmode" useros)
    (setvar "CMDECHO" usercmd)
  ) ; end error function
  ;^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^

  (setq usercmd (getvar "cmdecho"))
  (setvar "cmdecho" 0)
  (setq useros (getvar "osmode"))
  (setvar "osmode" 0)
  (while
    (progn
      (prompt "\nSelect cutting edge(s): ")
      (if (setq ss (ssget))
        (progn
          (command "._undo" "begin")
          (if (and (setq pt1 (getpoint "\nDraw line to select items to be trimmed: "))
                   (listp ptl)
                   (setq pt2 (getpoint pt1 "\nPick end point. "))
                   (listp pt2))
            (not (command "_.trim" ss "" "F" pt1 pt2 "" ""))
          )
        )
      )
    )
  )
  (command "._undo" "end")
  (*error* "")
  (princ)
) ; end defun

(princ "\nType TMM to start.")
(princ)