Author Topic: My first lisp-DCL "help please" (Read 5291 times)

Biscuits · « **on:** February 14, 2007, 02:47:23 PM »

Using Windows XP and ACAD2002 (yes...still).
This is my first attempt at DCL.
The idea is to create isometric mtext with different orientations using a dialogue box.
I tested the lisp by itself and it works great.
I've added the DCL using slide files and it will display fine.

I've managed to cobble this together using several website tutorials and examples.....but

now, I'm lost in making each image activate the corresponding portion of the lisp routine.

Could someone point me in the right direction from here?
Thanks

Quote

; My lisp file

(defun C:samp4 ()

(mode_tile "image_tiles" 4)

;----------------------------------------------------------------------------------------------

(defun c:LeftPlane (/ PT1)
(SETQ PT1 (GETPOINT "\nPick Text Insertion Point: "))
(Command "-Style" "IsoTextL" "Romans" "" "" "-30" "" "" "")
(initdia) (Command "_.MText" PT1 "J" "MC" "W" "0")
(Command "Rotate" "Last" "" PT1 "-30")
(Command "-Style" "STANDARD" "" "" "" "" "" "" "")

)
;----------------------------------------------------------------------------------------------

(defun c:RightPlane (/ PT1)
(SETQ PT1 (GETPOINT "\nPick Text Insertion Point: "))
(Command "-Style" "IsoTextR" "Romans" "" "" "30" "" "" "")
(initdia) (Command "_.MText" PT1 "J" "MC" "W" "0")
(Command "Rotate" "Last" "" PT1 "30")
(Command "-Style" "STANDARD" "" "" "" "" "" "" "")
)

;----------------------------------------------------------------------------------------------

(defun c:TopPlaneLeft (/ PT1)
(SETQ PT1 (GETPOINT "\nPick Text Insertion Point: "))
(Command "-Style" "IsoTextL" "Romans" "" "" "-30" "" "" "")
(initdia) (Command "_.MText" PT1 "J" "MC" "W" "0")
(Command "Rotate" "Last" "" PT1 "30")
(Command "-Style" "STANDARD" "" "" "" "" "" "" "")
)

;;----------------------------------------------------------------------------------------------

(defun c:TopPlaneRight (/ PT1)
(SETQ PT1 (GETPOINT "\nPick Text Insertion Point: "))
(Command "-Style" "IsoTextL" "Romans" "" "" "-30" "" "" "")
(initdia) (Command "_.MText" PT1 "J" "MC" "W" "0")
(Command "Rotate" "Last" "" PT1 "30")
(Command "-Style" "STANDARD" "" "" "" "" "" "" "")
)
;-------------------------------------------------------------------------------------------------------------------------------------------

(setq dcl_id (load_dialog "samp4.dcl"))

(if (not (new_dialog "samp4" dcl_id)
);not

(exit)
);if

(setq w (dimx_tile "im")
h (dimy_tile "im")
)

;-------------------------------------------------------------------------------------------------------------------------------------------
(start_image "im")
(mode_tile "image_tiles" 4)
(fill_image 0 0 w h -1)
(slide_image 0 0 w h "Top_Plane_Left View")
(end_image)
;-------------------------------------------------------------------------------------------------------------------------------------------
(start_image "im1")
(fill_image 0 0 w h -1)
(slide_image 0 0 w h "Top_Plane_Right View")
(end_image)
;-------------------------------------------------------------------------------------------------------------------------------------------
(start_image "im2")
(fill_image 0 0 w h -1)
(slide_image 0 0 w h "LeftPlane")
(end_image)
;-------------------------------------------------------------------------------------------------------------------------------------------
(start_image "im3")
(fill_image 0 0 w h -1)
(slide_image 0 0 w h "RightPlane")
(end_image)
;-------------------------------------------------------------------------------------------------------------------------------------------

; (action_tile "im" "(TopPlaneLeft)")
; (action_tile "im1" "(TopPlaneRight)")
; (action_tile "im2" "(LeftPlane)")
; (action_tile "im3" "(RightPlane)")

(action_tile
"cancel"
"(done_dialog) (setq userclick nil)"
);action_tile

(action_tile
"accept"
" (done_dialog)(setq userclick T))"
);action tile

(start_dialog)

(unload_dialog dcl_id)

(princ)

);defun

(princ)

-------------------------------------------------------------
; My DCL file
-------------------------------------------------------------
samp4 : dialog {
label = "Isometric Text" ;

: row {

: image {
key = "im" ;
height =8.0 ;
width = 30.0 ;
}

: image {
key = "im1" ;
height =8.0 ;
width = 30.0 ;
}
}
: row {
: column {
:text {
key = "text1";
label = "Top Plane - Left View";
width = 30;
fixed_width = true;
alignment = centered;
}
}
: column {
:text {
key = "text2";
label = "Top Plane - Right View";
width = 30;
fixed_width = true;
alignment = centered;

}
}
}

spacer;
spacer;
spacer;

:row {
: image {
key = "im2" ;
height =8.0 ;
width = 30.0 ;
}

: image {
key = "im3" ;
height =8.0 ;
width = 30.0 ;
}
}

: row {
: column {
:text {
key = "text3";
label = "Left Side View";
width = 30;
fixed_width = true;
alignment = centered;
}
}

: column {
:text {
key = "text4";
label = "Right Side View";
width = 30;
fixed_width = true;
alignment = centered;
}
}
}

: row {

ok_cancel ;
}

: row {
: paragraph {

: text_part {
label = "by Yours Truly";
}
}
}
}

T.Willey · « **Reply #1 on:** February 14, 2007, 03:07:09 PM »

How I would do it is, when the image tiles are selected, they each set the same variable, but to different values. Or you could have them just hit the image tile, and then have that end the dialog and run the code from there.

Code: [Select]

(action_tile "im" "(done_dialog 1)")
(action_tile "im1" "(done_dialog 2)")
(action_tile "im2" "(done_dialog 3)")
(action_tile "im3" "(done_dialog 4)")
(action_tile "cancel" "(done_dialog 0)")
(setq DiaResponse (start_dialog))
(unload_dialog dcl_id)
(cond
 ((equal DiaResponse 1)
   (c:TopPlaneLeft)
 )
 ((equal DiaResponse 2)
   (c:RightPlane)
 )
 ((equal DiaResponse 3)
   (c:RightPlane)
 )
 ((equal DiaResponse 4)
   (c:RightPlane)
 )
)

I have never used images in a dcl file, so this is a guess. If you do it this way, then you can remove the Okay button.

Edit: To get this to work you have to change your call to 'image' in the dcl to 'image_button', then selecting them will fire what you want. I just test it and it worked. And I fixed the calls to the functions since they are defined with the 'c:' in front which I didn't add the first time. And fixed a typo.

Biscuits · « **Reply #2 on:** February 14, 2007, 03:49:55 PM »

Thanks "T" got it to work partially.
Should be able to finish it myself.

Thanks for pointing me in the right direction!!

T.Willey · « **Reply #3 on:** February 14, 2007, 03:55:19 PM »

Quote from: Biscuits on February 14, 2007, 03:49:55 PM

Thanks "T" got it to work partially.
Should be able to finish it myself.

Thanks for pointing me in the right direction!!

You're welcome. Let us know if you need anymore help, and be sure to post the finished code so others can learn from it.

efernal · « **Reply #4 on:** February 14, 2007, 04:09:56 PM »

My sugestions bellow...

Code: [Select]

;;  My lisp file
;;  Adjustments by Eduardo Fernal : http://www.gr-acad.com.br
;;  14/02/2007 (or 02/14/2007 in USA)
(DEFUN c:samp4 (/ h w dcl_id flag userclick)
  ;;
  ;; Defined functions...
  (DEFUN c:leftplane (/ pt1)
    (SETQ pt1 (GETPOINT "\nPick Text Insertion Point: "))
    (COMMAND "-Style" "IsoTextL" "Romans" "" "" "-30" "" "" "")
    (INITDIA)
    (COMMAND "_.MText" pt1 "J" "MC" "W" "0")
    (COMMAND "Rotate" "Last" "" pt1 "-30")
    (COMMAND "-Style" "STANDARD" "" "" "" "" "" "" "")
  )
  ;;
  (DEFUN c:rightplane (/ pt1)
    (SETQ pt1 (GETPOINT "\nPick Text Insertion Point: "))
    (COMMAND "-Style" "IsoTextR" "Romans" "" "" "30" "" "" "")
    (INITDIA)
    (COMMAND "_.MText" pt1 "J" "MC" "W" "0")
    (COMMAND "Rotate" "Last" "" pt1 "30")
    (COMMAND "-Style" "STANDARD" "" "" "" "" "" "" "")
  )
  ;;
  (DEFUN c:topplaneleft (/ pt1)
    (SETQ pt1 (GETPOINT "\nPick Text Insertion Point: "))
    (COMMAND "-Style" "IsoTextL" "Romans" "" "" "-30" "" "" "")
    (INITDIA)
    (COMMAND "_.MText" pt1 "J" "MC" "W" "0")
    (COMMAND "Rotate" "Last" "" pt1 "30")
    (COMMAND "-Style" "STANDARD" "" "" "" "" "" "" "")
  )
  ;;
  (DEFUN c:topplaneright (/ pt1)
    (SETQ pt1 (GETPOINT "\nPick Text Insertion Point: "))
    (COMMAND "-Style" "IsoTextL" "Romans" "" "" "-30" "" "" "")
    (INITDIA)
    (COMMAND "_.MText" pt1 "J" "MC" "W" "0")
    (COMMAND "Rotate" "Last" "" pt1 "30")
    (COMMAND "-Style" "STANDARD" "" "" "" "" "" "" "")
  )
  ;;
  ;; ###############################################################
  ;; MAIN ROUTINE...
  ;; See the modifications on the dialog text bellow...
  (IF (> (SETQ dcl_id (LOAD_DIALOG "samp4.dcl"
                        ;|"c:\\listalsp\\myfirstlisp-dcl.dcl"|;
                      )
         )
         0
      )
    (IF (NEW_DIALOG "samp4" dcl_id)
      (PROGN 
             (SETQ w (DIMX_TILE "im")
                   h (DIMY_TILE "im")
             )
             ;;
             ;; make your slides in ms/ps, in a viewport x = w and y = h
             ;; this will fill the image_button correctly...
             (START_IMAGE "im0")             
             (FILL_IMAGE 0 0 w h -1)
             (SLIDE_IMAGE 0 0 w h "Top_Plane_Left View")
             (END_IMAGE)
             ;;
             (START_IMAGE "im1")
             (FILL_IMAGE 0 0 w h -1)
             (SLIDE_IMAGE 0 0 w h "Top_Plane_Right View")
             (END_IMAGE)
             ;;
             (START_IMAGE "im2")
             (FILL_IMAGE 0 0 w h -1)
             (SLIDE_IMAGE 0 0 w h "LeftPlane")
             (END_IMAGE)
             ;;
             (START_IMAGE "im3")
             (FILL_IMAGE 0 0 w h -1)
             (SLIDE_IMAGE 0 0 w h "RightPlane")
             (END_IMAGE)
             ;;
             (ACTION_TILE "im0" "(SETQ flag 1)")
             (ACTION_TILE "im1" "(SETQ flag 2)")
             (ACTION_TILE "im2" "(SETQ flag 3)")
             (ACTION_TILE "im3" "(SETQ flag 4)")
             (ACTION_TILE "cancel" "(DONE_DIALOG)(SETQ userclick nil)")
             (ACTION_TILE "accept" "(DONE_DIALOG)(SETQ userclick 1))")
             (START_DIALOG)
             (UNLOAD_DIALOG dcl_id)
             (IF (AND userclick flag)
               (COND ((= flag 0) (c:top_plane_left))
                     ((= flag 1) (c:top_plane_right))
                     ((= flag 2) (c:leftplane))
                     ((= flag 3) (c:rightplane))
               )
               nil
             )
      )
      nil
    )
    (ALERT "Error:\n\n\tUnable to load dialog file...\n\n\t")
  )
  (PRINC)
)
(PRINC "\n-> Type SAMP4 and press Enter to run...")
(PRINC)

;|
// myfirstlisp-dcl.dcl
samp4
:dialog
	{
		label="Isometric Text";
		width=68;
		fixed_width=true;
	:spacer
		{
			height=1;
		}
	:column
		{
			width=61;
			height=18;
			fixed_width=true;
			fixed_height=true;
			alignment=centered;
		:row
			{
				fixed_width=true;
				fixed_height=true;
			:column
				{
			     	:image_button
			     		{
			     			key="im";
			     			height =8.0;
			     			width=30.0;
			     		}
				:text
					{
			        		key="text1";
			        		label="Top Plane - Left View";
			       			alignment=centered;
					}
			     	}
			:column
				{
				:image_button
			     		{
			     			key="im1";
			     			height =8.0;
			     			width=30.0;
			     		}
			     	:text
			     		{
				        	key="text2";
				        	label="Top Plane - Right View";
				       		alignment=centered;
					}
				}
			}
		:row
			{
			:column
				{
		     		:image_button
		     			{
		     				key="im2";
		     				height =8.0;
		     				width=30.0;
		     			}
		     		:text
		     			{
		        			key="text3";
		        			label="Left Side View";
		       				alignment=centered;
					}
		     		}
			:column
				{     
				:image_button
					{
		     				key="im3";
		     				height =8.0;
		     				width=30.0;
		     			}
		     		:text
		     			{
		        			key="text4";
		        			label="Right Side View";
		       				alignment=centered;
					}
				}
			}
		}
	:spacer
		{
			height=1;
		}
     	ok_cancel;
        :text
		{
			label="by Yours Truly";
		}
	}
	// end of dialog
|;

<edit: code tags added>

CAB · « **Reply #5 on:** February 15, 2007, 09:42:06 AM »

efernal
Welcome to TheSwamp

CAB · « **Reply #6 on:** February 15, 2007, 09:59:16 AM »

Oops, looks like your flag values don't match, should be this I think.

Code: [Select]

             (ACTION_TILE "im0" "(SETQ flag 1)")
             (ACTION_TILE "im1" "(SETQ flag 2)")
             (ACTION_TILE "im2" "(SETQ flag 3)")
             (ACTION_TILE "im3" "(SETQ flag 4)")
             (ACTION_TILE "cancel" "(DONE_DIALOG)(SETQ userclick nil)")
             (ACTION_TILE "accept" "(DONE_DIALOG)(SETQ userclick 1))")
             (START_DIALOG)
             (UNLOAD_DIALOG dcl_id)
             (IF (AND userclick flag)
               (COND ((= flag [color=red]1[/color]) (c:top_plane_left))
                     ((= flag [color=red]2[/color]) (c:top_plane_right))
                     ((= flag [color=red]3[/color]) (c:leftplane))
                     ((= flag [color=red]4[/color]) (c:rightplane))
               )
               nil
             )

efernal · « **Reply #7 on:** February 15, 2007, 01:26:29 PM »

Sorry for the mistake...
You're correct...
Regards,
e.fernal

Biscuits · « **Reply #8 on:** February 20, 2007, 12:32:27 PM »

Many thanks to you guys for all the help. It's been quite a learning experience getting this one done.

Here is the final product
Now to see if I can attach the image from the printscreen with this code.
Anyone who can use this is welcome to it and modify as you wish.

Quote

;; IsoText lisp file

(DEFUN c:IsoText(/ h w dcl_id flag userclick)
;;
;; Defined functions...
(DEFUN c:leftplane (/ pt1)
(SETQ pt1 (GETPOINT "\nPick Text Insertion Point: "))
(COMMAND "-Style" "IsoTextL" "Romans" "" "" "-30" "" "" "")
(INITDIA)
(COMMAND "_.MText" pt1 "J" "MC" "W" "0")
(COMMAND "Rotate" "Last" "" pt1 "-30")
(COMMAND "-Style" "STANDARD" "" "" "" "" "" "" "")
)
;;
(DEFUN c:rightplane (/ pt1)
(SETQ pt1 (GETPOINT "\nPick Text Insertion Point: "))
(COMMAND "-Style" "IsoTextR" "Romans" "" "" "30" "" "" "")
(INITDIA)
(COMMAND "_.MText" pt1 "J" "MC" "W" "0")
(COMMAND "Rotate" "Last" "" pt1 "30")
(COMMAND "-Style" "STANDARD" "" "" "" "" "" "" "")
)
;;
(DEFUN c:topplaneleft (/ pt1)
(SETQ pt1 (GETPOINT "\nPick Text Insertion Point: "))
(COMMAND "-Style" "IsoTextR" "Romans" "" "" "30" "" "" "")
(INITDIA)
(COMMAND "_.MText" pt1 "J" "MC" "W" "0")
(COMMAND "Rotate" "Last" "" pt1 "-30")
(COMMAND "-Style" "STANDARD" "" "" "" "" "" "" "")
)
;;
(DEFUN c:topplaneright (/ pt1)
(SETQ pt1 (GETPOINT "\nPick Text Insertion Point: "))
(COMMAND "-Style" "IsoTextL" "Romans" "" "" "-30" "" "" "")
(INITDIA)
(COMMAND "_.MText" pt1 "J" "MC" "W" "0")
(COMMAND "Rotate" "Last" "" pt1 "30")
(COMMAND "-Style" "STANDARD" "" "" "" "" "" "" "")
)
;;
;; ###############################################################
;; MAIN ROUTINE...

(IF (> (SETQ dcl_id (LOAD_DIALOG "IsoText.dcl"
;|"c:\\listalsp\\myfirstlisp-dcl.dcl"|;
)
)
0
)
(IF (NEW_DIALOG "IsoText" dcl_id)
(PROGN
(SETQ w (DIMX_TILE "im")
h (DIMY_TILE "im")
)
;;

(START_IMAGE "im")
(FILL_IMAGE 0 0 w h -15)
(SLIDE_IMAGE 0 0 w h "Top_Plane_Left View")
(END_IMAGE)
;;
(START_IMAGE "im1")
(FILL_IMAGE 0 0 w h -15)
(SLIDE_IMAGE 0 0 w h "Top_Plane_Right View")
(END_IMAGE)
;;
(START_IMAGE "im2")
(FILL_IMAGE 0 0 w h -15)
(SLIDE_IMAGE 0 0 w h "LeftPlane")
(END_IMAGE)
;;
(START_IMAGE "im3")
(FILL_IMAGE 0 0 w h -15)
(SLIDE_IMAGE 0 0 w h "RightPlane")
(END_IMAGE)
;;
(START_IMAGE "im4")
(FILL_IMAGE 0 0 w h -15)
(SLIDE_IMAGE 0 0 w h "Lozier")
(END_IMAGE)

(ACTION_TILE "im" "(SETQ flag 1)")
(ACTION_TILE "im1" "(SETQ flag 2)")
(ACTION_TILE "im2" "(SETQ flag 3)")
(ACTION_TILE "im3" "(SETQ flag 4)")
(ACTION_TILE "cancel" "(DONE_DIALOG)(SETQ userclick nil)")
(ACTION_TILE "accept" "(DONE_DIALOG)(SETQ userclick 1))")
(START_DIALOG)
(UNLOAD_DIALOG dcl_id)
(IF (AND userclick flag)
(COND ((= flag 1) (c:topplaneleft))
((= flag 2) (c:topplaneright))
((= flag 3) (c:leftplane))
((= flag 4) (c:rightplane))
)
nil
)
)
nil
)
(ALERT "Error:\n\n\tUnable to load dialog file...\n\n\t")
)
(PRINC)
)
(PRINC "\n-> Type IsoText and press Enter to run...")
(PRINC)

xxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxx

DCL portion

xxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxx

IsoText
:dialog
   {
      label="Isometric Text";
      width=68;
      fixed_width=true;
   :spacer
      {
         height=1;
      }
   :column
      {
         width=61;
         height=18;
         fixed_width=true;
         fixed_height=true;
         alignment=centered;
      :row
         {
            fixed_width=true;
            fixed_height=true;
         :column
            {
               :image_button
                  {
                     key="im";
                     height =8.0;
                     width=30.0;
                  }
            :text
               {
                 key="text1";
                 label="Top Plane - Left View";
                     alignment=centered;
               }
               }
         :column
            {
            :image_button
                  {
                     key="im1";
                     height =8.0;
                     width=30.0;
                  }
               :text
                  {
                 key="text2";
                 label="Top Plane - Right View";
                     alignment=centered;
               }
            }
         }
      :row
         {
         :column
            {
               :image_button
                  {
                     key="im2";
                     height =8.0;
                     width=30.0;
                  }
               :text
                  {
                 key="text3";
                 label="Left Side View";
                     alignment=centered;
               }
               }
         :column
            {
            :image_button
               {
                     key="im3";
                     height =8.0;
                     width=30.0;
                  }
               :text
                  {
                 key="text4";
                 label="Right Side View";
                     alignment=centered;
               }
            }
         }

}


   :spacer
      {
         height=1;
      }
    ok_cancel;

:text
      {
         label="by Biscuits (with a little help from my friends)";
      }
   }
   // end of dialog

T.Willey · « **Reply #9 on:** February 20, 2007, 12:39:40 PM »

Glad you got it working the way you want it to.

You're welcome for whatever I did.

TimSpangler · « **Reply #10 on:** February 21, 2007, 12:44:03 PM »

You could add a sub to show the slide:

;;; ------------ SHOW SLIDE SUB
(defun SHOW_SLIDE ( tile slide / x y)

   (setq x (dimx_tile tile))
   (setq y (dimy_tile tile))
   (start_image tile)
   (fill_image 0 0 x y -15)
   (slide_image 0 0 x y slide)
   (end_image)
)

Then just call them:

(show_slide "im" "Top_Plane_Left View")
(show_slide "im1" "Top_Plane_Right View")
(show_slide "im2" "LeftPlane")
(show_slide "im3" "RightPlane")

Biscuits · « **Reply #11 on:** February 21, 2007, 04:39:45 PM »

Thanks Tim.

I'll give it a shot.

T.Willey · « **Reply #12 on:** February 21, 2007, 05:06:11 PM »

Quote from: Biscuits on February 21, 2007, 04:39:45 PM

Thanks Tim.

I'll give it a shot.

I'm so confused. :ugly: I didn't say anything this time, I swear.

j/k. I know you Tim S.

CAB · « **Reply #13 on:** February 21, 2007, 06:18:56 PM »

Wrong Tim, Tim.

Biscuits · « **Reply #14 on:** February 22, 2007, 09:01:35 AM »

Sum Tim Wong?

ooohhhhhh.............. is beer thirty and I just got to work

News:

Author Topic: My first lisp-DCL "help please" (Read 5291 times)

Biscuits

My first lisp-DCL "help please"

T.Willey

Re: My first lisp-DCL "help please"

Biscuits

Re: My first lisp-DCL "help please"

T.Willey

Re: My first lisp-DCL "help please"

efernal

Re: My first lisp-DCL "help please"

CAB

Re: My first lisp-DCL "help please"

CAB

Re: My first lisp-DCL "help please"

efernal

Re: My first lisp-DCL "help please"

Biscuits

Re: My first lisp-DCL "help please"

T.Willey

Re: My first lisp-DCL "help please"

TimSpangler

Re: My first lisp-DCL "help please"

Biscuits

Re: My first lisp-DCL "help please"

T.Willey

Re: My first lisp-DCL "help please"

CAB

Re: My first lisp-DCL "help please"

Biscuits

Re: My first lisp-DCL "help please"