Topic: Find & Replace Script - Quick Question

[M-dub]

We have about 100 or so drawings that were given temporary drawing numbers like SK-1234-01 while we waited to have proper drawing numbers assigned to us.  We now have those proper drawing numbers and we have to update all of the drawings before they go back to the client.  In order to make sure we cover all of the references to other drawings in addition to what's in the title block, this is what I'm thinking...

Would it be too much to expect from a script to do the following (pseudo script code):

Open SK-1234-01
Do a global find and replace on the text, "SK-1234-01" to "IS-923-01-34" and "SK-1234-02" to "IS-923-01-35" and basically go through the whole list, replacing the sketch number with the proper number (about 100).
SaveAs IS-923-01-34

The bold portion is what I'm wondering about... Although it might take a little while to get through the whole list, would it be too taxing on the PC to do this?  I don't think so, but I thought I'd throw it out there for you folks to see what you think.


(I will also have to do the exact same Find and Replace but removing the hyphens)

[David Hall]

CHText.lsp might do what you want

[David Hall]

you can also make a rename.bat file to rename all your SK dwgs to IS dwgs.  You can make this halfway in about 3 minutes.  If you know what the numbers are going to be, and they are sequential, you might get the whole batch file in under 5 minutes

[M-dub]

CHText.lsp might do what you want

Yeppers! 

That's what I planned on using IN my script.

I may not have explained my issue very well.

I have a list of 100 drawings.  I have to open each drawing and replace 100 strings of text with 100 OTHER strings of text.

Now that I think of it, it sounds pretty simple... should do just fine.  I guess I might start to worry if it were 10 times that amount.

[CAB]

I have a lisp from Will Deloach that does that for all files in a directory using ObjectDBX. (Very Fast)
It would have to be modified to accommodate all the text you want to change as it was set up
to change only one text string. I tried to find the old code in the swamp but have had no luck
linking you to it.

[M-dub]

That sounds good Alan!

Well, on Monday, I'll be spending an hour or so looking into this to decide whether it's worth automating it or whether we should just do it manually.  We'll catch up with this one then.

Thanks! 

[CAB]

Try this out Mike.
It only works in Modelspace in this first test version & only works with mText & plain Text.
I or someone else can add the layouts & attributes if you need them.
I am short of time this morning.

Code: [Select]

;;  TextReplace.lsp
;;  CAB 02/19/07 version 3

;;  Warning: There is no Undo, so back up your work.

;;  ObjectDBX Routine to replace text strings in all drawings in a
;;  selected folder

;;  This is a "Work In Progress"
;;  This is a collection of subroutines from several contributers
;;  at the Swamp & my own brand of tweaking. :) CAB

(defun TextReplaceDBX
       (flag textlist / DIRPATH DWGOBJ FULLPATH OBJ ODBX OLDTXT TEXTLIST TXT TXTLST)
  ;;  Add flag values
  ;;  flag 1 = ModelSpace Only
  ;;       2 = PaperSpace Only
  ;;       4 = Reserved
  ;;       8 = Include Attributed Blocks  * Not Operational
  ;;
  ;;  textlist = text to replace ("OldString" "NewString")

  (vl-load-com)
  (setq *acad (vlax-get-acad-object))


;;; -=<*>=- -=<*>=- -=<*>=- -=<*>=- -=<*>=- -=<*>=- -=<*>=- -=<*>=-
;;;                      Local Functions                           
;;; -=<*>=- -=<*>=- -=<*>=- -=<*>=- -=<*>=- -=<*>=- -=<*>=- -=<*>=-
  (defun *error* (msg)
    (if
      (not
        (member
          msg
          '("console break" "Function cancelled" "quit / exit abort" "")
        )
      )
       (princ (strcat "\nError: " msg))
    )
    (if (and odbx (not (vlax-object-released-p odbx)))
      (vlax-release-object odbx)
    )
    (gc)
    (princ)
  )
  ;;end error function

  (defun get_atts (obj / val)
    (if (vl-catch-all-error-p
          (vl-catch-all-apply
            '(lambda ()
               (setq val (vlax-safearray->list
                           (vlax-variant-value (vla-getattributes obj))
                         )
               )
             )
          )
        )
      nil
      val
    )
  )


  (defun ReplaceText (phraselst document / txt oName swaptext ck_for_text)
    (defun swaptext (obj txtlst)
      (setq txt    (vla-get-textstring obj)
            Oldtxt txt
      )
      (mapcar '(lambda (x / tmp)
                 (if (setq tmp (vl-string-subst (cadr x) (car x) txt))
                   (setq txt tmp)
                 )
               )
              phraselst
      )
      (if (/= OldTxt Txt)
        (vla-put-textstring obj txt)
      )
    )

    (defun ck_for_text (obj oType lst)
          (cond ((vl-position oType '("AcDbText" "AcDbMText"))
             (swaptext obj lst)
            )
               
             ;|((and (> (logand flag 8) 0)
                  (eq oType "AcDbBlockReference")
                  (eq (vla-get-hasattributes item) :vlax-true)
             )
             (foreach for-item (get_atts item)
               (swaptext obj lst)
             )
            )|;
      )
    )

    (if (> (logand flag 1) 0)
    ;;  Model Space Only
    (vlax-for item (vla-get-modelspace document)
      (setq oName (vla-get-objectname item))
      (ck_for_text item oName textlist)
    )
    )
    (if (> (logand flag 2) 0)
    ;;  Paper Space Only
    (vlax-for item (vla-get-paperspace document)
      (setq oName (vla-get-objectname item))
      (ck_for_text item oName textlist)
    )
  )
  )



  ;;+++++++++++++++++++++++++++++++++++++++++++++++++++++++++
  ;;        S T A R T   O F   M A I N   R O U T I N E       
  ;;+++++++++++++++++++++++++++++++++++++++++++++++++++++++++
  (if (setq DirPath (getfiled "Browse for folder"
                              "Open a folder and click on SAVE"
                              " "
                              1
                    )
      )
    (setq DirPath (substr DirPath 1 (- (strlen DirPath) 31)))
  )

  (if DirPath
    (progn

     (setq odbx (if (< (setq Vers (substr (getvar "acadver") 1 2)) "16")
                       (vla-GetInterfaceObject (vlax-get-acad-object) "ObjectDBX.AxDbDocument")
                       (vla-GetInterfaceObject (vlax-get-acad-object) (strcat "ObjectDBX.AxDbDocument." Vers))
                     ))     
      (foreach Dwg (vl-directory-files DirPath "*.dwg" 1)
        (setq FullPath (strcat DirPath Dwg))
        (if (vl-catch-all-error-p
                  (vl-catch-all-apply
                                 '(lambda ()
                                    (vlax-invoke-method odbx 'open FullPath)
                                  )
                  )
            )
          (prompt (strcat "\n ++ Couldn't open drawing \"" FullPath "\""))
          (progn
            (prompt (strcat "\n  - Report for - " FullPath))
            ;;  Replace Strings
            (ReplaceText TextList odbx)

            (vla-saveas odbx (vla-get-name odbx))
          )
        )
      )
      (prompt "\n***  REGEN all drawings to display new text properly.  ***")
      (vlax-release-object odbx)
      (setq odbx nil)
    )
  )



  (princ)
)    ;  **  END MAIN PROCEDURE  **
(prompt "\nText Replace Loaded, enter TextReplace to run.")
(princ)


(defun c:TextReplace ()
  ;;  Add flag values
  ;;  flag 1 = ModelSpace Only
  ;;       2 = PaperSpace Only
  ;;       4 = reserved
  ;;       8 = Include Attributed Blocks  * Not Operational
  ;;
  ;;  text to replace ("OldString" "NewString")
  (TextReplaceDBX 3 ; both Model & Paper Space
    '(("OldText" "NewString")
      ("Test 012807.1" "NewString")
     )
  )
  (princ)
)

[M-dub]

Awesome!  Thanks, CAB!  I will be on that job in about 2 hours or so.  I'll let you know how it works out for me.

BTW, 98% of all of our work is done in modelspace and this particular client doesn't use attributes too often, but I can't thank you enough for doing that!!! 

[T.Willey]

You might want to test this on one drawing first.  I don't know how well text is handled with ObjectDBX if the text is not left justified.  I know attributes will show up funny, but not sure about text.  Just an FYI...

[CAB]

Tim,I have not tested it but Jeff Said:

Tim, the alignment problem is only with Attributes and only when you change the alignment. Just changing the value does not cause a problem, IIRC. I'm pretty sure that Autocad already prevents you from creating the Xrefs in a loop. Although a problem is encountered with nested Xrefs, which is why the Reload is wrapped by the (vl-catch-all-apply).....you can't reload a nested xref, only the parent xref.

http://www.theswamp.org/index.php?topic=8246.msg105654#msg105654

[T.Willey]

Tim,I have not tested it but Jeff Said:

Tim, the alignment problem is only with Attributes and only when you change the alignment <snip>

This statement is wrong, if you change the value of the attribute when it is justified to something besides left, then the display is messed up.  I think if you go in and edit it, then it will show correct.  I have tested this and know it to be true.

[CAB]

Thanks for the clarification, good to know.

[T.Willey]

I just tried it with just text, and when first opened it shows them in the wrong stop, but then with my company setup (it does somethings that I wish it wouldn't) it regened the drawing, and all the text is shown in the right spot.

FYI..

Thanks for the clarification, good to know.

You're welcome.

[CAB]

Ha, you beat me to it. I was typing this.
Did a quick test on plain text center justified. The text appeared off a bit but the grips were in the correct position.
If you regen then the text reappears in the correct location. The grips were in the correct location.

[T.Willey]

Ha, you beat me to it. I was typing this.

i ninja!

Did a quick test on plain text center justified. The text appeared off a bit but the grips were in the correct position.
If you regen then the text reappears in the correct location. The grips were in the correct location.

This might be the same issue with attributes then, but to regen them you have to edit the block, or move it.

[CAB]

Mike,
Did the routine work for you or blow you computer up.
I do hope it went OK. I revised the code to work with Paper Space and/or Model Space.

<code removed, see previous post>

[T.Willey]

Here is one I did for someone on the Adesk Ng.  You can use/ingnore/change it all you want.  Right now it only works in the current drawing, but that can easly be changed.  It will look through text, mtext, tables, blocks, dimensions, and attribute definitions.

Code: [Select]

(defun c:ReplaceAllStrings (/ ActDoc DtextList MtextList)

(defun ReplaceAllStrings (Doc MtextReplcList DtextReplcList / tempObjType ColCnt RowCnt)

(defun ReplaceString (String ReplaceList MtextObj / strTest strReplc Pos IsFormat FormatList strTemp)

(foreach pair ReplaceList
 (setq strTest (car pair))
 (setq strReplc (cdr pair))
 (setq Pos -1)
 (while
  (and
   (< Pos (strlen String))
   (setq Pos (vl-string-search strTest String (setq Pos (1+ Pos))))
  )
  (if (equal Pos 0)
   (setq String
    (strcat
     strReplc
     (if (<= (1+ (+ Pos (strlen strTest))) (strlen String))
      (substr String (1+ (+ Pos (strlen strTest))))
      ""
     )
    )
   )
   (setq String
    (strcat
     (substr String 1 Pos)
     strReplc
     (if (<= (1+ (+ Pos (strlen strTest))) (strlen String))
      (substr String (1+ (+ Pos (strlen strTest))))
      ""
     )
    )
   )
  )
  (setq Pos (+ Pos (strlen strReplc)))
 )
)
(if MtextObj
 (progn
  (setq Pos 1)
  (setq FormatList '("A" "Q" "T" "S" "H" "F" "C"))
  (setq IsFormat 0)
  (while (<= Pos (strlen String))
   (setq strTemp (substr String 1 1))
   (cond
    ((= strTemp "\\")
     (if (vl-position (substr String (1+ Pos) 1) FormatList)
      (setq IsFormat (1+ IsFormat))
     )
     (setq Pos (1+ Pos))
    )
    ((= strTemp ";")
     (if (equal IsFormat 0)
      (progn
       (if (equal Pos 1)
        (setq String
         (strcat
          "\\U+00B1"
          (if (<= 2 (strlen String))
           (substr String 2)
           ""
          )
         )
        )
        (setq String
         (strcat
          (substr String 1 (1- Pos))
          "\\U+00B1"
          (if (<= (1+ Pos) (strlen String))
           (substr String (1+ Pos))
           ""
          )
         )
        )
       )
       (setq Pos (+ Pos 7))
      )
      (progn
       (setq IsFormat (1- IsFormat))
       (setq Pos (1+ Pos))
      )
     )
    )
    (T (setq Pos (1+ Pos)))
   )
  )
 )
)
String
)
;---------------------------------------------------------------------------------------
(setq BlkCol (vla-get-Blocks Doc))
(vlax-for Lo (vla-get-Layouts Doc)
 (vlax-for Obj (vla-get-Block Lo)
  (setq tempObjType (vla-get-ObjectName Obj))
  (cond
   ((vl-position tempObjType '("AcDbText" "AcDbAttributeDefinition"))
    (vla-put-TextString Obj (ReplaceString (vla-get-TextString Obj) DtextReplcList nil))
   )
   ((= tempObjType "AcDbMText")
    (vla-put-TextString Obj (ReplaceString (vla-get-TextString Obj) MtextReplcList T))
   )
   ((wcmatch tempObjType "AcDb*Dimension")
    (vlax-for tempObj (vla-Item BlkCol (cdr (assoc 2 (entget (vlax-vla-object->ename Obj)))))
     (if (= (vla-get-ObjectName tempObj) "AcDbMText")
      (vla-put-TextString tempObj (ReplaceString (vla-get-TextString tempObj) MtextReplcList T))
     )
    )
   )
   ((= tempObjType "AcDbBlockReference")
    (foreach Att (vlax-invoke Obj 'GetAttributes)
     (vla-put-TextString Att (ReplaceString (vla-get-TextString Att) DtextReplcList nil))
    )
    (foreach Att (vlax-invoke Obj 'GetAttributes)
     (vla-put-TextString Att (ReplaceString (vla-get-TextString Att) DtextReplcList nil))
    )
   )
   ((= tempObjType "AcDbTable")
    (setq ColCnt 0)
    (repeat (vla-get-Columns Obj)
     (setq RowCnt 0)
     (repeat (vla-get-Rows Obj)
      (vla-SetText Obj (ReplaceString (vla-GetText Obj RowCnt ColCnt) DtextReplcList nil))
      (setq RowCnt (1+ RowCnt))
     )
     (setq ColCnt (1+ ColCnt))
    )
   )
  )
 )
)
)
;------------------------------------------------------------------------
(setq ActDoc (vla-get-ActiveDocument (vlax-get-Acad-Object)))
(setq DtextList
 (list
  (cons "^" "\\U+00B0")
  (cons ";" "\\U+00B1")
  (cons "_" "\\U+06F8") ;; Doesn't like new string
  (cons "|" "\\U+00BC")
  (cons "{" "\\U+215C")
  (cons "\\" "\\U+00BD")
  (cons "}" "\\U+215D")
  (cons "[" "\\U+00BE")
  (cons "]" "\\U+215E")
  (cons "~" "%%C")
  (cons "<" "\\U+2104") ;; Doesn't like new string
  (cons ">" "\\U+214A") ;; Doesn't like new string
 )
)
(setq MtextList
 (list
  (cons "^" "\\U+00B0")
  (cons "_" "\\U+06F8") ;; Doesn't like new string
  (cons "|" "\\U+00BC")
  (cons "\\{" "\\U+215C")
  (cons "\\\\" "\\U+00BD")
  (cons "\\}" "\\U+215D")
  (cons "[" "\\U+00BE")
  (cons "]" "\\U+215E")
  (cons "~" "%%C")
  (cons "<" "\\U+2104") ;; Doesn't like new string
  (cons ">" "\\U+214A") ;; Doesn't like new string
 )
)
(ReplaceAllStrings ActDoc MtextList DtextList)
(princ)
)

Edit:  Updated code.  I knew I had a better version, just coudn't find it before.

[CAB]

Great Tim, thanks.
Waiting to see how Mike did before I go any further.
Work is pressing me.

[M-dub]

I'm just getting into it now!   

Man, I hate it when work gets in the way of work... and other things. 

[M-dub]

I'm just getting into it now!   

Man, I hate it when work gets in the way of work... and other things. 

Scratch that... Work just got in the way again!!!

[whdjr]

I have a lisp from Will Deloach that does that for all files in a directory using ObjectDBX. (Very Fast)
It would have to be modified to accommodate all the text you want to change as it was set up
to change only one text string. I tried to find the old code in the swamp but have had no luck
linking you to it.

I think this is the link you were talking about.

[CAB]

Yes, that's it. Thanks Will.

[CAB]

Mike, did this ever happen? Or still pending?

[M-dub]

Still pending.  I just have to wait until that boss comes in and tells me that his job takes precident over everyone else's work.  Just know that your work was not done in vain.  I WILL be getting to it.  It's just that these construction packages are more important to get out than that As Built package.

At the time I started this thread, I was in fact, on that job, but then things came up and well... I'm sure you've been in similar situations in the past...

[M-dub]

Ok, I am FINALLY getting to this, but it's for a job other than the one that prompted this thread.  (if that made any sense... ? )

The error I get is "Error: Automation Error. Problem in loading application"

I run TEXTREPLACE, go select my (testing) folder and click on Save and that's what I get.  Suggestions?

[CAB]

Do you mean you run TextReplaceDBX

[M-dub]

Nope.  I mean, I loaded and ran TextReplace.lsp and received that error.

(bear in mind that I'm a coding idiot)

What was my mistake?

[CAB]

Sorry for the confusion I created.
Enter this at the command line once it is loaded:
TextReplaceDBX

[M-dub]

Sorry for the confusion I created.
Enter this at the command line once it is loaded:
TextReplaceDBX

Once TextReplace.LSP is loaded, right?

(Just want to make sure)

[T.Willey]

Sorry for the confusion I created.
Enter this at the command line once it is loaded:
TextReplaceDBX

Once TextReplace.LSP is loaded, right?

(Just want to make sure)

Yes.

[M-dub]

I'm not getting it.

I must be missing something, which would also be par for the course.

Code: [Select]

Command: ad APPLOAD textreplace.LSP successfully loaded.


Command:
Text Replace Loaded, enter TextReplace to run.
Command:
Command: TextReplaceDBX
Unknown command "TEXTREPLACEDBX".  Press F1 for help.

[Kerry]

How about TextReplace

Command:
Text Replace Loaded, enter TextReplace to run.

[M-dub]

How about TextReplace

Command:
Text Replace Loaded, enter TextReplace to run.

That was the first one I tried and got

"Error: Automation Error. Problem in loading application"

I have to do a bunch of other stuff to these drawings as well, so I MAY end up just doing EVERYTHING with a script.  I would really hate for all of your help to be in vain, believe me!  I really hate the fact that A)  It's taken me this long to get to this issue, and B)  I can't contribute to the actual creation and troubleshooting of the code.  Just know that I truly do appreciate everyone's efforts just the same.

[Kerry]

TextReplace is the correct command.

Which Acad version are you using ?

Try pasting this at the command line

(atoi (substr (getvar "acadver") 1 2))

[M-dub]

Which Acad version are you using ?

AutoCAD 2002

Try pasting this at the command line

(atoi (substr (getvar "acadver") 1 2))

15

[Kerry]

and this ?

Code: [Select]

      (setq *acad (vlax-get-acad-object))

      (setq odbx (if (< (atoi (substr (getvar "acadver") 1 2)) 16)
                   (vla-getinterfaceobject *acad "ObjectDBX.AxDbDocument")
                   (vla-getinterfaceobject *acad "ObjectDBX.AxDbDocument.16")
                 )
      )

[M-dub]

and this ?

Code: [Select]

      (setq odbx (if (< (atoi (substr (getvar "acadver") 1 2)) 16)
                   (vla-getinterfaceobject *acad "ObjectDBX.AxDbDocument")
                   (vla-getinterfaceobject *acad "ObjectDBX.AxDbDocument.16")
                 )
      )

Error: Automation Error. Problem in loading application

[Kerry]

OK .. in 2002 DBX isn't automatically registered.

Try this as a once off ..

Code: [Select]

(STARTAPP "regsvr32.exe"
          (STRCAT "/s \"" (FINDFILE "axdb15.dll") "\"")
)


added:
...
then try the previous again.
*** make sure to run this first

Code: [Select]

(setq *acad (vlax-get-acad-object))

[M-dub]

OK .. in 2002 DBX isn't automatically registered.

Try this as a once off ..

Code: [Select]

(STARTAPP "regsvr32.exe"
          (STRCAT "/s \"" (FINDFILE "axdb15.dll") "\"")
)


added:
...
then try the previous again.

Not sure if this is what you were looking for, but


33

[M-dub]

Oops... just saw your update, so I tried it...

Code: [Select]

Command: (STARTAPP "regsvr32.exe"
(_>           (STRCAT "/s \"" (FINDFILE "axdb15.dll") "\"")
(_> )
33

Command: (setq odbx (if (< (atoi (substr (getvar "acadver") 1 2)) 16)
((_>                    (vla-getinterfaceobject *acad "ObjectDBX.AxDbDocument")
((_>                    (vla-getinterfaceobject *acad
"ObjectDBX.AxDbDocument.16")
((_>                  )
(_>       )
#<VLA-OBJECT IAxDbDocument 037247a8>

[Kerry]

Whhhheeeeee ... !!!

[Kerry]

Alan may change the test to something like :

Code: [Select]

(SETQ *acad (VLAX-GET-ACAD-OBJECT)
      odbx  (IF (< (SETQ acadvers (SUBSTR (GETVAR "acadver") 1 2)) "16")
              (PROGN
                (IF
                  (NOT (VL-REGISTRY-READ
                         "HKEY_CLASSES_ROOT\\ObjectDBX.AxDbDocument\\CLSID"
                       )
                  )
                   (STARTAPP "regsvr32.exe"
                             (STRCAT "/s \"" (FINDFILE "axdb15.dll") "\"")
                   )
                )
                (VLA-GETINTERFACEOBJECT *acad "ObjectDBX.AxDbDocument")
              )
              (VLA-GETINTERFACEOBJECT
                *acad
                (STRCAT "ObjectDBX.AxDbDocument" acadvers)
              )
            )
)

[Kerry]

Whhhheeeeee ... !!!

Translates to :
Try the original routine now Mike.

[M-dub]

Many Thanks, Kerry!



I think I have to have all of the dwg's closed for it to work right.

I'm just about at a good spot to break, then I'll try it.

[Kerry]

I HAVE had issues running DBX when drawings are open, so play safe for now ..

[CAB]

Mike, been out of the office.
Thanks Kerry.

Updated the code here per Kerry's suggestion.