Topic: Examples of usage GRREAD - let's share

[alanjt]

Excellent , Alan !
You have used the better method grdraw to show middle routine . I can learn a lot from your code

Enjoy. I had a bit of fun writing it.

[GDF]

Excellent , Alan !
You have used the better method grdraw to show middle routine . I can learn a lot from your code

Enjoy. I had a bit of fun writing it.

Nice routine.

To activate the PW command grread function, I have to hit the space bar after selecting the polyline.

[alanjt]

Excellent , Alan !
You have used the better method grdraw to show middle routine . I can learn a lot from your code

Enjoy. I had a bit of fun writing it.

Nice routine.

To activate the PW command grread function, I have to hit the space bar after selecting the polyline.

Thanks.
Yes, it allows for multiple LWPolyline selection, so you have to right-click/enter/spacebar after selecting all desired LWPolylines.

[Pad]

Thanks for the two leader arrow routines Alan.  Very useful.

[alanjt]

Thanks for the two leader arrow routines Alan.  Very useful.

Enjoy. 

[alanjt]

Similar to the new option to 2011 or being able to TAB through a list of ENames like one can TAB through different usable OSnaps in an area.

Code: [Select]

(defun AT:CycleThroughENames (lst / l n i g e)
  ;; Cycle through a list of ENames to choose one
  ;; lst - list of ENames
  ;; Alan J. Thompson, 03.29.11
  (if (>= (setq l (length lst)) 2)
    (progn
      (princ "\n<Tab> to cycle through entities: ")
      (redraw (setq i (nth (setq n 0) lst)) 3)
      (while (progn (setq g (grread nil 10))
                    (cond ((equal g '(2 9))
                           (redraw i 4)
                           (redraw (setq i (nth (setq n (rem (1+ n) l)) lst)) 3)
                           T
                          )
                          ((or (member g '((2 32) (2 13))) (eq (car g) 25)) (redraw (setq e i) 4))
                          (T (redraw i 4))
                    )
             )
      )
      e
    )
    (car lst)
  )
)
EDIT: Minor change to follow a suggestion by Lee.

Test subroutines (and a quick sub to convert the selection set to a list):

Code: [Select]

(defun ss->lst (ss / i l)
  (if (eq (type ss) 'PICKSET)
    (repeat (setq i (sslength ss)) (setq l (cons (ssname ss (setq i (1- i))) l)))
  )
)

(defun c:Test (/ ent)
  (if (setq ent (AT:CycleThroughENames (ss->lst (ssget))))
    (sssetfirst nil (ssadd ent))
  )
  (princ)
)

(defun c:Test2 (/ pt ent)
  (if (and (setq pt (getpoint "\nSpecify point: "))
           (setq ent (AT:CycleThroughENames (ss->lst (ssget "_C" pt pt))))
      )
    (sssetfirst nil (ssadd ent))
  )
  (princ)
)

[Lee Mac]

Nice one Alan It reminds me of a snippet I posted here 

Looking back at it, it could probably be shortened to just:

Code: [Select]

(defun c:msel ( / ss i l )
  (and
    (setq ss (ssget))
    (setq i -1 l (sslength ss))
    (princ "\nPress Tab to Cycle Through Selection <Exit>: ")
    (while (= 9 (cadr (grread nil 10))) (sssetfirst nil (ssadd (ssname ss (setq i (rem (1+ i) l))))))
  )
  (princ)
)

[alanjt]

(rem (1+ i) l)

Clever. :kewl: You've proved me useless.

[Lee Mac]

(rem (1+ i) l)

Clever. :kewl: You've proved me useless.

Thanks Alan 

[alanjt]

These would probably make more sense. I was getting caught up in worrying with it only returning an EName if the user right-clicked, hit enter or the spacebar, but that's kind of silly. If they selected the objects, they're bound to want to, regardless...

Code: [Select]

(defun AT:CycleThroughENames (lst / l i n)
  (if (>= (setq l (length lst)) 2)
    (progn (princ "\n<Tab> to cycle through entities: ")
           (redraw (setq i (nth (setq n 0) lst)) 3)
           (while (eq (cadr (grread nil 10)) 9)
             (mapcar 'redraw (list i (setq i (nth (setq n (rem (1+ n) l)) lst))) '(4 3))
           )
           (redraw i 4)
           i
    )
    (car lst)
  )
)



(defun AT:CycleThroughSS (ss / l i e)
  (if (eq (type ss) 'PICKSET)
    (if (eq (setq l (sslength ss)) 1)
      (ssname ss 0)
      (progn (princ "\n<Tab> to cycle through entities: ")
             (redraw (setq e (ssname ss (setq i 0))) 3)
             (while (eq (cadr (grread nil 10)) 9)
               (mapcar 'redraw (list e (setq e (ssname ss (setq i (rem (1+ i) l))))) '(4 3))
             )
             (redraw e 4)
             e
      )
    )
  )
)
Thanks for the example to put my head on a little straighter, Lee.

[Lee Mac]

Nice one Alan, you're welcome

[pBe]

Question:

Can grread retrieve infos from a "gripped" object?

[Lee Mac]

Can grread retrieve infos from a "gripped" object?

What 'infos' would you be looking to retrieve?

grread is simply a function to monitor user input.

[alanjt]

Question:

Can grread retrieve infos from a "gripped" object?

You can select the 'gripped' object with (ssget "_I") and extract info from there.

[pBe]

You can select the 'gripped' object with (ssget "_I") and extract info from there.

grread is simply a function to monitor user input.

I understand, just wondering that's all 

Thank you gentlemen