Topic: update - using ssnamex for enames

[CAB]

There is a catch to using this code to get a list of enames.

Code: [Select]

(setq ss (ssget))
(setq enames (mapcar 'cadr (ssnamex ss)))
When you use a Window selection an additional list is included in the list:

Code: [Select]

(<Entity name: 1bc2ab8>
  <Entity name: 1bc2a88>
  <Entity name: 1bc2a50>
  <Entity name: 1bc2b48>
  <Entity name: 1bc2b18>
  <Entity name: 1bc2ae8>
  (0 (2041.3 215.161 0.0234375))  <-----<<<
)
To remove it i used this:

Code: [Select]

((vl-remove-if-not '(lambda (x) (= (type x) 'ename)) (mapcar 'cadr (ssnamex ss)))
there may be a better way, if so please share it.


I discovered the problem when developing this to delete a selection set ss

Code: [Select]

(mapcar '(lambda (ent) (vla-Delete (vlax-ename->vla-object Ent)))
(vl-remove-if-not '(lambda (x) (= (type x) 'ename)) (mapcar 'cadr (ssnamex ss))))

[MP]

Here's one way Alan --

Code: [Select]

(defun SS->Objects ( ss )
    (if (eq 'pickset (type ss))
        (mapcar 'cadr
            (vl-remove-if
               '(lambda (tuple) (minusp (car tuple)))
                (ssnamex ss)
            )
        )
    )
)

[ElpanovEvgeniy]

For deleting all ename in a choice, I - use:

Code: [Select]

(if (setq ss (ssget))
  (mapcar (function entdel)
          (vl-remove-if (function listp) (mapcar (function cadr) (ssnamex ss)))
  ) ;_  mapcar
) ;_  if
To create list VLA-OBJECTS, I - use:

Code: [Select]

(if (setq ss (ssget))
  (mapcar (function vlax-ename->vla-object)
          (vl-remove-if (function listp) (mapcar (function cadr) (ssnamex ss)))
  ) ;_  mapcar
) ;_  if


[CAB]

Thanks fellas

This fits my condensed style perfectly. 
I'm a happy camper.

Code: [Select]

  (if (setq ss (ssget))
    (mapcar 'entdel (vl-remove-if 'listp (mapcar 'cadr (ssnamex ss))))
  )

[ElpanovEvgeniy]

Success to you! 
I should consider every second...