Topic: InputBox

[Patrick_35]

Hello
Also my small contribute share on this fabulous site
To supplement what Gary Fowler did on this nice post http://www.theswamp.org/index.php?topic=9684.0 and in same logic, here the InputBox function

@+

Code: [Select]

(defun InputBox (Title Message Default XPos YPos / users1 value)
  (vl-load-com)
  (if (not Xpos)
    (setq XPos (* (/ (car (getvar "screensize")) 2) 10)))
  (if (not YPos)
    (setq YPos (* (/ (cadr (getvar "screensize")) 2) 10)))
  (or *acad* (setq *acad* (vlax-get-acad-object)))
  (setq users1 (getvar "users1"))
  (acad-push-dbmod)
  (vla-eval
    *acad*
    (strcat
      "ThisDrawing.SetVariable \"USERS1\","
      "InputBox (\""
      Message
      "\", \""
      Title
      "\", \""
      Default
      "\", \""
      (rtos XPos)
      "\", \""
      (rtos YPos)
      "\")"
    )
  )
  (setq value (getvar "users1"))
  (setvar "users1" users1)
  (acad-pop-dbmod)
  value
)

(InputBox "My title" "My Message" "Default" nil nil)
(InputBox "My title" "My Message" "Default" 150 200)

[Didge]

Nice One Patrick 

[lispman21]

Never used an input box like this.  What type of application would you use it in or for.

[CAB]

Patric I get this error using ACAD2000.

Code: [Select]

Command: (inputbox "My title" "My Message" "Default" nil nil)
; error: Automation Error. VBA expression evaluation failed
; reset after error

[Fatty]

Hi, guys
You can play with this also:

Code: [Select]

(defun AnswerMe (TitleStr MsgStr  / IntPass StrPass)
(vl-load-com)  
(setq WshShell (vlax-create-object "WScript.Shell"))
(setq IntPass (vlax-invoke WshShell 'Popup
TitleStr  7
MsgStr  35)
      )

(setq StrPass
(cond ((= intPass 6) "Yes")
      ((= intPass 7) "No")
      ((= intPass 2) "Not sure about")))
(alert StrPass);for debug only
(vlax-release-object WshShell)
(princ)
)
; CaLL :
(AnswerMe "Do you want something?" "Answer My Question:" )

Fatty

~'J'~

[MP]

Patric I get this error using ACAD2000.

Code: [Select]

Command: (inputbox "My title" "My Message" "Default" nil nil)
; error: Automation Error. VBA expression evaluation failed
; reset after error

Perhaps include this in the initialization bit Alan --

Code: [Select]

(if (null (member "acvba.arx" (arx)))
    (arxload "acvba.arx")
)
Nice demonstration Patrick; you too Fatty.

[CAB]

Hummm.

Code: [Select]

Command: (arxload "acvba.arx")
; error: ARXLOAD failed
; reset after error
Search failed to find this.

Gotta go, so I'll look again later.

[MP]

What version of AutoCAD are you runnin' Alan? Maybe it'll have to perform a more intelligent | branched load on the arxname. I've only got 2006 here and don't know them off the top of my head.

[CAB]

I am using ACAD2000 to test & this one runs fine
http://www.theswamp.org/index.php?topic=9684.0

Must be an ACAD version problem so don't spend any time chasing it.

If I have time later I'll try it in 2006.

[LE]

I tried too... and I got same error as Alan using A2005 - and having loaded "acvba.arx"

[GDF]

I tried too... and I got same error as Alan using A2005 - and having loaded "acvba.arx"

Same error using 2006

Gary

[Patrick_35]

Never used an input box like this.  What type of application would you use it in or for.

If you need an input in your application, you can use it

Patric I get this error using ACAD2000.

After your message, i tested it in ACAD2000 and the code do it, not error

I tried too... and I got same error as Alan using A2005 - and having loaded "acvba.arx"

It's "acvba.arx" or "acadvba.arx" ?
In my french version of ACAD2000, i find "acadvba.arx", not "acvba.arx"

Thank's for you code Fatty, good job

@+

[Serge J. Gianolla]

Patrick, no problemo here on 2006. Ca marche au poil!
Fatty good work too.

[Fatty]

Thanks to all, guys
I am still learning 

Fatty

~'J'~

[Patrick_35]

Thanks Serge
Your remark make me think that it will be necessary for me to find a new avatar 
J'ai remarqué aussi qu'il va falloir grandement améliorer mon anglais et désolé pour les fautes   
Amicalement

Flatty
I see your code and i don't understand what the parameter number seven can be serve 

@+