Topic: Startup Priority

[ronjonp]

OK....so I have nearly 200 lisp routines that I load via calling them from a custom mnl file. My question is, how can I load all these routines but not wipe out my users pgp settings? Right now all the routines load up last so any quick keys that are defined in the acad.pgp get overwritten with conflicting routines.

thanks,

Ron

[ronjonp]

Nothing? I thought you gurus would have this one knocked out in minutes .......on side note....anyone one of you using autoload to load your routines see this:

; error: no function definition: AUTOLOAD

but they still all load fine.

Thanks,

Ron

[Jeff_M]

Add the following to the end of the .mnl file:

(setvar "re-init" 16)

This will reintialize the Acad.pgp file. I haven't used the acad.pgp in so long that I'm not positive this will work, but I'm pretty sure it will.

[Jeff_M]

Nothing? I thought you gurus would have this one knocked out in minutes

Heck, I just got here.....haven't even had a cup of coffee yet.....

[CAB]

I suspect that AUTOLOAD is not causing the error but the routine that it is attempting to load that is generating the error.

As for your overwrite problem, perhaps an example of what you are loading. The problem is not clear to me.

[T.Willey]

I suspect that AUTOLOAD is not causing the error but the routine that it is attempting to load that is generating the error.

As for your overwrite problem, perhaps an example of what you are loading. The problem is not clear to me.

I think the ronjonp's problem is, say you have a lisp routine that you use, and to call it, you type "Li", and then in your pgp file, you have "Li" as "Line".  Now the "Li" call will call the lisp instead of the "Line" command.  Here wants the pgp file to have the control, not the lisp routine.

If not, then never mind.   

[ronjonp]

T Willey...you hit the nail on the head. I tried using the (setvar "re-init" 16) at the end of the mnl file but it still does not work. I also tried manually REINIT and it doesn't work? I made sure the pgp being found was the one I made changes to (findfile acad.pgp).

My acad.lsp that I load has a series of:

(AUTOLOAD "bb" '("bb"))
(AUTOLOAD "xx" '("xx"))
(AUTOLOAD "yy" '("yy"))

......and so on

Is this possibly an Autoload problem?

thanks,

Ron



Did you get your coffee Jeff

[T.Willey]

Looks like what Jeff said should work.

Type:  Integer
Saved in:  Not-saved
Initial value:  0


Reinitializes the digitizer, digitizer port, and acad.pgp file. The setting is stored as a bitcode using the sum of the following values:

1
 Digitizer input/output port reinitialization
 
4
 Digitizer reinitialization
 
16
 PGP file reinitialization (reload)
 

To specify more than one reinitialization, enter the sum of the bitcode values. For example, enter 5 to specify both digitizer port (1) and digitizer reinitialization (4).

Other than that I don't know what you could do.

[Jeff_M]

Yep, got my coffee, Ron! And also Yes, this very well may be an AUTOLOAD issue....here's what the help file says:

The following list describes the search order AutoCAD uses to validate a command name.

If the input is a null response (SPACEBAR or ENTER), AutoCAD uses the name of the last command issued. HELP is the default.
AutoCAD checks the command name against the list of built-in commands. If the command is in the list and is not preceded by a period (.), AutoCAD then checks the command against a list of undefined commands. If the command is undefined, the search continues. Otherwise, the command is run, unless another reason prevents it from doing so. Running it transparently or in Perspective mode might be impossible.
AutoCAD checks the command name against the names of commands defined by a device driver, and then by those defined by the display driver.
AutoCAD checks the command name against the external commands defined in the program parameters file (acad.pgp). If the command name corresponds to a defined external command, that command runs, and the search is complete.
AutoCAD checks the command name against the list of commands defined by AutoLISP or ObjectARX applications. At this point, an autoloaded command is loaded. (For information about autoloading commands, see Command Autoloader.)
AutoCAD checks the command name against the list of system variables. If the command name is in the list, AutoCAD executes theSETVAR command, using the input as the variable name.
If the command name corresponds to a command alias defined in the program parameters file, AutoCAD uses the expanded command name and continues the search, starting a new search against the list of built-in commands.
If all the preceding steps fail, the search terminates with a warning message about illegal command names.

Note the the PGP file is checked for EXTERNAL applications first, then for Autoload, then for Alias's........

[CADaver]

His MNL is a series of autoloads that don't load until called.  He would need to add the re-init to the end of each called routine, wouldn't he?

[nivuahc]

I think the only real solution to the problem at hand is good housekeeping.

[Jeff_M]

I think the only real solution to the problem at hand is good housekeeping.

AGREED!

[CADaver]

I think the only real solution to the problem at hand is good housekeeping.

AGREED!

AGREED^2

We've come to depend on the way the current hiarchy functions to make sure things are loaded in an acceptable order.

[ronjonp]

His MNL is a series of autoloads that don't load until called.  He would need to add the re-init to the end of each called routine, wouldn't he?

I don't have all the autoload lines in the mnl...I have a line that looks for an external file with all the lisp definitions in it and loads it if found. I know I need to do some cleanup but what i don't understand here is why reinit doesn't recognize my command aliases when manually initialized after startup.

Ron

[T.Willey]

I have an idea, not sure if it will work, but maybe.  I need to know how to make a lisp routine from a lisp routine.  I'm trying to redefine the lisp routines, to the command that the alias belong to.  I have it all worked out so far, but can't seem to redefine within the lisp.

Question (incase it got lost in there):
How to make a lisp function from a lisp function, and have it be defined right then are there? and have it be callable from the command line.

[ronjonp]

T Willey,

You lost me .

What steps do you take to ensure that the PGP file takes priority over externally defined commands?

I feel like this should be alot easier than I'm making it out to be.

Thanks for all the input,

Ron

[T.Willey]

I didn't.  I opened the pgp file, made a list of all the command alias's and the commands.  Then I read all the lisp files that are loaded, and compaired them.  Now I'm trying to convert the ones that overlap, to the commands that are defined in the pgp file.

So I have a list of lists, that I need to make defuns out of.  One example (on my computer) would be
("ATE" . "DDATTE")
Trying to do something like
(defun c:ate () (command ".ddatte"))
But can't get it to work right yet.

[Jeff_M]

Ron, as I see it Tim may be on to the only way around this situation, without telling your users to use alias's that don't conflict with your lisp functions.

Tim, here's a quick example to write/load/run/remove a lisp from a lisp:

Code: [Select]

(defun c:comments (/ file1 file2 t1 t2 timer1-end
   timer1-start timer2-end timer2-start)
  (setq file1 (open "c:\\testlisp1.lsp" "w")
file2 (open "c:\\testlisp2.lsp" "w"))
  (write-line "(defun c:test2 (/ mytest2)" file2)
  (write-line "  (setq mytest2 \"mytest2\")" file2)
  (write-line "  (princ)" file2)
  (write-line ")" file2)
  (close file2)
  ;;
  (write-line "(defun c:test1 (/ mytest1)" file1)
  (write-line "  (setq mytest1 \"mytest1\")" file1)
  (repeat 100000
    (write-line ";;;;this is a standard comment" file1)
    )
  (write-line "  (princ)" file1)
  (write-line ")" file1)
  (close file1)
  (setq timer1-start (getvar "millisecs"))
  (load "c:\\testlisp1.lsp")
  (setq timer1-end (getvar "millisecs"))
  (setq timer2-start (getvar "millisecs"))
  (load "c:\\testlisp2.lsp")
  (setq timer2-end (getvar "millisecs"))
  (setq t1 (strcat (rtos (/ (- timer1-end timer1-start) 1000.0) 2 5) " seconds."))
  (setq t2 (strcat (rtos (/ (- timer2-end timer2-start) 1000.0) 2 5) " seconds."))
  (princ (strcat "\nTime to load Testlisp1: " t1))
  (princ (strcat "\nTime to load Testlisp2: " t2))
  (princ (strcat "\nTestlisp1 file size = "
(rtos (vl-file-size "c:\\testlisp1.lsp") 2 0) " bytes."))
  (princ (strcat "\nTestlisp2 file size = "
(rtos (vl-file-size "c:\\testlisp2.lsp") 2 0) " bytes."))
  (vl-file-delete "c:\\testlisp1.lsp")
  (vl-file-delete "c:\\testlisp2.lsp")
  (princ)
  )


[T.Willey]

Is there no other way, than to write it to a lisp file, then load it, then delete the file?  I was hoping to do it from the command line, kind of behind the scenes.

Thanks Jeff.

[Jeff_M]

Yeah......this will load it:

Code: [Select]

(eval (read "(defun c:test () (alert \"TEST\"))"))


[T.Willey]

Yeah......this will load it:

Code: [Select]

(eval (read "(defun c:test () (alert \"TEST\"))"))


I tried that, and it didn't work, now I try it, and it does.  I must have typed something wrong.  Thanks Jeff.

Ron,
Here is the code I did, let me know if it works for you.  Right now it prompts you with how to call the lisp funtion that won't work anymore.

Code: [Select]

(defun c:ResetPgp (/ pgpFile Opened TextLine ComamndList LispRoutine)

(if (setq pgpFile (findfile "acad.pgp"))
 (progn
  (setq Opened (open pgpFile "r"))
  (while (setq TextLine (read-line Opened))
   (if
    (and
     (/= (substr TextLine 1 1) ";")
     (vl-string-search "," TextLine)
     (vl-string-search "*" TextLine)
    )
    (setq CommandList
     (cons
      (cons
       (strcase (substr TextLine 1 (vl-string-search "," TextLine)))
       (strcat "." (substr TextLine (+ 2 (vl-string-search "*" TextLine))))
      )
      CommandList
     )
    )
   )
  )
  (close Opened)
  (foreach LispRoutine (vl-remove-if-not '(lambda (x) (= (strcase (substr x 1 2)) "C:")) (atoms-family 1))
   (if (setq tmpList (assoc (strcase (substr LispRoutine 3)) CommandList))
    (progn
     (eval (read (strcat "(defun c:" (car tmpList) " () (command \"." (cdr tmpList) "\") (princ) )")))
     (prompt (strcat "\n Lisp routine \"" (substr LispRoutine 3) "\" is repalced with acad.pgp command alias."))
    )
   )
  )
 )
)
(princ)
)


[CAB]

I'm with Bob on this one.

But is this what you wanted Tim?

Code: [Select]

(defun test (key)
  (cond
    ((= key "prg1")
     (defun c:newprg ()
       (c:prg1) ; call the routine
     )
    )
    ((= key "prg2")
     (defun c:newprg ()
       (c:prg2) ; call the routine
     )
    )
    ((= key "prg3")
     (defun c:newprg ()
       (c:prg3) ; call the routine
     )
    )
  )
  (c:newprg)
)


(defun c:prg1()
  (print "You are here, prg1")
  (princ)
  )
(defun c:prg2()
  (print "You are here, prg2")
  (princ)
  )
(defun c:prg3()
  (print "You are here, prg3")
  (princ)
  )

(test "prg3")
(test "prg2")
(test "prg1")

[T.Willey]

Not really Alan, Jeff showed me the right way.  Thanks though.

[CAB]

What do they say? "Don't dive in if you cant see the bottom." 

[T.Willey]

What do they say? "Don't dive in if you cant see the bottom." 

You have helped me before, so no big deal.    You can post to help me out anytime. 

[CADaver]

I don't have all the autoload lines in the mnl...I have a line that looks for an external file with all the lisp definitions in it and loads it if found. I know I need to do some cleanup but what i don't understand here is why reinit doesn't recognize my command aliases when manually initialized after startup.

If you have code to this affect:

Code: [Select]

(AUTOLOAD "bb" '("bb"))
when you enter bb it will autoload the function regardless of the pgp setting, won't it?.

[CADaver]

Gotta go with Bob on this one.  It's a lot easier to avoid the conflicts outright than to program around them.

[TimSpangler]

One thing we do here when creatin new functions is to give them 3 letter call instead of 2 so they do not conflict with acad and if you are a keyboard junkie you know what your lisps are.

[GDF]

Ron,
Here is the code I did, let me know if it works for you.  Right now it prompts you with how to call the lisp funtion that won't work anymore.

Code: [Select]


(defun c:ResetPgp (/ pgpFile Opened TextLine ComamndList LispRoutine)

(if (setq pgpFile (findfile "acad.pgp"))
 (progn
  (setq Opened (open pgpFile "r"))
  (while (setq TextLine (read-line Opened))
   (if
    (and
     (/= (substr TextLine 1 1) ";")
     (vl-string-search "," TextLine)
     (vl-string-search "*" TextLine)
    )
    (setq CommandList
     (cons
      (cons
       (strcase (substr TextLine 1 (vl-string-search "," TextLine)))
       (strcat "." (substr TextLine (+ 2 (vl-string-search "*" TextLine))))
      )
      CommandList
     )
    )
   )
  )
  (close Opened)
  (foreach LispRoutine (vl-remove-if-not '(lambda (x) (= (strcase (substr x 1 2)) "C:")) (atoms-family 1))
   (if (setq tmpList (assoc (strcase (substr LispRoutine 3)) CommandList))
    (progn
     (eval (read (strcat "(defun c:" (car tmpList) " () (command \"." (cdr tmpList) "\") (princ) )")))
     (prompt (strcat "\n Lisp routine \"" (substr LispRoutine 3) "\" is repalced with acad.pgp command alias."))
    )
   )
  )
 )
)
(princ)
)
[/quote]


Tim

Thanks for sharing this one, I see now that I have some cleanup to do.

Gary

[TimSpangler]

forgot to add that we usually use double first letter i.e. la for the Layer command lla for the label command

Clear as mud?

[T.Willey]

Tim

Thanks for sharing this one, I see now that I have some cleanup to do.

Gary

No problem.  It looked like it would be fun to see how to solve the problem.  It worked on my computer.

I don't have all the autoload lines in the mnl...I have a line that looks for an external file with all the lisp definitions in it and loads it if found. I know I need to do some cleanup but what i don't understand here is why reinit doesn't recognize my command aliases when manually initialized after startup.

If you have code to this affect:

Code: [Select]

(AUTOLOAD "bb" '("bb"))
when you enter bb it will autoload the function regardless of the pgp setting, won't it?.

I have "AA" defined as a multi-select block edit program.  After I run the program I posted, it issues the area command, so it looks like it will work.

[CADaver]

I don't have all the autoload lines in the mnl...I have a line that looks for an external file with all the lisp definitions in it and loads it if found. I know I need to do some cleanup but what i don't understand here is why reinit doesn't recognize my command aliases when manually initialized after startup.

If you have code to this affect:

Code: [Select]

(AUTOLOAD "bb" '("bb"))
when you enter bb it will autoload the function regardless of the pgp setting, won't it?.

I have "AA" defined as a multi-select block edit program.  After I run the program I posted, it issues the area command, so it looks like it will work.

I can sorta see where it would.  You've basically redefined the function from the PGP. 

But I think my evaluation of the AUTOLOAD vs PGP is the reason his original attempt was not working, right?

[T.Willey]

I don't have all the autoload lines in the mnl...I have a line that looks for an external file with all the lisp definitions in it and loads it if found. I know I need to do some cleanup but what i don't understand here is why reinit doesn't recognize my command aliases when manually initialized after startup.

If you have code to this affect:

Code: [Select]

(AUTOLOAD "bb" '("bb"))
when you enter bb it will autoload the function regardless of the pgp setting, won't it?.

I have "AA" defined as a multi-select block edit program.  After I run the program I posted, it issues the area command, so it looks like it will work.

I can sorta see where it would.  You've basically redefined the function from the PGP. 

But I think my evaluation of the AUTOLOAD vs PGP is the reason his original attempt was not working, right?

I think so, based on what Jeff quoted from the help files.

[ronjonp]

Tim,

Thats a sweet little routine. Worked like a charm here .

Thanks for your efforts,

Ron

[T.Willey]

Tim,

Thats a sweet little routine. Worked like a charm here .

Thanks for your efforts,

Ron

You're welcome Ron.  It was fun to test the brain.

[CADaver]

Thanks for your efforts,

Yeah, thanks Tim.  While I'll probably never use the routine, there are some nifty tricks there for future projects.

[T.Willey]

Thanks for your efforts,

Yeah, thanks Tim.  While I'll probably never use the routine, there are some nifty tricks there for future projects.

One thing you can do, is comment out the line where it makes the defun, and just find out what command alias's you are overwritting.  Could be cool just to see.

You're welcome to all.  Have fun using it or learning something from it.

[T.Willey]

Found an even better way to do this on the Adesk site.  The only problem is, it will always list all the values that match an alias.  But it will make the command calls look better.  But as Tony T. pointed out, it would have to ran per drawing opened.

Code: [Select]

(defun c:ResetPgp (/ pgpFile Opened TextLine ComamndList LispRoutine)

(if (setq pgpFile (findfile "acad.pgp"))
 (progn
  (setq Opened (open pgpFile "r"))
  (while (setq TextLine (read-line Opened))
   (if
    (and
     (/= (substr TextLine 1 1) ";")
     (vl-string-search "," TextLine)
     (vl-string-search "*" TextLine)
    )
    (setq CommandList
     (cons
      (cons
       (strcase (substr TextLine 1 (vl-string-search "," TextLine)))
       (strcat "." (substr TextLine (+ 2 (vl-string-search "*" TextLine))))
      )
      CommandList
     )
    )
   )
  )
  (close Opened)
  (foreach LispRoutine (vl-remove-if-not '(lambda (x) (= (strcase (substr x 1 2)) "C:")) (atoms-family 1))
   (if (setq tmpList (assoc (strcase (substr LispRoutine 3)) CommandList))
    (progn
     (vl-acad-undefun (eval LispRoutine)) ;; The one new thing added
     (prompt (strcat "\n Lisp routine \"" (substr LispRoutine 3) "\" is repalced with acad.pgp command alias."))
    )
   )
  )
 )
)
(princ)
)


[Kerry]

$.02

............  my advice would be to defun it as "LabelMakerThingymabobber" and let people shortcut it as they will.  If it's on a menu, it makes no difference at all if it has a short name or not, for people who want to run it commandline, they can do so.

ditto ^^ .. this  has worked well for be. I use a shortcuts.LSP file for the alias definitions, which loads last on the startup sequence