Topic: Seperating Xrefs from blocks

[GDF]

Tim

Tim

I just caught this thread and tried your revised routine.
Works great, I can sure use this one. Thanks.

Gary

Cool!
Thanks for testing Gary.

Edit: Gary/all the way it's coded, it should work with drawings opened with ObjectDBX.  It will print to the current drawing opened.

So, I can use objectdbx to bind all xrefs within a directory, by using this function within an objectdbx routine?
Kool.

Gary

[T.Willey]

Yup.  You would need to make small changes (to make it work like it should with multiply drawings).

[T.Willey]

Aaron,

  This code works on your drawing.  I had some bad order in the way it worked.  I detached the xref, and then tried to get the name, and that won't work, so I had to get the name first.

Let me know it still causes problems.

Code: [Select]

(defun ReloadBindXrefs (Doc / XrefList LstLen TroubleList *error* tmpName)

(defun *error* (msg)
;(vl-bt)
(prompt (strcat "\n Error--> " msg))
)

(vlax-for Blk (vla-get-Blocks Doc)
 (if (= (vla-get-IsXref Blk) :vlax-true)
  (progn
   (if
    (vl-catch-all-error-p
     (vl-catch-all-apply 'vla-Reload (list Blk))
    )
    (if
     (and
      (setq tmpName (vla-get-name Blk))
      (vl-catch-all-error-p
       (vl-catch-all-apply 'vla-Detach (list Blk))
      )
     )
     (setq TroubleList (cons Blk TroubleList))
     (prompt (strcat "\n Detached xref: " tmpName))
    )
    (progn
     (vla-Bind Blk :vlax-true)
     (if
      (and
       (= (vla-get-IsXref Blk) :vlax-true)
       (not (vl-position (vla-get-Name Blk) XrefList))
      )
      (setq XrefList (cons Blk XrefList))
     )
    )
   )
  )
 )
)
(setq LstLen (length XrefList))
(while
 (and
  (> LstLen 0)
  (> LstLen (setq LstLen (length XrefList)))
 )
 (foreach Blk XrefList
  (if
   (or
    (= (vla-get-IsXref Blk) :vlax-false)
    (and
     (vla-Bind Blk :vlax-true)
     (= (vla-get-IsXref Blk) :vlax-true)
    )
   )
   (setq XrefList (vl-remove Blk XrefList))
  )
 )
)
(foreach Blk (append XrefList TroubleList)
 (prompt (strcat "\n Unable to bind xref: " (vla-get-Name Blk)))
)
(princ)
)
Call with (for current drawing)
(ReloadBindXrefs (vla-get-ActiveDocument (vlax-get-Acad-Object)))

[Hangman]

Hey Tim,
This works superbly.  THANK YOU very much.  I appreciate your help.

btw, I was reading the One Up link from Se7en and found your comment about tidying up an eleven year stint.
I hope it's in your best interest.
And why would you put so much time into helping me when you have more pressing issues at hand   Now I owe you a double THANK YOU !!

Best of luck in your endeavors.  And if there's anything I can do for you, let me know, you have my email addr.

And so, ... now we need to work on the images. 

[T.Willey]

Hey Tim,
This works superbly.  THANK YOU very much.  I appreciate your help.

You're welcome.  I seem to be drawn to questions about xrefs.  It's like I must answer. 

btw, I was reading the One Up link from Se7en and found your comment about tidying up an eleven year stint.
I hope it's in your best interest.

This was directed toward Michael.  I haven't been coding that long. 

Best of luck in your endeavors.  And if there's anything I can do for you, let me know, you have my email addr.

Thanks.

And so, ... now we need to work on the images. 

Did you see I started a thread about them.  I can't seem to figure that one out, and it looks like I'm not the only one.  I have started looking into coding with C# (.Net) and didn't see anything about images that would help, but it was a quick look.  This really bugs me that I/we can't figure it out.

[Maverick®]

Tim, Have you been learning reply ettique from Cadaver?