Topic: dimscale in dxf code?

[paulmcz]

I'd like to select dimension and set the dimscale to the value that dimension has. Where in the dxf code can I find the value and how can I retrieve it, if the dimscale for that dimension was set to 1?
This is what I have but it doesn't work if the selected dimension has dimscale 1.

Code: [Select]

(defun c:dsc (/ dim lst xd)
(setq dim (car (entsel "\n Select dimension to copy dimscale from: ")))
(setq lst (entget dim '("ACAD")))
(setq xd (cdr (assoc 1040 (cdadr (assoc -3 lst)))))
(setvar "dimscale" xd)
)
Thanks,
Paul.

[Crank]

Code: [Select]

(command ".dim1" "restore" "" pause)

[Jeff_M]

Code: [Select]

(or (setq xd (cdr (assoc 1040 (cdadr (assoc -3 lst)))))
    (setq xd 1.0)
    )
This will default to 1 if the selected dimension has not been altered.

A comment if I may: You should verify that 1.) the user DID select something, and 2.) the selected entity IS a dimension.....

[paulmcz]

Code: [Select]

(or (setq xd (cdr (assoc 1040 (cdadr (assoc -3 lst)))))
    (setq xd 1.0)
    )
This will default to 1 if the selected dimension has not been altered.

A comment if I may: You should verify that 1.) the user DID select something, and 2.) the selected entity IS a dimension.....

Thanks Jeff. That's what I have.

Code: [Select]

(defun c:dsc (/ dim lst xd)
  (command "cmdecho" (getvar "cmdecho"))
  (setq
    dim (car (entsel "\n Select dimension to copy dimscale from: "))
  )
  (setq lst (entget dim '("ACAD")))
  (cond ((or
   (= (cdr (assoc 0 lst)) "DIMENSION")
   (= (cdr (assoc 0 lst)) "LEADER")
)
(if (assoc -3 lst)
    (setq xd (cdr (assoc 1040 (cdadr (assoc -3 lst)))))
    (setq xd 1.0)
  )
   (setvar "dimscale" xd)
   (princ (strcat "\n Dimscale is now set to: " (rtos xd 2 3)))

)
(T (princ "\n No dimension selected"))
  )
  (princ)
)
I am wondering if the dimscale value exists in the code if you select dimension that has dimscale 1. This > (assoc -3 lst) < evaluates to nil in such case.

[paulmcz]

Code: [Select]

(command ".dim1" "restore" "" pause)

Very simple and it does the job too.
Thanks.

[Nick-LTC]

;try this, in your cond statement

(cond   ((or
      (= (cdr (assoc 0 lst)) "DIMENSION")
      (= (cdr (assoc 0 lst)) "LEADER")
   )
   (if (assoc -3 lst)
       (setq xd (if (setq xd (cdr (assoc 1040 (cdadr (assoc -3 lst))))) xd 1.0)); added to check for nil<<<<<<<<<<<
       (setq xd 1.0)
     )
      (setvar "dimscale" xd)
      (princ (strcat "\n Dimscale is now set to: " (rtos xd 2 3)))
   
   )
   (T (princ "\n No dimension selected"))
  )

[CAB]

Nick, welcome to the swamp.

Here is my version of paulmcz's routine.

Code: [Select]

(defun c:dsc (/ dim lst xd usercmd)
  (setq usercmd (getvar "cmdecho"))
  (setvar "cmdecho" 0)
  (or
    (and
      (setq dim (entsel "\n Select dimension to copy dimscale from: "))
      (setq lst (entget (car dim) '("ACAD")))
      (vl-position (cdr (assoc 0 lst)) '("DIMENSION" "LEADER"))
      (or
        (and (assoc -3 lst)
             (setq xd (cdr (assoc 1040 (cdadr (assoc -3 lst)))))
        )
        (setq xd 1.0)
      )
      (setvar "dimscale" xd)
      (princ (strcat "\n Dimscale is now set to: " (rtos xd 2 3)))
    )
    (princ "\n No dimension selected")
  )
  (setvar "cmdecho" usercmd)
  (princ)
)