Topic: XLINE angle

[Humbertogo]

How to get the angle in XY plane of a XLINE...?
witch dxf code need to read this.?

Thanks

[ElpanovEvgeniy]

Code: [Select]

(setq e (car (entsel "\nSelect XLINE object:"))
      a (angle '(0 0) (cdr (assoc 11 (entget e))))
) ;_  setq

[ElpanovEvgeniy]

Code: [Select]

(if (setq e (car (entsel "\nSelect XLINE object:")))
  ((lambda (x)
     (if (minusp (car x))
       (if (minusp (cadr x))
(+ (atan (abs (cadr x)) (abs (car x))) pi)
(+ (atan (abs (car x)) (cadr x)) (* 0.5 pi))
       ) ;_  if
       (if (minusp (cadr x))
(+ (atan (car x) (abs (cadr x))) (* 1.5 pi))
(atan (cadr x) (car x))
       ) ;_  if
     ) ;_  if
   ) ;_  lambda
    (cdr (assoc 11 (entget e)))
  )
) ;_  if

[Andrea]

modified version for radian to degree.

Code: [Select]

(setq e (car (entsel "\nSelect XLINE object:"))
      a (/ (* (angle '(0 0) (cdr (assoc 11 (entget e)))) 180) pi)
)
(alert (strcat "Angle = " (rtos a)))

[MP]

Quick and dirty alternate spin:

Code: [Select]

(   (lambda ( / ename result )
        (if (setq ename (car (entsel)))
            (vl-catch-all-apply
               '(lambda ( )
                    (setq result
                        (angle
                           '(0 0)
                            (vlax-get
                                (vlax-ename->vla-object ename)
                               'DirectionVector
                            )
                        )   
                    )
                )
            )
        )   
        result
    )
)

[LE]

Code: [Select]

(defun angvec  (vect)
  (cond
    ((equal (car vect) 0 0.0001)
     (if (minusp (cadr vect))
       (* 1.5 pi)
       (/ pi 2)))
    ((equal (car vect) -1 0.0001) pi)
    ((equal (cadr vect) 0 0.0001)
     (if (minusp (car vect))
       pi
       0))
    (T (atan (/ (cadr vect) (car vect))))))

(defun vecang (ang) (list (cos ang) (sin ang) 0.0))


[Sdoman]

Wow! A smorgasbord of GetXlineAngles.  This place is so Cool.

[ElpanovEvgeniy]

(defun angvec  (vect)
  (cond
    ((equal (car vect) 0 0.0001)
     (if (minusp (cadr vect))
       (* 1.5 pi)
       (/ pi 2)))
    ((equal (car vect) -1 0.0001) pi)
    ((equal (cadr vect) 0 0.0001)
     (if (minusp (car vect))
       pi
       0))
    (T (atan (/ (cadr vect) (car vect))))))

Code: [Select]

(atan (/ (cadr vect) (car vect))) = (atan  (cadr vect) (car vect))


[LE]

(atan (/ (cadr vect) (car vect))) = (atan  (cadr vect) (car vect))

 

Evgeniy;

That function is a very old one, back on 1993-1994, in those days I normally did not read the help file at all.... and nowdays I kept forgetting that num1/num2 is done internally.

Thanks.

[Humbertogo]

thanks guys