Topic: Lower case XREF name

[ronjonp]

Why will the paths change to lowercase but the name won't?

Code: [Select]

(defun c:xrlcase (/ sl index ent OBJ)
  (if (setq sl (ssget "_X"
      '((0 . "INSERT"))
       )
      )
    (progn
      (setq index -1)
      (while (< (setq index (1+ index)) (sslength sl))
(setq ent (ssname sl index)
      OBJ (vlax-ename->vla-object ent)
)
(if (vlax-property-available-p OBJ 'Path)
  (progn
    (vla-put-path obj (strcase (vla-get-path obj) T))
    (vla-put-name obj (strcase (vla-get-name obj) T))
  )
)
      )
    )
  )
)
Thanks,

Ron

[Jeff_M]

Because the name is set in the Blocks collection.....change your (if to this and add blk to your local variables declarations:

Code: [Select]

(if (vlax-property-available-p OBJ 'Path)
  (progn
    (vla-put-path obj (strcase (vla-get-path obj) T))
    (setq blk (vla-item
(vla-get-blocks
  (vla-get-activedocument
    (vlax-get-acad-object)
    )
  )
(vla-get-name obj)))
    (vla-put-name blk (strcase (vla-get-name obj) T))
  )
)

[ronjonp]

Thanks Jeff