Topic: find z value of selected 3dpolylines at equal distances

[motee-z]

Hello
please help to label z value of 3d polyline at equal distances like in attached drawing
manually doing that very long i have to flatten 3d polyline then explode it then join these lines to convert it to polyline then divided at equal distances then apparent entersection to get z value then label this value
thanks for any help 

[motee-z]

it looks my request very difficult that no one reply

[roy_043]

Look into the vlax-curve-* functions.
As far as I can see the steps are:
1.
Create a copy of the 3D poly and set the Z for all vertices to zero.
2.
Use the vlax-curve-getpointatdist function on the flat 3D poly to get a list of points.
3.
Use the vlax-curve-getclosestpointtoprojection to project the points on the original poly.
4.
Extract the Z value from the points and create texts. Use vlax-curve-getfirstderiv for angle info.

It is not exactly hard, but it does involve some work. Maybe you should do some of that work yourself.

[ronjonp]

Give this a try ... remember to donate to TheSwamp 

Code - Auto/Visual Lisp: [Select]

1. (defun c:labelz (/ makereadable a e i n np o o2 op p x)
2.   ;; Make Angle Readable by: ymg
3.   (defun makereadable (a)
4.     (setq a (rem (+ a pi pi) (+ pi pi)))
5.     (rem (if (< (* pi 0.5) a (* pi 1.5))
6.            (+ a pi)
7.            a
8.          )
9.          (+ pi pi)
10.     )
11.   )
12.   (vl-load-com)
13.   (if (and (setq e (car (entsel "\nPick 3D Polyline: ")))
14.            (setq o (vlax-ename->vla-object e))
15.            (= (vla-get-objectname o) "AcDb3dPolyline")
16.            (setq o2 (vla-copy o))
17.            (null (initget 7))
18.            (setq n (getreal "\nEnter distance increment to label: "))
19.       )
20.     (progn (setq i 0)
21.            ;; Flatten 3d point list
22.            (setq np (mapcar '(lambda (x)
23.                                (if (zerop (rem (setq i (1+ i)) 3))
24.                                  0.0
25.                                  x
26.                                )
27.                              )
28.                             ;; 3D point list
29.                             (setq op (vlax-get o 'coordinates))
30.                     )
31.            )
32.            (setq i 0)
33.            ;; Flatten copy of polyline
34.            (vlax-put o2 'coordinates np)
35.            (while (setq p (vlax-curve-getpointatdist o2 i))
36.              ;; Perpendicular angle at point
37.              (setq
38.                a (makereadable
39.                    (+ (* pi 0.5)
40.                       (angle '(0 0) (vlax-curve-getfirstderiv o2 (vlax-curve-getparamatpoint o2 p)))
41.                    )
42.                  )
43.              )
44.              ;; 3D point
45.              (setq p (vlax-curve-getclosestpointtoprojection o p '(0.0 0.0 1.0) t))
46.              ;; Create label
47.              (entmakex (list '(0 . "TEXT")
48.                              '(100 . "AcDbEntity")
49.                              '(67 . 0)
50.                              '(8 . "POINT LABEL")
51.                              '(100 . "AcDbText")
52.                              (cons 10 p)
53.                              '(40 . 1.2)
54.                              (cons 1 (rtos (last p) 2 2))
55.                              (cons 50 a)
56.                              '(41 . 1.0)
57.                              '(51 . 0.0)
58.                              '(7 . "Standard")
59.                              '(71 . 0)
60.                              '(72 . 0)
61.                              (cons 11 (list 0.0 0.0 (last p)))
62.                              '(100 . "AcDbText")
63.                              '(73 . 0)
64.                        )
65.              )
66.              ;; Make circle
67.              (entmakex (list '(0 . "CIRCLE")
68.                              '(100 . "AcDbEntity")
69.                              '(67 . 0)
70.                              '(8 . "Place LABEL")
71.                              '(100 . "AcDbCircle")
72.                              (cons 10 p)
73.                              '(40 . 0.18)
74.                        )
75.              )
76.              ;; Increment index
77.              (setq i (+ i n))
78.            )
79.            ;; Erase copy
80.            (vla-delete o2)
81.     )
82.   )
83.   (princ))

[motee-z]

i have been looking for this lisp since 5 year
thank you ronjonp nice lisp

[ronjonp]

i have been looking for this lisp since 5 year
thank you ronjonp nice lisp

Glad to help out.