Topic: get angle of line and insert at the end

[andrew_nao]

I think the problem is that he is not allowed to change those or at least he must
change them back to there company standard.

my angle base is 0

we dont have any company standard really. other then our layer names.. lol which is sad to say the least.


my angbase changed to  270 somehow an now it wont let me change it back

[andrew_nao]

Ensure:

ANGBASE = 90.0
ANGDIR  = 1

Then try this:
...

this is exactly what im trying to do. with the exception of putting the text in as a field and turn the decimal into degrees

ill use this as reference, but im still going to try to do it myself.
sense of accomplishment type of thing.

but the anglebase and angdir vars was a step in the right direction for me
if there was a way to get the XY plane value that is listed from when you list a line, i would be in great shape but im getting some other value.

[Lee Mac]

this is exactly what im trying to do. with the exception of putting the text in as a field and turn the decimal into degrees

You could change the Field formatting quite easily to include a degree symbol if necessary.

if there was a way to get the XY plane value that is listed from when you list a line, i would be in great shape but im getting some other value.

Note that the angle returned by the LIST command is affected by the ANGBASE and ANGDIR System Variables, the angle returned by the angle function on the two endpoints is not and is always measured anti-clockwise from the X-Axis in the current plane.

[andrew_nao]

You could change the Field formatting quite easily to include a degree symbol if necessary.

yea i can change the formatting but i was hoping to just use text
but it dont look like i can

[Lee Mac]

but it dont look like i can

Of course you can. But you will need to adjust the angle value to account for the settings of ANGBASE / ANGDIR

[Lee Mac]

Judging from your earlier response, it sounds like you've given up on this, so here's my earlier post modified to not use a Field:

Code - Auto/Visual Lisp: [Select]

1. ;; Line Angle  -  Lee Mac
2. ;; Displays the Angle of a Line at its endpoint
3.  
4. (defun c:LineAng ( / acdoc acsel acspc mtx pnt )
5.    (setq acdoc (vla-get-activedocument (vlax-get-acad-object))
6.          acspc ((if (= 1 (getvar 'CVPORT)) vla-get-paperspace vla-get-modelspace) acdoc)
7.    )
8.    (if (ssget '((0 . "LINE")))
9.        (progn
10.            (while (= 8 (logand 8 (getvar 'UNDOCTL)))
11.                (vla-endundomark acdoc)
12.            )
13.            (vla-startundomark acdoc)
14.            (vlax-for obj (setq acsel (vla-get-activeselectionset acdoc))
15.                (setq pnt
16.                    (vlax-3D-point
17.                        (polar
18.                            (vlax-get obj 'endpoint)
19.                            (vlax-get obj 'angle)
20.                            (getvar 'TEXTSIZE)
21.                        )
22.                    )
23.                )
24.                (setq mtx (vla-addmtext acspc pnt 0.0 (angtos (vlax-get obj 'angle) 0 3)))
25.                (vla-put-attachmentpoint mtx acattachmentpointmiddlecenter)
26.                (vla-put-insertionpoint  mtx pnt)
27.            )
28.            (vla-delete acsel)
29.            (vla-endundomark acdoc)
30.        )
31.    )
32.    (princ)
33. )
34. (vl-load-com) (princ)

Again, ensure:

ANGBASE = 90
ANGDIR  = 1


For those interested, here is one possible version of an angle function that respects the settings of ANGBASE and ANGDIR:

Code - Auto/Visual Lisp: [Select]

1. ;; 'angle' function to respect ANGBASE / ANGDIR  -  Lee Mac
2.  
3. (defun _angle ( p1 p2 )
4.     (rem
5.         (+ pi pi
6.             (
7.                 (if (zerop (getvar 'ANGDIR)) + -)
8.                 (- (angle p1 p2) (getvar 'ANGBASE))
9.             )
10.         )
11.         (+ pi pi)
12.     )
13. )

[andrew_nao]

Judging from your earlier response, it sounds like you've given up on this...

i have. i got frustrated that i couldnt do it on my own.

i thought with my code, it was something stupid and simple i was missing.

[nivuahc]

i have. i got frustrated that i couldnt do it on my own.

i thought with my code, it was something stupid and simple i was missing.

I know that feeling all too well.

When I get in that type of situation, more often than not it's because I've got metaphoric blinders on and I can't see the problem though it's likely right in front of me. What I like to do is step away from the problem for a bit and try to focus on something else.

That usually helps to remove those blinders and allows me to see things more clearly.

And tossing around ideas with others usually helps me to see things with another pair of eyes. It's why I love this place so much.

But don't give up.

At least not permanently.