Topic: Convert a line to a wave

[diarmuid]

I had an old lisp routine that used to draw a wave type line.  This was not associate with any linetype file etc.  so could in effect standalone.  Does wnybody now of a lisp that could draw a line or convert a line to the attached image

[CAB]

Your image is not attached.

[diarmuid]

Oops,

forgot to attach the image.

 

Any help would be greatly appreciated

Regards

Diarmuid

[Bryco]

It's a pline w/ bulges set to 1

[diarmuid]

I see what you are getting at.  However, what i'm trying to do is to alter about 200 P & ID's for a client.  the lines represents a flexible hose connection.  And i was hoping to be able to pick the start and the end point and the hose is drawn.  Their standard wont allow me ot add additional linetype to their acadiso.lin or allow another .lin file. . I've seen similar lisp's that create and insulation type line which would not be suitable in this instance.

Again

Thanks for your help

Diarmuid

[Lee Mac]

Maybe:

Code: [Select]

(defun c:hose (/ p1 p2 rad num ang i lst)

  (setq Rad 2.)
 
  (if (and (setq p1 (getpoint "\nSpecify First Point: "))
           (setq p2 (getpoint "\nSpecify Second Point: " p1)))
    (progn
      (setq num (fix (/ (distance p1 p2) (* 2. rad))) ang (angle p1 p2) i 1)

      (entmakex (append (list (cons 0 "LWPOLYLINE")
                              (cons 100 "AcDbEntity")
                              (cons 100 "AcDbPolyline")
                              (cons 90 num)
                              (cons 70 0)
                              (cons 10 p1)
                              (cons 42 i))

                        (repeat num
                          (setq lst
                            (append lst
                              (list (cons 10 (setq p1 (polar p1 ang (* 2. rad))))
                                    (cons 42 (setq i (* -1 i)))))))))))
  (princ))


[diarmuid]

yes!!!!!!, brilliant.  Thank you thank you thank you.

Thanks for all the input form everybody.

Regards

Diarmuid

[Lee Mac]

You're welcome Diarmuid 

[T.Willey]

I guess Lee beat me to it, but here is one I wrote that will let you pick at many points as you want, pline style.  It might overlap itself at corners, but well I didn't want to spend that much time on it.

Code: [Select]

(defun c:WavePline (/ DivideDistance EntList Blg Pt nPt cnt Dist Sc )
   
    (defun DivideDistance ( sPt ePt dist / Ang tempDist SpDist Amnt )
       
        (setq Ang (angle sPt ePt))
        (setq tempDist (distance sPt ePt))
        (setq SpDist (/ tempDist (setq Amnt (fix (/ tempDist dist)))))
        (setq Amnt (1+ Amnt))
        (setq cnt (+ Amnt cnt))
        (repeat Amnt
            (setq EntList
                (cons
                    (cons 42 (setq Blg (- Blg)))
                    (cons
                        (cons 41 0.)
                        (cons
                            (cons 40 0.)
                            (cons
                                (cons 10 (list (car sPt) (cadr sPt)))
                                EntList
                            )
                        )
                    )
                )
            )
            (setq sPt (polar sPt Ang SpDist))
        )
        EntList
    )
    ;-------------------------------------------------
    (setq Dist 0.4)
    (setq Sc (getvar 'LtScale))
    (setq EntList
        (list
            (cons 90 2)
            (cons 100 "AcDbPolyline")
            (cons 100 "AcDbEntity")
            (cons 0 "LWPOLYLINE")
        )
    )
    (setq Blg 1.)
    (setq cnt 0)
    (if (setq Pt (getpoint "\n Select first point: "))
        (progn
            (while (setq nPt (getpoint Pt "\n Select next point: "))
                (setq EntList (DivideDistance Pt nPt (* Dist Sc)))
                (setq Pt nPt)
                (setq cnt (1+ cnt))
            )
            (entmake (subst (cons 90 cnt) '(90 . 2) (reverse EntList)))
        )
    )
    (princ)
)


[diarmuid]

you guys are just showing off now.

Thanks man