Topic: (Challenge) 3D Plines

[Mark]

Return the extreme Z values (highest/lowest) of a given 3D polyline.

[fixo]

Here is my 2c

Code: [Select]

(defun getexremelev  (3dpoly /)
  (vl-load-com)
  (setq coors (vlax-get 3dpoly 'Coordinates))
  (while coors
    (setq tmp (list (car coors) (cadr coors) (caddr coors)))
    (setq pt_list (cons tmp pt_list))
    (setq coors (cdddr coors)))
  (setq zs (list (apply 'min (mapcar 'caddr pt_list))
(apply 'max (mapcar 'caddr pt_list))
)
)
  zs
  )

(defun C:test  ()
  (if
    (setq ss (ssget "+.:S:E" (list (cons 0 "POLYLINE"))))
     (progn
       (setq obj (vlax-ename->vla-object (ssname ss 0)))
       (setq els (getexremelev obj))
       (alert (strcat "Min value: "
      (vl-princ-to-string (car els))
      "\n"
      "Max value: "
      (vl-princ-to-string (cadr els))))
       )
     )
  )
~'J'~

[Didge]

Here's another approach.

Code: [Select]

(defun c:MIN-MAX-Z (/ enm elst vlst)
  (if (and (setq enm (car (entsel "\nSelect 3D Polyline > "))) (eq (cdr (assoc 0 (setq elst (entget enm)))) "POLYLINE"))
    (progn
      (while (= (cdr (assoc 0 (setq elst (entget (setq enm (entnext enm))))  )) "VERTEX")
(setq vlst (append vlst (list (cdr (assoc 10 elst)))))
      )
      (alert (strcat "Highest Z value: " (rtos (apply 'max (mapcar 'caddr vlst))) "\n\n"
     "Lowest Z value: " (rtos (apply 'min (mapcar 'caddr vlst)))))
    )
    (prompt "\nSelected object is not a 3D Polyline")
  )
  (princ)
)


[It's Alive!]

mine 

Code: [Select]


(DEFUN C:DOIT (/ CNT L OBJ)
  (VL-LOAD-COM)
  (SETQ ENT (CAR (ENTSEL)))
 
  (IF ENT
    (PROGN
   
      (SETQ OBJ (VLAX-ENAME->VLA-OBJECT ENT))
     
      (IF (EQ (VLAX-GET OBJ 'OBJECTNAME) "AcDb3dPolyline")
        (PROGN
       
          (SETQ CNT (/ (LENGTH (VLAX-GET OBJ 'COORDINATES)) 3)
                L   '()
          )
         
          (WHILE (< 0 CNT)
            (SETQ CNT (1- CNT)
                  L   (CONS (CADDR (VLAX-SAFEARRAY->LIST
                                     (VLAX-VARIANT-VALUE
                                       (VLAX-GET-PROPERTY OBJ 'COORDINATE CNT)))) L))
          )
         
          (SETQ L (VL-SORT L '<)
                L (LIST (CAR L) (NTH (1- (LENGTH L)) L))
          )
         
          (PRINC
            (STRCAT "Low: " (RTOS (CAR L)) " High: " (RTOS (CADR L)))
          )
         
        )
      )
    )
  )
  (PRINC)
)


edit oops

[VovKa]

Code: [Select]

(vl-load-com)
(defun test (EntName / LL UR)
  (vla-GetBoundingBox
    (vlax-ename->vla-object EntName)
    'LL
    'UR
  )
  (vl-sort (list (last (vlax-safearray->list LL))
(last (vlax-safearray->list UR))
   )
   '<
  )
)
;;;(test (car (entsel)))
wil return a list (minz maxz)

[Keith™]

Code: [Select]

(vl-load-com)
(defun test (EntName / LL UR)
  (vla-GetBoundingBox
    (vlax-ename->vla-object EntName)
    'LL
    'UR
  )
  (vl-sort (list (last (vlax-safearray->list LL))
(last (vlax-safearray->list UR))
   )
   '<
  )
)
;;;(test (car (entsel)))
wil return a list (minz maxz)

Interesting code

[ElpanovEvgeniy]

All hello!
I offer other variant.
Unlike others.

Code: [Select]

(defun test (e)
 ;; min-max-Z-point
 (list (vlax-curve-getclosestpointto e '(0. 0. -1e+99))
       (vlax-curve-getclosestpointto e '(0. 0. 1e+99))
 ) ;_  list
) ;_  defun
;;(test(car(entsel)))
(defun test1 (e)
 ;; min-max-box-point
 (list (list (car (vlax-curve-getclosestpointto e '(-1e+99 0. 0.)))
             (cadr (vlax-curve-getclosestpointto e '(0. -1e+99 0.)))
             (caddr (vlax-curve-getclosestpointto e '(0. 0. -1e+99)))
       ) ;_  list
       (list (car (vlax-curve-getclosestpointto e '(1e+99 0. 0.)))
             (cadr (vlax-curve-getclosestpointto e '(0. 1e+99 0.)))
             (caddr (vlax-curve-getclosestpointto e '(0. 0. 1e+99)))
       ) ;_  list
 ) ;_  list
) ;_  defun
;;(test1(car(entsel)))


[VovKa]

it's kinda tricky, Evgeniy
but try (test) on the following 3dpoly
(command "._3dpoly" '(-50 -50 10) '(-50 50 0) '(50 50 -10) '(50 -50 0) "_c")

[ElpanovEvgeniy]

it's kinda tricky, Evgeniy
but try (test) on the following 3dpoly
(command "._3dpoly" '(-50 -50 10) '(-50 50 0) '(50 50 -10) '(50 -50 0) "_c")

fix...

Code: [Select]

(defun test (e)
 ;; min-max-Z-point
 (list (vlax-curve-getclosestpointto e '(0. 0. -1e+16))
       (vlax-curve-getclosestpointto e '(0. 0. 1e+16))
 ) ;_  list
) ;_  defun
;;(test(car(entsel)))
(defun test1 (e)
 ;; min-max-box-point
 (list (list (car (vlax-curve-getclosestpointto e '(-1e+16 0. 0.)))
             (cadr (vlax-curve-getclosestpointto e '(0. -1e+16 0.)))
             (caddr (vlax-curve-getclosestpointto e '(0. 0. -1e+16)))
       ) ;_  list
       (list (car (vlax-curve-getclosestpointto e '(1e+16 0.)))
             (cadr (vlax-curve-getclosestpointto e '(0. 1e+16)))
             (caddr (vlax-curve-getclosestpointto e '(0. 0. 1e+16)))
       ) ;_  list
 ) ;_  list
) ;_  defun
;;(test1(car(entsel)))

[VovKa]

congratulations Evgeniy, it looks like i've found a bug in vlax-curve-getclosestpointto function

[ElpanovEvgeniy]

congratulations Evgeniy, it looks like i've found a bug in vlax-curve-getclosestpointto function

It is my error!
There was no accuracy...

Code: [Select]

(equal 1e+99 (+ 1e+99 10))returne T..

[VovKa]

as a matter of fact your function (test) shouldn't work in most cases, but because of some 'undocumented features' in vlax-curve-getclosestpointto it returns the desired z's...

[ElpanovEvgeniy]

-e+99 = a minus infinity for autocad

[CAB]

Some very interesting solutions!

I like fixo's but would modify it to this:

Code: [Select]

(defun getexremelev (3dpoly / coors zList)
  (vl-load-com)
  (setq coors (vlax-get 3dpoly 'Coordinates))
  (while coors
    (setq zList (cons (caddr coors) zList))
    (setq coors (cdddr coors))
  )
  (list (apply 'min zList) (apply 'max zList))
)

Code: [Select]

(defun C:test (/ ss obj els)
  (if
    (setq ss (ssget "+.:S:E" (list (cons 0 "POLYLINE"))))
     (progn
       (setq obj (vlax-ename->vla-object (ssname ss 0)))
       (setq els (getexremelev obj))
       (alert (strcat "Min value: " (vl-princ-to-string (car els))
                      "\nMax value: " (vl-princ-to-string (cadr els))
              )
       )
     )
  )
)