Topic: drill count with table

[Crookedmonk]

Does anyone know of a routine that will count all holes(circles) and place them in a table with count #'s and sizes?

[kpblc]

_.dataextraction ?

[Krushert]

Yup DataExtraction.  One of my favorites.

[BIGAL]

Pretty easy a good learn lisp task. I have attached the 1st part which makes a blank table try it you will need to reduce columns etc you then use a INSERTROWS function and set the text.

Code: [Select]

(setq numrows (1+ numrows))
(vla-InsertRows Objtable  numrows (vla-GetRowHeight Objtable (1- numrows)) 1)
(vla-Settext Objtable  numrows 0 holenum )
(vla-Settext Objtable  numrows 1 Rad)

Post a sample dwg so can see how you want to label the circles.

[Crookedmonk]

This is what I was looking for. I tried _.DATAEXTRACTION but just get a table full of hole sizes. Does not show the total amount of hits.

[BIGAL]

Try  this no power left will mod re table.

Code: [Select]

; Make a count of common items
; By AlanH Aug 2021

; http://www.theswamp.org/index.php?topic=57408.0


(vl-load-com)
; By Gile
(defun my-count (a L)
  (cond
   ((null L) 0)
   ((equal a (car L)) (+ 1 (my-count a (cdr L))))
   (t (my-count a (cdr L))))
)

; By Gile
(defun remove_doubles (lst)
  (if lst
    (cons (car lst) (remove_doubles (vl-remove (car lst) lst)))
  )
)

(defun c:cntcirc ( / ss rad val cnt lst2 lst3 sp curspace tot)

(setq ss (ssget '((0 . "CIRCLE"))))

(if (= ss nil)
(progn (Alert "no circles selected will exit ")(exit))
(progn
(setq lst '())
(repeat (setq x (sslength ss))
(setq rad (cdr (assoc 40 (entget (ssname ss (setq x (1- x)))))))
(setq lst (cons rad lst))
)
)
)

(setq lst2 (remove_doubles lst))
(foreach val lst2
(setq cnt (my-count val lst))
(setq lst3 (cons (list  val cnt) lst3))
)

(setq lst3 (vl-sort lst3 '(lambda (x y) (< (car x)(car y)))))

(setq sp (vlax-3d-point (getpoint "pick a point for table")))

(Setq curspace (vla-get-modelspace (vla-get-activedocument (vlax-get-acad-object))))

(setq numrows 3)
(setq numcolumns 2)
(setq rowheight 1)
(setq colwidth 5)
(setq objtable (vla-addtable curspace sp numrows numcolumns rowheight colwidth))
(vla-settext objtable 0 0 "HIT COUNT")
(vla-settext objtable 1 0 "DIA")
(vla-settext objtable 1 1 "TOTAL COUNT")
(command "_zoom" "e")
(setq Objtable (vlax-ename->vla-object (entlast)))
(setq Objtable (vlax-ename->vla-object (entlast)))
(vla-setcellalignment objtable 2 0 acMiddleCenter)
(vla-setcellalignment objtable 2 1 acMiddleCenter)

(vla-put-regeneratetablesuppressed Objtable :vlax-true)


(foreach val lst3
(vla-InsertRows Objtable  numrows (vla-GetRowHeight Objtable (1- numrows)) 1)
(vla-Settext Objtable  numrows 0  (nth 0 val))
(vla-Settext Objtable  numrows 1 (nth 1 val))
(vla-setcellalignment objtable numrows 0 acMiddleCenter)
(vla-setcellalignment objtable numrows 1 acMiddleCenter)
(setq numrows (1+ numrows))
)

(vla-InsertRows Objtable  numrows (vla-GetRowHeight Objtable (1- numrows)) 1)
(setq numrows (1+ numrows))
(vla-InsertRows Objtable  numrows (vla-GetRowHeight Objtable (1- numrows)) 1)

(vla-setcellalignment objtable numrows 1 acMiddleCenter)
(setq tot 0)
(foreach val lst3
(setq tot (+ tot (cadr val)))
)
(vla-Settext Objtable  numrows 1 tot)

(vla-put-regeneratetablesuppressed Objtable :vlax-false)

(princ)
)

(c:cntcirc)