Topic: Entity Block Color Change to true color

[reyas1123]

Hi,
I found a lisp file ENCC-BLCC.lsp  the lisp can change only index normal color, my query is there a way to include to change entity to  true color in this Lisp? likewise if possible to include crossing or window in selecting entity in the block.

Thanks.

[ronjonp]

Look into the acad_truecolordlg function. It will return a 420 number than can be applied to objects. Or you can go to Lee's site and study THIS.

[reyas1123]

Thanks Ron for the reply, how i wish to do so but honestly I am a newbie to LSP  Thanks.

[ronjonp]

Thanks Ron for the reply, how i wish to do so but honestly I am a newbie to LSP  Thanks.

Give this a try .. did not test much so use with caution.

[reyas1123]

Thanks Ron it works perfectly,

[MSTG007]

Nice routine guys. Sure beats going through the layer manager on this... Great job.

[ronjonp]

Thanks Ron it works perfectly,

Glad to help. 

[ronjonp]

Nice routine guys. Sure beats going through the layer manager on this... Great job.

Be aware that the routine posted by the OP sets the color byobject not bylayer.

[MSTG007]

I did not notice that. Thanks Ron for pointing that out.

[ronjonp]

I did not notice that. Thanks Ron for pointing that out.

Here's a quick one to change the layer color:

Code - Auto/Visual Lisp: [Select]

1. (defun c:cc (/ _color c e l)
2.   (defun _color (ename color / code el i l)
3.     ;; Get truecolor number from acad_truecolordlg if it exists
4.     (setq code (last color))
5.     ;; Strip old truecolor value
6.     (if (assoc 420 (entget ename))
7.       (entmod (vl-remove 'nil
8.                          (mapcar '(lambda (x)
9.                                     (cond ((= (car x) 62) '(62 . 256))
10.                                           ((= (car x) 420) nil)
11.                                           (x)
12.                                     )
13.                                   )
14.                                  (entget ename)
15.                          )
16.               )
17.       )
18.     )
19.     (setq el (entget ename))
20.     ;; Apply new color
21.     (if (setq i (assoc (car code) el))
22.       (entmod (subst code i el))
23.       (entmod (append el (list code)))
24.     )
25.   )
26.   (if (setq c (acad_truecolordlg
27.                 (atoi (if (getenv "RJP_CC")
28.                         (getenv "RJP_CC")
29.                         "1"
30.                       )
31.                 )
32.               )
33.       )
34.     (while (setq e (nentsel "\nPick an item to change its layer color: "))
35.       (if (setq l (tblobjname "layer" (cdr (assoc 8 (entget (car e))))))
36.         (progn (_color l c) (setenv "RJP_CC" (itoa (cdar c))))
37.       )
38.     )
39.   )
40.   (princ)
41. )

[MSTG007]

Now, that's cool.

[ronjonp]

Now, that's cool.

[Lee Mac]

I think it could actually be reduced to:

Code - Auto/Visual Lisp: [Select]

1. (defun c:cc ( / c e )
2.     (and (setq c (acad_truecolordlg (cond ((last cc-default)) (1)) nil))
3.          (setq cc-default c)
4.          (while (setq e (car (nentsel "\nSelect object to change layer colour: ")))
5.              (entmod (append (entget (tblobjname "layer" (cdr (assoc 8 (entget e))))) c))
6.          )
7.     )
8.     (princ)
9. )

Nice one Ron 

[MSTG007]

Lee, how do you take 40 lines of code down to 10?? lol! I can actually understand that more. lol. Great job.

[ronjonp]

I think it could actually be reduced to:

Code - Auto/Visual Lisp: [Select]

1. (defun c:cc ( / c e )
2.     (and (setq c (acad_truecolordlg (cond ((last cc-default)) (1)) nil))
3.          (setq cc-default c)
4.          (while (setq e (car (nentsel "\nSelect object to change layer colour: ")))
5.              (entmod (append (entget (tblobjname "layer" (cdr (assoc 8 (entget e))))) c))
6.          )
7.     )
8.     (princ)
9. )

Nice one Ron 

Thanks
I guess I should have tested against the layers. When applying an index color to an object that already had a true color assigned, it would not update.
Sometimes I wish I had 1/2 of your brain