Topic: Looking for a Layer Script File

[GDF]

I can't get the layer restore C:LRES to work.
Oops

Code: [Select]

;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;; ARCH:FINDPATH Function ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
(defun ARCH:FINDPATHIT  ()
  (setq DWGPATH (strcat (getvar "dwgprefix") (getvar "dwgname")))
  (setq FINDPATH (substr DWGPATH 1 (- (strlen DWGPATH) 4))))

(defun C:LSAV  (/ lfile lfile1 lfilen entx lname layeron layerfr f1 f2)
  (setvar "cmdecho" 0)
  ;;(setq lfile "c:/ARCH_LAYSETS") 
  ;;(setq lfile (strcat  "\\ARCH_LAYSETS"))
  ;;(setq lfile1 (strcat lfile ".scr"))
  (ARCH:FINDPATHIT) ;new routine
  (setq lfile1 (strcat FINDPATH ".scr"))
  (setq lfilen (open lfile1 "w"))
  (prompt (strcat "\n* Storing Layer settings to: " lfile1 " *"))
  (terpri)
  (setq CLAYER1 (GETVAR "CLAYER"))
  (write-line "layer" lfilen)
  (write-line "S" lfilen)
  (write-line CLAYER1 lfilen)
  (setq entx (tblnext "layer" 1))
  (while entx
    (progn (setq lname (cdr (assoc 2 entx)))
           (setq layeron (cdr (assoc 62 entx)))
           (if (minusp layeron)
             (setq layeron "off")
             (setq layeron "on"))
           (setq layerfr (cdr (assoc 70 entx)))
           (setq f1 (/ layerfr 2))
           (setq f2 (/ layerfr 2.0))
           (if (< f1 f2)
             (setq layerfr "freeze")
             (setq layerfr "thaw"))
           (write-line layeron lfilen)
           (write-line lname lfilen)
           (write-line layerfr lfilen)
           (write-line lname lfilen)
           (setq entx (tblnext "layer"))))
  (write-line "" lfilen)
  (write-line "LAYS-RESTORE-MSG\n" lfilen)
  (close lfilen)
  (setvar "cmdecho" 1)
  (princ))
;;;
(defun C:LRES  (/ LRES)
  ;;(command "script" "c:/ARCH_LAYSETS")
  ;;(command "script" (findfile (strcat FINDPATH "\\ARCH_LAYSETS.scr")))
  (ARCH:FINDPATHIT) ;new routine   
  (setq LRES (findfile (strcat FINDPATH ".scr")))
  (setvar "cmdecho" 0)
  (command "script" LRES)
  (princ))


[kdub_nz]

In what way is it not working ?

[GDF]

Xref layers

[kdub_nz]

What about them ?

[kdub_nz]

Gary,

While waiting for your response, I'm wondering ... Have you looked at the built in  LAYERSTATESAVE, LAYERSTATE


https://knowledge.autodesk.com/support/autocad/learn-explore/caas/CloudHelp/cloudhelp/2016/ENU/AutoCAD-Core/files/GUID-3E0F662B-226F-4A27-B5BB-D15252CC994C-htm.html

https://knowledge.autodesk.com/support/autocad/learn-explore/caas/CloudHelp/cloudhelp/2016/ENU/AutoCAD-Core/files/GUID-CA2A1FF0-0BF9-4D47-B268-23261B289035-htm.html

https://knowledge.autodesk.com/support/autocad/learn-explore/caas/CloudHelp/cloudhelp/2016/ENU/AutoCAD-Core/files/GUID-F1453A4F-C184-40D9-9EE1-E1149812501A-htm.html

[alanjt]

Assuming you want something quick (based on your code), to elaborate on Kerry's suggestion of using LayerStates, you could use something like the following.

Since your code requires

Code: [Select]

(defun c:LSav (/)
  (layerstate-save (getvar 'DWGNAME) 3 nil)
  (princ)
)


(defun c:LRes (/)
  (if (layerstate-restore (getvar 'DWGNAME) nil)
    (vla-regen (vla-get-activedocument (vlax-get-acad-object))
               (if (eq (getvar 'CVPORT) 1)
                 acAllViewports
                 acActiveViewport
               )
    )
  )
  (princ)
)

(vl-load-com)
(princ)


Since your code only accounts for on/off and freeze/thaw, I set the bit code to work the same way for the layerstate-save function.

1- Restore the saved On or Off value
2- Restore the saved Frozen or Thawed value
4- Restore the saved Lock value
8- Restore the saved Plot or No Plot value
16- Restore the saved VPVSDFLT value
32- Restore the saved Color
64- Restore the saved LineType
128- Restore the saved LineWeight

[GDF]

Thanks guys. Been out of pocket. I was having trouble with script files running for xref layers.

I will start using layer states from now on.

Thanks Alan for the code.

[GDF]

Oh and thanks kdub.

[alanjt]

Welcome.