Topic: InternetExplorer.application.body

[mkweaver]

The following code has worked for years - until I upgraded internet explorer to version 11:

Code - Auto/Visual Lisp: [Select]

1. ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
2. ;;;  Routine:   HTMLToIE                                                                        ;;;
3. ;;;  Purpose:   Display text in an internet explorer window                                     ;;;
4. ;;;  Arguments: HTML - the html text to put in the window                                       ;;;
5. ;;;             Title - the document title                                                      ;;;
6. ;;;             Width - the width of the window in pixels                                       ;;;
7. ;;;             height - the height of the window in pixels                                     ;;;
8. ;;;  Notes:     The resulting window will not retain focus and typically ends up behind the     ;;;
9. ;;;             autocad window.  Alt-tab once will bring it to the front.                       ;;;
10. ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
11. (defun HTMLToIE (HTML Title width height / objIEA doc body Start)
12.   (vl-load-com)
13.   (setq objIEA (vlax-create-object "InternetExplorer.Application"))
14.   (vlax-put-property objIEA "Toolbar" 0)
15.   (vlax-put-property objIEA "StatusBar" 0)
16.   (vlax-put-property objIEA "Width" width)
17.   (vlax-put-property objIEA "Height" height)
18.   (vlax-put-property objIEA "Left" 0)
19.   (vlax-put-property objIEA "Top" 0)
20.   (vlax-put-property objIEA "Visible" :vlax-true)
21.   (vlax-invoke objIEA "Navigate2" "about:blank")
22.   (while (/= 4 (vlax-get-property objIEA "ReadyState"))
23.     (princ ".")
24.   )
25.   (setq doc    (vlax-get-property objIEA "Document")
26.         body   (vlax-get-property doc "Body")
27.         parent (vlax-get-property doc "parentWindow")
28.   )
29.   (vlax-put-property body "scroll" "yes")
30.   (vlax-put-property body "InnerHTML" HTML)
31.   (vlax-put-property doc 'Title Title)
32.   (vlax-release-object body)
33.   (vlax-release-object doc)
34.   ;;Wait three seconds
35.   (guipause 2) 
36.   (vlax-release-object objIEA)
37.   (gc)
38.   (princ)
39. )

It now fails on

Code - Auto/Visual Lisp: [Select]

1. (vlax-get-property doc "Body")

with the following error message:

bad argument type: VLA-OBJECT #<variant 9 [object HTMLBodyElement]>

Suggestions appreciated.

Mike

[ronjonp]

This fixed it for me ( using vlax-get vs. vlax-get-property )

Code - Auto/Visual Lisp: [Select]

1.   (setq doc    (vlax-get objIEA 'Document)
2.         body   (vlax-get doc 'body)
3.         parent (vlax-get doc 'ParentWindow)
4.   )

[mkweaver]

That did it!

Thanks,
Mike

[ronjonp]

That did it!

Thanks,
Mike

Code - Auto/Visual Lisp: [Select]

1. ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
2. ;;;  Routine:   HTMLToIE                                                                        ;;;
3. ;;;  Purpose:   Display text in an internet explorer window                                     ;;;
4. ;;;  Arguments: HTML - the html text to put in the window                                       ;;;
5. ;;;             Title - the document title                                                      ;;;
6. ;;;             Width - the width of the window in pixels                                       ;;;
7. ;;;             height - the height of the window in pixels                                     ;;;
8. ;;;  Notes:     The resulting window will not retain focus and typically ends up behind the     ;;;
9. ;;;             autocad window.  Alt-tab once will bring it to the front.                       ;;;
10. ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
11. (defun htmltoie (html title width height / _getprop body doc objiea)
12.   (vl-load-com)
13.   ;; ronjonp added property check
14.   (defun _getprop (o prop / p)
15.     (if (or (= (type (setq p (vlax-get-property o prop))) 'vla-object)
16.             (= (type (setq p (vlax-get o prop))) 'vla-object)
17.         )
18.       p
19.     )
20.   )
21.   (if (setq objiea (vlax-create-object "InternetExplorer.Application"))
22.     (progn (foreach p '("Toolbar" "StatusBar" "Left" "Top") (vlax-put objiea p 0))
23.            (vlax-put-property objiea "Width" width)
24.            (vlax-put-property objiea "Height" height)
25.            (vlax-put-property objiea "Visible" :vlax-true)
26.            (vlax-invoke objiea "Navigate2" "about:blank")
27.            (while (/= 4 (vlax-get-property objiea "ReadyState")) (princ "."))
28.            (if (and (setq doc (_getprop objiea "Document")) (setq body (_getprop doc "Body")))
29.              (progn (vlax-put-property body "scroll" "yes")
30.                     (vlax-put-property body "InnerHTML" html)
31.                     (vlax-put-property doc 'title title)
32.                     (foreach x (list body doc objiea) (vlax-release-object x))
33.              )
34.              (vlax-release-object objiea)
35.            )
36.            ;;Wait three seconds
37.            ;; (guipause 2)
38.            (gc)
39.     )
40.   )
41.   (princ)
42. )
43. ;; (htmltoie "test" "foo" 500 500)