Topic: esc command script

[johnratliff]

I need a little help here:

I'm trying to use the below lisp to extract plain text in a script file. The lisp ends the text selection with the esc. I've tried ^c,^C^C, (Command) and can't get the script to escape the selection.

Code: [Select]

(defun C:ETEXT  (/ FILE FUNC ENTITY ENTTYP TEXTMT)
 (setq fnamepe (getvar "dwgname"))
  (setq fnameme (substr fnamepe 1 (- (strlen fnamepe) 4)));Gets drawing name and strips file name extension.
  (setq fname (strcat fnameme ".txt")) ;add new extension to fname
  (if (= FNAME NIL)
    (setq FNAME
           (getfiled
             "Select the text file in which you want to extract data"
             "c:/"
             "txt"
             1))
    (setq FUNC
           (getstring
             (strcat
               "[data to be stored in "
               FNAME
               "]"
               "/Change file/<press Enter or Right-click to proceed>:")))
    )
  (if (= FUNC "c")
    (setq FUNC "C"))
  (if (= FUNC "C")
    (setq FNAME
           (getfiled
             "Select the text file in which you want to extract data"
             "c:/"
             "txt"
             1)))
  (while (/= FNAME NIL)
    (setq ENTITY
           (car
             (entsel
               "\nPress `Esc` to exit, or select the text string to be exported.")))
    (if (/= ENTITY NIL)
      (progn
        (setq ENTTYP (cdr (assoc 0 (entget ENTITY))))
        (if (wcmatch ENTTYP "*TEXT*")
          (progn
            (setq TEXTMT (cdr (assoc 1 (entget ENTITY))))
            (setq FILE (open FNAME "a"))
            (write-line TEXTMT FILE)
            (close FILE)
            (prompt (strcat "\nLine- `" TEXTMT "` added to " FNAME))
            )
          (prompt "\nSelected entity is not a text string")
          )
        )
      (prompt "\nNo entity selected")
      )
    )
  )
;;;;end of code

[ronjonp]

Are you trying to put selected text object strings into a *.txt file?

[johnratliff]

Yes, I'm using the lisp to build the text file. I'm then using a script to run the lisp on multiple files but the lisp uses "esc" to end the selection and I can't find the escape command to end the script. I don't know enough lisp to modify the lisp routine.

[johnratliff]

It was a bit of a struggle, but I got rid of all the while's and and most of the if's and the lisp now closes the file. I'd still like to know if there is a command line for the "esc" key so it could be used in a script.

[CAB]

This may be of some use to you.

Code - Auto/Visual Lisp: [Select]

1. (defun c:etext (/ fname ofile path)
2.   (vl-load-com)
3.   (setq fname (vl-filename-base (getvar "DWGname")))
4.   (setq path (getvar "DWGPrefix"))
5.   (setq fname (strcat fname ".txt"))
6.   (setq ofile (open (strcat path fname) "a"))
7.   (if (vl-catch-all-error-p
8.         (setq err (vl-catch-all-apply
9.                     '(lambda ()
10.                        ;;  the following will catch ESCape
11.                        (while t
12.                          (setq entity (car (entsel "\nPress `Esc` to exit, or select the text string to be exported.")))
13.                          (if (and entity
14.                                   (setq obj (vlax-ename->vla-object entity))
15.                                   (vlax-property-available-p obj 'textstring)
16.                                   (setq txt (vla-get-textstring obj))
17.                                   (/= "" (vl-string-trim " /t/n" txt))
18.                              )
19.                            (progn
20.                              (write-line txt ofile)
21.                              (prompt (strcat "\nText added to " fname))
22.                            )
23.                            (prompt "\nMissed or Selected entity is not a text string")
24.                          )
25.                        )
26.                      )
27.                   )
28.         )
29.       )
30.     (if (wcmatch (strcase (vl-catch-all-error-message err)) "*CANCEL*")
31.       (princ "\nUser Quit")
32.       (alert (vl-catch-all-error-message err))
33.     )
34.   )
35.  
36.   (and ofile (close ofile))
37.  
38.   (princ)
39. )