Topic: List of Xref in Dwgprops Comments Area

[jaydee]

Hi.
I got these codes from this forum either from Ronjonp/T.willey/joe Burke
which returns a list of xref in a list

(defun xrefnamelist (/ #list)
  (vlax-for i (vla-get-filedependencies (vla-get-activedocument (vlax-get-acad-object))) ;_ vla-get-FileDependencies
    (if (= (vla-get-feature i) "Acad:XRef")
      (setq #list (cons (vl-filename-base (vla-get-filename i)) #list)) ;_ setq
    ) ;_ if
  ) ;_ vlax-for
  (acad_strlsort #list)
) ;_ defun


How can i seperate the list and format it so it could be written to dwgprops comments areas.
or format each xref name separated by "\r\n" so each xref is list under the other in a column style
ie
(vla-put-comments si    (strcat "\nXrefs:  " xref1 "\r\n" xref2 "\r\n" xref3 "\r\n"xref4  "\r\n" etc. etc))

drawing properties summary tab comment:
Xrefs:
REFERENCE DRAWING 1
REFERENCE DRAWING 2
REFERENCE DRAWING 3
REFERENCE DRAWING 4
etc.


Thankyou

[irneb]

You can do that in several ways, perhaps:

Code: [Select]

(setq str "")
(foreach xref (xrefnamelist)
  (setq str (strcat str "\n\r" xref))
)
(vla-put-comments si (strcat "\nXrefs: (vl-string-trim "\n\r" str)))
Edit, if you want to keep the new-line before the list, just omit that vl-string-trim function. It's unclear how you prefer it, since the code you've got would show the 1st xref on the 1st line, but your example shows it on the 2nd line.

[irneb]

Probably the "most" lisplike and "elegant" way would be something like this:

Code: [Select]

(vla-put-comments si
  (apply 'strcat (cons "Xrefs:" (mapcar '(lambda (str) (strcat "\r\n" str)) (xrefnamelist))))
)

[jaydee]

thankyou Irneb
both codes works the way i wanted it and mod it slightly and should have been "\r\n"

(foreach xref (xrefnamelist)
  (setq str (strcat str "\n\r" xref))
)
(vla-put-comments si (strcat "Xrefs:  " str))

Cheers

[irneb]

You're welcome!

Sorry about the wrong order of return & newline, couldn't remember what was the "correct" way round.