TheSwamp
Code Red => AutoLISP (Vanilla / Visual) => Topic started by: JohnK on October 06, 2003, 01:09:20 PM
-
I need a second eye on this. It is KILLING me! I want a way to get as many points as the user wants but i cant seem to get it all to work out the way i want it to. This one will work, but im getting a headache. Can anyone else see anything i could improve on. (Oh i think i should mention that im also construction a pointlist and counter to go along with this too. I wanted to be able to do something to the pointlist... so that is why those exist. )
(defun getpoints (pt)
(if (= cntr nil) (setq cntr 1))
(cond
((/= pt nil)
(setq ans (getpoint pt "\nSpecify point:"))
(setq PointList (cons pt PointList))
(setq cntr (1+ cntr))
(grdraw pt ans 2))
((not pt)
(setq ans (getpoint "\nSpecify point:"))
(setq PointList (cons ans PointList))
(setq cntr (1+ cntr)))
)
ans
)
(defun startpoints (x)
(cond
((not x)
(setq x (getpoints (setq x (getpoints nil))))
(startpoints x))
((/= x nil)
(setq x (getpoints x))
(startpoints x))
)
(princ)
)
Start the example like this: (startpoints nil)
-
Okay, thinking out loud. You may have already found these issues.
First, grdraw if passed nil to ans, crashes. Needs to be set in cond/if:
(if (/= ans nil)
(grdraw pt ans 2)
)
This keeps it from crashing, but now we're stuck in the eternal loop, because ans is the value of nil, which means x is the value of nil and will continue to use ((not x) as true, therefore continue to process. Tried passing ((= ans nil) (command "")) within the cond statement of startpoints, but that starts off ending. Question: What can we do to start ans off non-nil? Here's the code as the brainstorming I did. Beware:
(defun getpoints (pt)
(if (= cntr nil)
(setq cntr 1)
)
(cond
((/= pt nil)
(setq ans (getpoint pt "\nSpecify point:"))
(setq PointList (cons pt PointList))
(setq cntr (1+ cntr))
(if (/= ans nil)
(grdraw pt ans 2)
)
)
((not pt)
(setq ans (getpoint "\nSpecify point:"))
(setq PointList (cons ans PointList))
(setq cntr (1+ cntr))
)
)
ans
)
(defun startpoints (x)
(cond
((= ans nil)
(command "")
)
((not x)
(setq x (getpoints (setq x (getpoints nil))))
(startpoints x)
)
((/= x nil)
(cond ((/= ans nil)
(setq x (getpoints x))
(startpoints x)
)
((= ans nil)
(command "")
)
)
)
)
(princ)
)
-
you lost me at
(getpoints (setq x (getpoints nil)))
-
Ok im going nuts! I got it tweeked down a bit. :?
Here run this. (getpoints nil)
(defun getpoints (pt)
(if (= cntr nil) (setq cntr 1))
(cond
((and pt)
(setq ans (getpoint pt "\nSpecify point:"))
(setq PointList (cons pt PointList))
(setq cntr (1+ cntr))
(grdraw pt ans 2)
(getpoints ans))
((not pt)
(setq ans (getpoint "\nSpecify point:"))
(setq PointList (cons ans PointList))
(setq cntr (1+ cntr))
(getpoints ans))
)
ans
)
The real problem is that it errors out if i cancle and i cant think of a way to get out of it... AHHHH!
-
Nice touch doing it recursively :)
Until you get it to work, will the stuff below do what you're trying to accomplish?
(defun points (/ plst pt p1 sp cnt)
(cond ((setq pt (getpoint "\nStart point: "))
(setq plst (cons pt plst)
p1 pt
sp pt
cnt 2)
)
)
(while pt
(initget "Close")
(setq pt (getpoint p1 (strcat "\nGimme point no. " (itoa cnt) ": ")))
(cond ((vl-consp pt)(grdraw p1 pt 2)
(setq plst (cons pt plst) p1 pt))
((= pt "Close")(grdraw p1 sp 2)
(setq pt sp plst (cons pt plst) pt nil))
)
(setq cnt (1+ cnt))
)
(reverse plst)
)
-
BLAM![/i]
(defun getpoints (pt)
(if (= cntr nil) (setq cntr 1))
(cond
((and pt)
(setq ans (getpoint pt "\nSpecify point:"))
(if (and ans)
(progn
(setq PointList (cons ans PointList))
(setq cntr (1+ cntr))
(grdraw pt ans 2)
(getpoints ans)
)
)
)
((not pt)
(setq ans (getpoint "\nSpecify point:"))
(if (and ans)
(progn
(setq PointList (cons ans PointList))
(setq cntr (1+ cntr))
(getpoints ans)
)
)
)
)
pointlist
)
-
Oh i didnt see you snuck in there Stig. LOL.
...brb Ill look.
-
wow! :shock: Man, i like that.
OBTW, that is perfect.
-
Same in both cases. It errors out if I hit enter. The break point is on grdraw. So, what that's telling me is that you're trying to pass the ans variable as nil to grdraw. I'm guessing this can't be done. Also, (getpoints ans) seems to need an if statement like reversing the pointlist and seeing if the last element in the list was nil to keep it from cycling through getpoints again.
Okay, nevermind, I see you and Stig have worked this out.
-
Se7en, how about just varying the getpoint function on account of pt. Of course, you'll have to handle both cntr and PointList from the calling code:
(defun getpointy (pt / ans)
(if (= cntr nil)
(setq cntr 1)
)
(cond ((setq ans (if pt (getpoint pt "\nSpecify point: ")
(getpoint "\nSpecify point: ")))
(cond ((and ans pt)
(setq PointList (cons pt PointList)
cntr (1+ cntr))
(grdraw pt ans 2)
)
)
(getpointy ans)
)
)
PointList
)
-
:shock: :lol: ...Now why didnt i think of that!? :?
That's awesome! Thank you Stig.
-
Wait, it throws away the last point! That's no good.
Fixed (I hope):
(defun getpointy (pt / ans)
(if (= cntr nil)
(setq cntr 1)
)
(cond ((setq ans (if pt (getpoint pt "\nSpecify point: ")
(getpoint "\nSpecify point: ")))
(setq PointList (cons ans PointList))
(cond ((and ans pt)
(setq cntr (1+ cntr))
(grdraw pt ans 2)
)
)
(getpointy ans)
)
)
(reverse PointList)
)
-
Ah, thank you. Do you realise how nuts this was making me today. I couldnt stop thinking about it all day. :P Thank you.
-
Yeah, I think we all know those problems that just get stuck and drive one nuts.
Came to think of a small thing: what are you using the counter for? Can't you just count the number of points afterwards? It would make the code a bit clearer.
(defun getPoints (/ PointList cntr)
(defun getpointy (pt / ans)
(cond ((setq ans (if pt (getpoint pt "\nSpecify point: ")
(getpoint "\nSpecify point: ")))
(setq PointList (cons ans PointList))
(if pt (grdraw pt ans 2))
(getpointy ans)
)
)
(reverse PointList)
)
(setq PointList (getpointy nil)
cntr (length PointList))
)
-
Good idea! That makes a whole lot more sence dosent it?! (why keep track of two things when all you have to handle is one.)
Man Stig, your on fire!