Print Page - replace character in text file with lisp

Code Red => AutoLISP (Vanilla / Visual) => Topic started by: pedroantonio on September 28, 2017, 11:22:51 AM

Title: replace character in text file with lisp
Post by: pedroantonio on September 28, 2017, 11:22:51 AM

Hi i am using ths code to export coordinates from my attribiute block points. I want to do a change in the code. My problem is that in the drawing some points have the letter (for example Q) and when i export the coordinates i need the Q to change with R. Is it possible to do this with lisp? When export the points and before save the file to do this change. The letters Q and R is for the example
the export file is p,x,y,z

Code - Auto/Visual Lisp: [Select]

(defun c:PXYZ ( / *error* del des ent idx lst obj ord out rtn sel )
 
 
    (defun *error* ( msg )
        (if (= 'file (type des))
            (close des)
        )
        (if (not (wcmatch (strcase msg t) "*break,*cancel*,*exit*"))
            (princ (strcat "\nError: " msg))
        )
        (princ)
    )
 
    (setq ord '("POINT" POINT-X POINT-Y "ELEV" )
          out  (LM:uniquefilename (strcat (getvar 'dwgprefix) (vl-filename-base (getvar 'dwgname))) ".crd")
          del  ","
    )
    (if (setq sel (ssget '((0 . "INSERT") (66 . 1))))
        (if (setq des (open out "w"))
            (progn
                (repeat (setq idx (sslength sel))
                    (setq ent (ssname sel (setq idx (1- idx)))
                          obj (vlax-ename->vla-object ent)
                    )
                    (setq lst
                        (append
                            (mapcar '(lambda ( a b ) (cons a (rtos b)))
                               '(point-x point-y point-z)
                                (trans (cdr (assoc 10 (entget ent))) ent 0)
                            )
                            (mapcar '(lambda ( x ) (cons (strcase (vla-get-tagstring x)) (vla-get-textstring x)))
                                (append
                                    (vlax-invoke obj 'getattributes)
                                    (vlax-invoke obj 'getconstantattributes)
                                )
                            )
                        )
                    )
                  (setq rtn (cons (vl-remove 'nil (mapcar '(lambda ( x ) (cdr (assoc x lst))) ord)) rtn))
                )
      (foreach idx (LM:alphanumsort-i (mapcar 'car rtn))
      (write-line (LM:lst->str (nth idx rtn) del) des)
   )
                (setq des (close des))
            )
            (princ (strcat "\nUnable to open file: \"" out "\" for writing."))
        )
    )
    (princ)
)                
 
;; List to String  -  Lee Mac
;; Concatenates each string in a list, separated by a given delimiter
 
(defun LM:lst->str ( lst del )
    (if (cdr lst)
        (strcat (car lst) del (LM:lst->str (cdr lst) del))
        (car lst)
    )
)
 
;; Unique Filename  -  Lee Mac
;; Returns a unique filename for a given path & file extension
 
(defun LM:uniquefilename ( pth ext / fnm tmp )
    (if (findfile (setq fnm (strcat pth ext)))
        (progn
            (setq tmp 1)
            (while (findfile (setq fnm (strcat pth "(" (itoa (setq tmp (1+ tmp))) ")" ext))))
        )
    )
    fnm
)
 
;; Alphanumerical Sort-i  -  Lee Mac
;; Sorts a list of strings containing a combination of alphabetical & numerical characters and returns the indices.
 
(defun LM:alphanumsort-i ( lst )
    (vl-sort-i (mapcar 'LM:splitstring lst)
        (function
            (lambda ( a b / x y )
                (while
                    (and
                        (setq x (car a))
                        (setq y (car b))
                        (= x y)
                    )
                    (setq a (cdr a)
                          b (cdr b)
                    )
                )
                (cond
                    (   (null x) b)
                    (   (null y) nil)
                    (   (and (numberp x) (numberp y)) (< x y))
                    (   (numberp x))
                    (   (numberp y) nil)
                    (   (< x y))
                )
            )
        )
    )
)
 
;; Split String  -  Lee Mac
;; Splits a string into a list of text and numbers
 
(defun LM:splitstring ( str )
    (
        (lambda ( l )
            (read
                (strcat "("
                    (vl-list->string
                        (apply 'append
                            (mapcar
                                (function
                                    (lambda ( a b c )
                                        (cond
                                            (   (or (= 34 b) (= 92 b))
                                                (list 32 34 92 b 34 32)
                                            )
                                            (   (or (< 47 b 58)
                                                   ;(and (= 45 b) (< 47 c 58) (not (< 47 a 58)))
                                                    (and (= 46 b) (< 47 a 58) (< 47 c 58))
                                                )
                                                (list b)
                                            )
                                            (   (list 32 34 b 34 32))
                                        )
                                    )
                                )
                                (cons nil l) l (append (cdr l) '(( )))
                            )
                        )
                    )
                    ")"
                )
            )
        )
        (vl-string->list str)
    )
)
 
 
(vl-load-com) (princ) 
 

thanks

Title: Re: replace character in text file with lisp
Post by: JohnK on September 28, 2017, 12:21:11 PM

I understand your question but my problem is that I cannot read AutoLisp very well anymore (I'm not very good at it anymore because of lack of practice). But from what little I understand of your code I think you're making it too complicated -i.e. why are you sorting a list of chars? Operating on a smallest as possible list (a list of numbers for example) will make your operation faster. I would tackle this in a few steps like so:

1. Read the contents of the file into a list of lists.
2. Iterate through that list and convert to a list of ASCII numbers and search for a value that falls out of range (then replace if necessary).
3. OPTIONAL: do the search and replace here as separate process.
3./4. Convert list back to text and write back to file.

The logic being that searching for number falling outside a specific range is faster then comparing characters or strings.

I have *some* code but you'd have to be the judge of its value (Any autolisp code I have is very old; I wrote it years ago).

I hope that makes sense and what little I offered up helps you in some way. Sorry if it doesn't.

Code - Auto/Visual Lisp: [Select]

(defun file-get-list-from ( name / fp lst read-file-into-list )         ;;/*{{{*/
  ;; file-get-list-from
  ;;
  ;; GENERAL FILE READER
  ;; given a file name this procedure will read the contents
  ;; into a list
  ;;
  ;; EX:
  ;;    (mapcar
  ;;       'read (get-list-from-file
  ;;         (findfile layers-to-load-from-file)))
  ;;
  ;; By: John K
  ;;
(defun read-file-into-list ( str file )         ;;/*{{{*/
  (if str
    (cons
      (if str str)
      (read-file-into-list (read-line file) file))))    ;;/*}}}*/
  (setq fp (open name "R"))
  (setq lst (read-file-into-list (read-line fp) fp))
  (close fp)
 lst )       ;;/*}}}*/
 

Code - Auto/Visual Lisp: [Select]

(defun al-string-to-list (str / alst cntr)      ;;/*{{{*/
  ;; al-string-to-list
  ;;
  ;; Convert a string to a ascii number list of intigers
  ;;
  ;; Ex: (al-string-to-list "test")
  ;;   > (116 101 115 116)
  ;;
  ;; By: John K
  ;;
  (if (= cntr '()) (setq cntr 1))
  (while (<= cntr (strlen str))
    (setq alst (cons (ascii (substr str cntr 1)) alst)
          cntr (1+ cntr)))
  (reverse alst) )       ;;/*}}}*/

Code - Auto/Visual Lisp: [Select]

(defun al-list-to-string (strlist / strlst)     ;;/*{{{*/
  ;; al-list-to-string
  ;;
  ;; Convert a list of ascii numbers to a string
  ;;
  ;; Ex: (al-list-to-string '(116 101 115 116))
  ;;   > ("test")
  ;;
  ;; By: John K
  ;;
  (cond 
    ((eq (type StrList) 'LIST)
     (setq strlst "")
      (mapcar 
        '(lambda (x) (setq strlst (strcat strlst (chr x))))  
        strlist)
      )
     )
  strlst
  )     ;;/*}}}*/

Title: Re: replace character in text file with lisp
Post by: ribarm on September 28, 2017, 01:34:30 PM

I think OP wants revision of his already posted code... I (perhaps others) don't know though are those letters separate text/mtext entities that are independent and are placed near those blocks or they are bounded to those attributed blocks - perhaps those letters are attributes itself (I mean their textstrings)... It would be nice if OP would upload sample of his testing DWG with some of those block references...

Title: Re: replace character in text file with lisp
Post by: JohnK on September 28, 2017, 01:47:13 PM

The subject line says: "text file" so I thought it was just that, a text file.

Oh, I don't have the ability to edit anyone's AutoLisp code anymore. Maybe after a weekends hard study I can get back into the swing of things again--enough to scratch through some minor edits based on theory--but I don't really even have the desire to know AutoLisp anymore (I don't even have AutoCAD installed on my work machine).

Sorry, well, I tried.

Title: Re: replace character in text file with lisp
Post by: ronjonp on September 28, 2017, 02:34:20 PM

Quick glance, replace line 42 with this:

Code - Auto/Visual Lisp: [Select]

(write-line (vl-string-translate "Q" "R" (lm:lst->str (nth idx rtn) del)) des)

Be aware it's case sensitive.

Title: Re: replace character in text file with lisp
Post by: pedroantonio on September 28, 2017, 04:19:21 PM

Thank you :-)

Title: Re: replace character in text file with lisp
Post by: ronjonp on September 28, 2017, 04:23:10 PM

Quote from: Topographer on September 28, 2017, 04:19:21 PM

Thank you :)

You're welcome.

TheSwamp

Code Red => AutoLISP (Vanilla / Visual) => Topic started by: pedroantonio on September 28, 2017, 11:22:51 AM