TheSwamp
Code Red => AutoLISP (Vanilla / Visual) => Topic started by: jxphklibin on March 31, 2009, 03:16:45 AM
-
How to delete "" nil in the list (1245 "" "add" (1 "" 2 nil "" 3 5 "" nil 6 "" 8 . 9))
_$ (list 1245 "" nil "add" '(1 "" 2 nil "" 3 5 "" nil 6 "" 8 . 9))
(1245 "" "add" (1 "" 2 nil "" 3 5 "" nil 6 "" 8 . 9))
_$ (vl-list* 1 "" 2 NIL "" 3 5 "" NIL 6 "" 8 9)
(1 "" 2 nil "" 3 5 "" nil 6 "" 8 . 9)
-
not pretty, but seems to work ..
(setq myList (list 1245 "" nil "add" "" '(1 "" 2 nil "" 3 5 "" nil 6 "" 8.9))
string (vl-prin1-to-string myList)
pattern (vl-prin1-to-string "")
)
(while (setq index (vl-string-search pattern string 0))
(setq string (vl-string-subst "" pattern string))
)
(setq pattern (vl-prin1-to-string nil))
(while (setq index (vl-string-search pattern string 0))
(setq string (vl-string-subst "" pattern string))
)
(setq NewList (read string))
;;=> (1245 "add" (1 2 3 5 6 8.9))
-
oh, wait ..
[forestgump]
'pretty is as pretty does'
[/gump]
:)
-
Hi,
Another way
<EDIT>: corrected an error if some members of the last dotted pair have to be removed.
(defun nested-remove-if (fun lst / ele)
(if lst
(if (listp (cdr lst))
(if (atom (setq ele (car lst)))
(if (apply fun (list ele))
(nested-remove-if fun (cdr lst))
(cons ele (nested-remove-if fun (cdr lst)))
)
(list (nested-remove-if fun ele))
)
(if (apply fun (list (car lst)))
(if (not (apply fun (list (cdr lst))))
(cdr lst)
)
(if (apply fun (list (cdr lst)))
(list (car lst))
lst
)
)
)
)
)
_$ (setq lst '(1245 "" "add" (1 "" 2 nil "" 3 5 "" nil 6 "" 8 . 9)))
(1245 "" "add" (1 "" 2 nil "" 3 5 "" nil 6 "" 8 . 9))
_$ (n-remove-if '(lambda (x) (member x '("" nil))) lst)
(1245 "add" (1 2 3 5 6 8 . 9))
-
Gile's post gave the nudge I needed to get this one to work. Merci, Gile.
(defun ShouldIGo(x)
(if (member x '("" nil)) T nil)
)
(setq myList '(1245 "" nil "add" (1 "" 2 nil "" 3 5 "" nil 6 "" 8.9)))
(setq myNewList (vl-remove-if 'ShouldIGo (mapcar '(lambda (x) (if (listp x) (vl-remove-if 'ShouldIGo x) x)) myList)))
-
.... corrected an error if some members of the last dotted pair have to be removed.
...
Is that a dotted pair or a decimal number?
Mine will not work if it is a dotted pair
-
Is that a dotted pair or a decimal number?
Mine will not work if it is a dotted pair
In jxphklibin's list the nested list is a dotted list built with vl-list*, it's why I built my own recursive function instead of using a mapcar statement (it's needed to test if the last cdr is an atom or a list)
-
One would have to ask jxphklibin if the dotted list is your intention & for what pourpose.
-
Nice , Kerry Brown , gile.
Thanks!
I just find a way to deal with it, no intention & no pourpose. Since there is possible existence of the dotted list. At the same time, also let me know to delete the specified elements of the list (including nested list) in another way. You are very nice！Thanks again!!!
-
Hi,
Another way
<EDIT>: corrected an error if some members of the last dotted pair have to be removed.
(defun nested-remove-if (fun lst / ele)
(if lst
(if (listp (cdr lst))
(if (atom (setq ele (car lst)))
(if (apply fun (list ele))
(nested-remove-if fun (cdr lst))
(cons ele (nested-remove-if fun (cdr lst)))
)
(list (nested-remove-if fun ele))
)
(if (apply fun (list (car lst)))
(if (not (apply fun (list (cdr lst))))
(cdr lst)
)
(if (apply fun (list (cdr lst)))
(list (car lst))
lst
)
)
)
)
)
_$ (setq lst '(1245 "" "add" (1 "" 2 nil "" 3 5 "" nil 6 "" 8 . 9)))
(1245 "" "add" (1 "" 2 nil "" 3 5 "" nil 6 "" 8 . 9))
_$ (n-remove-if '(lambda (x) (member x '("" nil))) lst)
(1245 "add" (1 2 3 5 6 8 . 9))
Hi,gile
When the list is:
(list 1245 "" nil "add" "" (list 1 "" 2 nil "" 3 5 "" nil 6 "" 8 9 (list 888 888 "" nil 9999 9999 nil "") 555 "" nil 666) 777 "" nil 77777)
, then it doesn't work correctly! But Kerry Brown's work correctly!
-
Oopss
(defun nested-remove-if (fun lst / ele)
(if lst
(if (listp (cdr lst))
(if (atom (setq ele (car lst)))
(if (apply fun (list ele))
(nested-remove-if fun (cdr lst))
(cons ele (nested-remove-if fun (cdr lst)))
)
(cons (nested-remove-if fun ele)
(nested-remove-if fun (cdr lst))
)
)
(if (apply fun (list (car lst)))
(if (not (apply fun (list (cdr lst))))
(cdr lst)
)
(if (apply fun (list (cdr lst)))
(list (car lst))
lst
)
)
)
)
)
-
Forgive me but may i ask why are you removing the "NIL" from the lists, can't you just ignore them?
I ask because it seems like removing them would take more effort then need be.
-
(defun deflate ( x / a )
(cond
((atom x) x)
((null (vl-consp x)) (if (vl-every 'atom x)(vl-remove-if 'null x)(mapcar 'deflate x)))
((setq a (car x)) (cons (deflate a) (deflate (cdr x))))
((deflate (cdr x)))
)
)
Forgive me but may i ask why are you removing the "NIL" from the lists, can't you just ignore them?
I ask because it seems like removing them would take more effort then need be.
It's play time for nerds, get with the program.
-
> It's play time for nerds, get with the program.
*lol*
Here is mine i guess.
(setq mylist '(list ((1245 "" ((nil "add" (""))))) (list 1 "" 2 nil "" 3 5 "" nil 6 "" 8 9 (list 888 888 "" nil 9999 9999 nil "") 555 "" nil 666 777 "" nil) 77777))
(killer-n mylist "")
(defun killer-n (x a)
(if (atom x)
(if (not (eq a x)) x)
(vl-remove-if 'null
(cons (killer-n (car x) a)
(killer-n (cdr x) a)))))
-
my variant:
(defun f (l)
(cond ((null l) nil)
((atom l) (list l))
((listp l) (append (f (car l)) (f (cdr l))))
) ;_ cond
) ;_ defun
-
....
When the list is:
(list 1245 "" nil "add" "" (list 1 "" 2 nil "" 3 5 "" nil 6 "" 8 9 (list 888 888 "" nil 9999 9999 nil "") 555 "" nil 666) 777 "" nil 77777)
.....
Scope creep :-D
Back to my little drawing board
-
(defun killer-n (x a)
(if (atom x)
(if (not (eq a x)) x)
(vl-remove-if 'null
(cons (killer-n (car x) a)
(killer-n (cdr x) a)))))
Thanks for 'getting w/the program', :lol:. Unfortunately it crashes when using the original poster's data. :(
-
my variant:
(defun f (l)
(cond ((null l) nil)
((atom l) (list l))
((listp l) (append (f (car l)) (f (cdr l))))
) ;_ cond
) ;_ defun
Very pretty Evgeniy :), but flattens the list instead of merely removing the nils :oops:.
-
I have not truly understood a problem, I am corrected...
(defun f (l)
(if l
(if (listp l)
(if (car l)
(cons (f (car l)) (f (cdr l)))
(f (cdr l))
) ;_ if
l
) ;_ if
) ;_ if
)
-
variant 2:
(defun f (l)
(cond ((not l) nil)
((atom l) l)
((and (listp l) (car l)) (cons (f (car l)) (f (cdr l))))
((f (cdr l)))
) ;_ cond
)
-
Thanks for 'getting w/the program', :lol:. Unfortunately it crashes when using the original poster's data. :(
*Ack* i didnt see that dot. I'll get back to it when i put out a fire or two.
Your right, nice puzzle.
-
Very nicely done Evgeniy: both variants 1 & 2.
-
variant 2:
(defun f (l)
(cond ((not l) nil)
((atom l) l)
((and (listp l) (car l)) (cons (f (car l)) (f (cdr l))))
((f (cdr l)))
) ;_ cond
)
Can be reduced to:
(defun f (l)
(cond
((null l) nil)
((atom l) l)
((car l) (cons (f (car l)) (f (cdr l))))
((f (cdr l)))
)
)
:)
-
Can be reduced to:
(defun f (l)
(cond
((null l) nil)
((atom l) l)
((car l) (cons (f (car l)) (f (cdr l))))
((f (cdr l)))
)
)
Very nicely reduced.
Excellent work!
:)
-
Not only does the OP want to remove nil but also "" 8-)
-
Not only does the OP want to remove nil but also "" 8-)
lol, missed that salient point.
Evgeny's would be easy to modify to suit, but revising my own submission:
(defun deflate ( x / a )
(cond
((atom x) x)
((null (vl-consp x)) (if (vl-every 'atom x)(vl-remove-if 'null x)(mapcar 'deflate x)))
((and (setq a (car x))(/= a "")) (cons (deflate a) (deflate (cdr x))))
((deflate (cdr x)))
)
)
-
Here's a more generic function using Evgeny's submission as a starting point:
(defun remove_all ( x lst / a )
(cond
((member x lst) nil)
((atom x) x)
((member (setq a (car x)) lst) (remove_all (cdr x) lst))
((cons (remove_all a lst) (remove_all (cdr x) lst)))
)
)
(setq lst '(1245 "" "add" (1 "" 2 nil "" 3 5 "" nil 6 "" 8 . 9)))
(remove_all lst '(nil ""))
=> (1245 "add" (1 2 3 5 6 8 . 9))
I reserve the right to reverse the order of the arguments; at present doesn't feel right, but gotta get back to work.
-
Now named properly, and arguments in proper order (in my mind anyway): :ugly:
(defun remove_items ( items lst / a )
(cond
((member lst items) nil)
((atom lst) lst)
((member (setq a (car lst)) items) (remove_items items (cdr lst)))
((cons (remove_items items a) (remove_items items (cdr lst))))
)
)
(setq lst '(1245 "" "add" (1 "" 2 nil "" 3 5 "" nil 6 "" 8 . 9)))
(remove_items '(nil "") lst)
=> (1245 "add" (1 2 3 5 6 8 . 9))
-
More generic, using a predicate function
(defun nest-remove-if (fun lst / a )
(cond
((apply fun (list lst)) nil)
((atom lst) lst)
((apply fun (list (setq a (car lst)))) (nest-remove-if fun (cdr lst)))
((cons (nest-remove-if fun a) (nest-remove-if fun (cdr lst))))
)
)
_$ (setq lst (list 1245 "" nil "add" "" '(1 "" 2 nil "" 3 5 "" nil 6 "" 8 . 9)))
(1245 "" nil "add" "" (1 "" 2 nil "" 3 5 "" nil 6 "" 8 . 9))
_$ (nest-remove-if '(lambda (x) (member x '("" nil))) lst)
(1245 "add" (1 2 3 5 6 8 . 9))
_$ (nest-remove-if 'numberp lst)
("" nil "add" "" ("" nil "" "" nil ""))
-
after seeing the last functions posted.... I start to remember the x-arch or reni urban site days.... they look to close (and I am not saying that were copied eh!) :)
-
yeah most of those are pretty killer. After taking care of some things here i dont even want to continue with mine (i would just embarrass myself).
-
Nice , Kerry Brown , gile.
Thanks!
I just find a way to deal with it, no intention & no pourpose. Since there is possible existence of the dotted list. At the same time, also let me know to delete the specified elements of the list (including nested list) in another way. You are very nice！Thanks again!!!
You're welcome jx'
Now that you have several answers, can you explain why you want to remove the items from the list.
Usually the items in a list are EXPECTED to be in a certain order .. with "" indicating a null string and nil indicating a null value.
It seemed to me at first thought that removing the items would ruin the possibility of any further referencing of items in the list.
Regards
Kerry Brown
-
Nice , Kerry Brown , gile.
Thanks!
I just find a way to deal with it, no intention & no pourpose. Since there is possible existence of the dotted list. At the same time, also let me know to delete the specified elements of the list (including nested list) in another way. You are very nice！Thanks again!!!
You're welcome jx'
Now that you have several answers, can you explain why you want to remove the items from the list.
Usually the items in a list are EXPECTED to be in a certain order .. with "" indicating a null string and nil indicating a null value.
It seemed to me at first thought that removing the items would ruin the possibility of any further referencing of items in the list.
Regards
Kerry Brown
I am sorry,this is my first meeting by my codes as follows:
;; By 木子CAD工具 小李子 2009-3-28
(defun AllBlkNInBlkdef (blkn / blkdef e typ bn bnl e-l nl)
(setq blkdef (tblobjname "block" blkn))
(while (setq e (entnext blkdef))
(setq typ (cdr (assoc 0 (entget e))))
(if (= typ "INSERT")
(setq bn (vla-get-name (vlax-ename->vla-object e))
bnl (if bn
(cons ;;(if (setq nl (AllBlkNInBlkdef bn))
(list bn nl)
;;bn
;;)
bnl
)
)
)
)
(setq blkdef e)
)
bnl
)
(defun c:ABnInBl (/ i en ss blknlst ABblknlst)
(if (setq ss (ssget '((0 . "INSERT"))))
(repeat (setq i (sslength ss))
(setq en (ssname ss (setq i (1- i)))
blkn (vla-get-name (vlax-ename->vla-object en))
blknlst (AllBlkNInBlkdef blkn)
ABblknlst (cons ;;(if blknlst
(list blkn blknlst)
;;blkn
;;)
ABblknlst
)
)
)
(princ "*** 你没有选择任何图块 ***")
)
(princ ABblknlst)
(princ)
)
Later, I modified the code as shown below, this situation does not appear.
;; By 木子CAD工具 小李子 2009-3-28
(defun AllBlkNInBlkdef (blkn / blkdef e typ bn bnl e-l nl)
(setq blkdef (tblobjname "block" blkn))
(while (setq e (entnext blkdef))
(setq typ (cdr (assoc 0 (entget e))))
(if (= typ "INSERT")
(setq bn (vla-get-name (vlax-ename->vla-object e))
bnl (if bn
(cons (if (setq nl (AllBlkNInBlkdef bn))
(list bn nl)
bn
)
bnl
)
)
)
)
(setq blkdef e)
)
bnl
)
(defun c:ABnInBl (/ i en ss blknlst ABblknlst)
(if (setq ss (ssget '((0 . "INSERT"))))
(repeat (setq i (sslength ss))
(setq en (ssname ss (setq i (1- i)))
blkn (vla-get-name (vlax-ename->vla-object en))
blknlst (AllBlkNInBlkdef blkn)
ABblknlst (cons (if blknlst
(list blkn blknlst)
blkn
)
ABblknlst
)
)
)
(princ "*** 你没有选择任何图块 ***")
)
(princ ABblknlst)
(princ)
)
-
Code was prepared, So I thought, if the nested list also includes a dotted list,and I try,it doesn't work. And then......：
(defun RemoveItem (item lst)
(mapcar '(lambda (x) (if (vl-consp x) (RemoveItem item x) x))
(vl-remove item lst)
)
)
;; or
(defun RemoveItem (item lst)
(mapcar '(lambda (x) (if (listp x) (RemoveItem item x) x))
(vl-remove item lst)
)
)
;; or:
(defun RemoveItem (item lst)
(mapcar '(lambda (x) (if (atom x) x (RemoveItem item x)))
(vl-remove item lst)
)
)
;; and:
(defun RemoveItem (item lst / x tmplst)
(foreach x (vl-remove item lst)
(if (atom x)
(setq tmplst (cons x tmplst))
(setq tmplst (cons (RemoveItem item x) tmplst))
)
)
(reverse tmplst)
)
-
Hi,gile
The efficiency of your function is too low, and the following two functions are the implementation of speed compared to the results from the comparison, it is obvious that the difference.
(defun nest-remove-if (fun lst / a )
(cond
((apply fun (list lst)) nil)
((atom lst) lst)
((apply fun (list (setq a (car lst)))) (nest-remove-if fun (cdr lst)))
((cons (nest-remove-if fun a) (nest-remove-if fun (cdr lst))))
)
)
(defun RemoveItem (pattern mylist / string index newlist)
(setq string (vl-prin1-to-string myList)
pattern (vl-prin1-to-string pattern)
)
(while (setq index (vl-string-search pattern string 0))
(setq string (vl-string-subst "" pattern string))
)
(read string)
;;(setq NewList (read string))
)
;; 测试效率
(defun c:test ( / lst t0)
(setq lst (list 121 "" nil
(list "abc" "" (list 777 888 '("aaa" 8888 nil "" 999 . 9) 999) "dde" "" 111)
"aaa" "" 999 000
(list 88 "" 9090 "" "" "AAA" "BBB" ""
(list "ccc" "" "DDD" "" 123 '( 222 "" nil 333 . 66666))
)
"" 55555555 nil "TTTTTT" '(44444 nil 585858 "" . 6666) "PPPPPPPP" "" nil "" "fffff" "" nil ""
)
)
(setq t0 (getvar "TDUSRTIMER"))
(repeat 1000
(nest-remove-if '(lambda (x) (member x '("" nil))) lst)
)
(princ "\n用时")
(princ (* (- (getvar "TDUSRTIMER") t0) 86400))
(princ "秒")
(setq t0 (getvar "TDUSRTIMER"))
(repeat 1000
(RemoveItem "" lst)
(RemoveItem nil lst)
;;(foreach x '("" nil) (setq lst (RemoveItem x lst)))
)
(princ "\n用时")
(princ (* (- (getvar "TDUSRTIMER") t0) 86400))
(princ "秒")
(princ)
) ;|
_$ (c:test)
用时8.375秒
用时0.344秒
_$ (c:test)
用时8.219秒
用时0.359秒
_$
|;
-
(defun RemoveItem (pattern mylist / string index newlist)
(setq string (vl-prin1-to-string myList)
pattern (vl-prin1-to-string pattern)
)
(while (setq index (vl-string-search pattern string 0))
(setq string (vl-string-subst "" pattern string))
)
(read string)
;;(setq NewList (read string))
)
Oh, I just found that it should not deal with the LIST contains REAL number With vl-prin1-to-string :
(setq A pi)
(setq B (RemoveItem nil (list 1 nil A)))
(/= A (cadr B))--->T
-
More generic, using a predicate function
(defun nest-remove-if (fun lst / a )
(cond
((apply fun (list lst)) nil)
((atom lst) lst)
((apply fun (list (setq a (car lst)))) (nest-remove-if fun (cdr lst)))
((cons (nest-remove-if fun a) (nest-remove-if fun (cdr lst))))
)
)
_$ (setq lst (list 1245 "" nil "add" "" '(1 "" 2 nil "" 3 5 "" nil 6 "" 8 . 9)))
(1245 "" nil "add" "" (1 "" 2 nil "" 3 5 "" nil 6 "" 8 . 9))
_$ (nest-remove-if '(lambda (x) (member x '("" nil))) lst)
(1245 "add" (1 2 3 5 6 8 . 9))
_$ (nest-remove-if 'numberp lst)
("" nil "add" "" ("" nil "" "" nil ""))
Thanks for sharing,gile
I like it. "fun" agrument is funny! Good job!
-
only nil...
:-)
(defun f (l)
(cond
((atom l) l)
((car l) (cons (f (car l)) (f (cdr l))))
((f (cdr l)))
)
)
-
my little contribution...
(while (vl-string-search "nil" (setq lt (vl-prin1-to-string l)))
(setq l (read (vl-string-subst "" "nil " lt)))
)
or..
(read (acet-str-replace "nil" "" (vl-prin1-to-string l) t))