Topic: need some suggestions on converting string to list

[andrew_nao]

sorry for the title, i wasnt sure on what to name it.

im converting a string to a list using Alanjt's code listed here (thank you)
http://www.theswamp.org/index.php?topic=32845.0

im using a space as the separator, however if the item is a dimension like 6 1/2" and using the separator splits that into 2 list items, what can i do to not separate dimensions like that but still use the space as a separator to split my string into a list.. or is this just not possible?

[Lee Mac]

I'm guessing this is related to this task:

http://www.theswamp.org/index.php?topic=41407.0

[andrew_nao]

yes Lee, it is but new topic

[Lee Mac]

Did Irneb not solve your problem?

[andrew_nao]

Did Irneb not solve your problem?

no ones really did. i have too many different scenarios for any of that to work. even the old code i was using didnt work properly.
so im starting over by breaking down a string to list then taking the number, converting it, then adding it back into the list and then convert the list back to a string.
thats the plan anyway

[irneb]

Could you state a sample string? You'd probably need to find some way of distinguishing where the measurement starts and/or stops.

Another way could be to use the code I added here: http://www.theswamp.org/index.php?topic=41407.msg465217#msg465217

In particular the ExtractImperial function. That would extract only the dimension portion from the string. Thereafter you could split the string at the point where you find that and perform the normal str2lst idea on the 2 sides. Then simply an append.

The basis for this idea is contained in that thread as well. I mean the AddMetric method uses the string returned from ExtractImperial to search for the position in the original string - it simply uses vl-string-subst. You could use vl-string-search in the same way.

[irneb]

I cannot figure why it "won't" work for you. Here's what I mean:

Code - Auto/Visual Lisp: [Select]

1. (vl-load-com)
2.  
3. (defun ExtractImperial  (str / len n m c res)
4.   (setq n 0 len (strlen str) res "")
5.   (while (and (not (wcmatch res "*#',*#\"")) (< n len))
6.     (while (and (<= (setq n (1+ n)) len) (not (wcmatch (substr str n 1) "[0-9]"))))
7.     (setq m 0)
8.     (while (and (<= (+ n (setq m (1+ m))) (1+ len)) (not (wcmatch (substr str n m) "*[~-'0-9/\" ]*"))))
9.     (setq res (vl-string-trim " /-" (substr str n (1- m))) n (+ n m)))
10.   (if (wcmatch res "*#',*#\"") res ""))
11.  
12. (defun str2lst (str / left dim pos split)
13.   (defun split (str / )
14.     (setq str (vl-string-translate " " "\002" (vl-string-trim " " str)))
15.     (while (wcmatch str "*\002*") (setq str (vl-string-subst "\" \"" "\002" str)))
16.     (read (strcat "(\"" str "\")")))
17.   (vl-remove-if '(lambda (a) (eq a ""))
18.     (if (not (eq (setq dim (ExtractImperial str)) ""))
19.       (append (split (substr str 1 (setq pos (vl-string-search dim str)))) (list dim)
20.               (str2lst (substr str (+ 1 pos (strlen dim)))))
21.       (split str))))

Some test cases:

Code: [Select]

_$ (str2lst "Test Test Test 6'-5 2/3\"")
("Test" "Test" "Test" "6'-5 2/3\"")
_$ (str2lst "6'-5 2/3\"")
("6'-5 2/3\"")
_$ (str2lst "6'-5 2/3\" test test")
("6'-5 2/3\"" "test" "test")
_$ (str2lst "6'-5 2/3\"test test")
("6'-5 2/3\"" "test" "test")
_$ (str2lst "test6'-5 2/3\"test test")
("test" "6'-5 2/3\"" "test" "test")
_$ (str2lst "test 6'-5 2/3\" test test6'-5 2/3\"test test")
("test" "6'-5 2/3\"" "test" "test" "6'-5 2/3\"" "test" "test")
_$ (str2lst "Test Test Test 6'-5 2/3\" test")
("Test" "Test" "Test" "6'-5 2/3\"" "test")

[andrew_nao]

Could you state a sample string? You'd probably need to find some way of distinguishing where the measurement starts and/or stops.

yes i can. something like
four (4) @ 14 1/2" 90%%d apart

your coding works otherwise its when you throw the least expected string in there it doesnt convert.

i guess thats where i would need to find where the measure starts n stops

[andrew_nao]

i need to just separate the dimension and any number after it with a dash or a comma.   then it works.

i guess theses old dogs will just have to learn a new trick and change the way they do things

[andrew_nao]

spoke to soon

2 5/8" O.D. x 1 5/16" I.D.
it results in

2 5/8" (67mm) O.D. x 1 5/16" I.D.

leaves out the 1 5/16"

there is always something... 

[irneb]

Ok, I thought that regular expressions should be used here. Seems it's not just more efficient, but also a lot more comprehensive.

I'm using the RX:Search function from my code here: http://caddons.svn.sourceforge.net/viewvc/caddons/Libraries/RegExp.LSP?revision=62&view=markup

Some tests:

Code: [Select]

_$ (RX:Search "four (4) @ 14 1/2\" 90%%d apart" "((\\d+'[ -]\\d \\d+/\\d+\")|(\\d+'[ -]\\d\")|(\\d+')|(\\d+ \\d+/\\d+\")|(\\d+/\\d+\"))")
((11 . "14 1/2\""))
_$ (RX:Search "2 5/8\" O.D. x 1 5/16\" I.D." "((\\d+'[ -]\\d \\d+/\\d+\")|(\\d+'[ -]\\d\")|(\\d+')|(\\d+ \\d+/\\d+\")|(\\d+/\\d+\"))")
((0 . "2 5/8\"") (14 . "1 5/16\""))The 1st number is the start index where the pattern was found, the string is the portion matching the pattern. That would make it simpler to use substr to split the string into it's portions.

[irneb]

Sorry the regular expression search pattern should be changed to allow for the case where there's only an inch number shown (no feet and no fractions):

"((\\d+'[ -]\\d \\d+/\\d+\")|(\\d+'[ -]\\d\")|(\\d+')|(\\d+ \\d+/\\d+\")|(\\d+/\\d+\")|(\\d+\"))"

[irneb]

Here's the AddMetric function - using the RX:Search:

Code: [Select]

(defun AddMetric (str /)
  (foreach val (reverse (RX:Search str "((\\d+'[ -]\\d \\d+/\\d+\")|(\\d+'[ -]\\d\")|(\\d+')|(\\d+ \\d+/\\d+\")|(\\d+/\\d+\")|(\\d+\"))"))
    (setq str (vl-string-subst (strcat (cdr val) " (" (rtos (cvunit (distof (cdr val) 4) "inch" "mm") 2 0) "mm)") (cdr val) str (car val))))
  str)
Seems to work fine now:

Code: [Select]

_$ (AddMetric "four (4) @ 14 1/2\" 90%%d apart")
"four (4) @ 14 1/2\" (368mm) 90%%d apart"
_$ (AddMetric "2 5/8\" O.D. x 1 5/16\" I.D.")
"2 5/8\" (67mm) O.D. x 1 5/16\" (33mm) I.D."
_$ (AddMetric "5'-2 5/8\" O.D. x 1 5/16\" I.D.")
"5'-2 5/8\" (1591mm) O.D. x 1 5/16\" (33mm) I.D."
_$ (AddMetric "5' 2 5/8\" O.D. x 1 5/16\" I.D.")
"5' 2 5/8\" (1591mm) O.D. x 1 5/16\" (33mm) I.D."
_$ (AddMetric "12'-6\"")
"12'-6\" (3810mm)"
_$ (AddMetric "12'-6\" dia circle")
"12'-6\" (3810mm) dia circle"
_$ (AddMetric "this is a 12'-6 1/2\" dia circle")
"this is a 12'-6 1/2\" (3823mm) dia circle"
_$ (AddMetric "this is a 12' dia circle")
"this is a 12' (3658mm) dia circle"

[andrew_nao]

it seems that if i use your search function from the link you gave, i need the rest of the functions also for it to work? it keeps asking for the other functions of your code to use the search function... or am i missing something in the translation?

[andrew_nao]

ok so i think i figured this out, however it doesnt work for me like it did you

Command: (addmetric "2 5/8\" O.D. x 1 5/16\" I.D.")
"2 5/8\" (67mm) O.D. x 1 5/16\" I.D."


here is the code i have

Code: [Select]

;; conversion code by irneb from theswamp.org

(defun RX:Search (string pattern / lst col item)

   ;(if (RX:Start)
     ;(progn
       (vlax-Put *RX-Link* 'Pattern pattern) ;Set the pattern to match
       ;; Get the collection of match objects
       (setq col (vl-catch-all-apply 'vlax-Invoke (list *RX-Link* 'Execute string)))
       (if (not (vl-catch-all-error-p col))
         (progn
          ;; Loop through collection & place into return list
           (vlax-for item col
             ;; Get the position & length
             (setq lst (cons (cons (vlax-Get item 'FirstIndex) (vlax-Get item 'Value)) lst))
             (vlax-release-object item) ;Release the match object
           ) ;_ end of while
          (vlax-release-object col) ;Release the collection object
         ) ;_ end of progn
      ) ;_ end of if
       (reverse lst) ;Return list in correct order
     ;) ;_ end of progn
   ;) ;_ end of if
) ;_ end of defun
 


(defun ExtractImperial (str / len n m c res)
  (setq n 0 len (strlen str) res "")
  (while (and (not (wcmatch res "*#',*#\"")) (< n len))
    (while (and (<= (setq n (1+ n)) len) (not (wcmatch (substr str n 1) "[0-9]"))))
    (setq m 0)
    (while (and (<= (+ n (setq m (1+ m))) (1+ len)) (not (wcmatch (substr str n m) "*[~-'0-9/\" ]*"))))
    (setq res (vl-string-trim " /-" (substr str n (1- m))) n (+ n m)))
  (if (wcmatch res "*#',*#\"") res "")
)

(defun AddMetric (str /)
  (foreach val (reverse
  (RX:Search str "((\\d+'[ -]\\d \\d+/\\d+\")|(\\d+'[ -]\\d\")|(\\d+')|(\\d+ \\d+/\\d+\")|(\\d+/\\d+\")|(\\d+\"))"))
    (setq str (vl-string-subst (strcat (cdr val) " (" (rtos (cvunit (distof (cdr val) 4) "inch" "mm") 2 0) "mm)") (cdr val) str (car val)))) str)

; code from me
(DEFUN C:test ()

;
;; GET ENTITY
;
       (SETQ MT (ENTSEL "\nPLEASE PICK DESIRED TEXT"))
       (SETQ MTED (ENTGET (CAR MT)))
       (SETQ MTLL (ASSOC '1 MTED))
       (SETQ MTT (CDR MTLL))
   (setq MTT (addmetric MTT))
(SETQ TLN (CONS 1 MTT))
(SETQ TLNN (SUBST TLN MTLL MTED))
(ENTMOD TLNN)
(PRINC)
)


[andrew_nao]

now its not working

tried on a new dwg
PLEASE PICK DESIRED TEXT; error: bad argument type: VLA-OBJECT nil

[irneb]

it seems that if i use your search function from the link you gave, i need the rest of the functions also for it to work? it keeps asking for the other functions of your code to use the search function... or am i missing something in the translation?

Yes you are correct, you need an absolute minimum of the RX:Search, RX:Start & RX:Set functions to be loaded in order to use my regular expression library. Fore ease, here's the 3 defuns:

Code - Auto/Visual Lisp: [Select]

1. (vl-load-com)
2.  
3. ;;; -------------------------------------------------------------------------------------
4. ;;; Get a reference to the Regular Expression Object object
5. ;;; -------------------------------------------------------------------------------------
6. ;;; Result: a vla object for the regular expression tools
7. ;;; -------------------------------------------------------------------------------------
8. (defun RX:Start (/)
9.   (if (or (not *RX-Link*)
10.           (not (setq *RX-Link* (vl-bb-ref '*RX-Link*)))
11.           (vlax-object-released-p *RX-Link*)
12.       ) ;_ end of or
13.     (progn
14.       (vl-bb-set '*RX-Link* (setq *RX-Link* (vlax-get-or-create-object "VBScript.RegExp")))
15.       (RX:Set t t t)
16.     ) ;_ end of progn
17.   ) ;_ end of if
18.   *RX-Link*
19. ) ;_ end of defun
20.  
21. ;;; -------------------------------------------------------------------------------------
22. ;;; Change settings for regexp
23. ;;; -------------------------------------------------------------------------------------
24. ;;; Arguments:
25. ;;; multiline  = nil -> Stop- / t -> Don't stop at line ends
26. ;;; global     = nil -> only find 1st occurence; t -> find all occurences
27. ;;; ignorecase = nil -> case sensitive; t -> case insensitive
28. ;;; -------------------------------------------------------------------------------------
29. ;;; Result: undefined
30. ;;; -------------------------------------------------------------------------------------
31. (defun RX:Set (multiline global ignorecase)
32.   (if *RX-Link*
33.     (progn
34.       (vlax-put *RX-Link*
35.                 'Multiline
36.                 (if multiline
37.                   -1
38.                   0
39.                 ) ;_ end of if
40.       ) ;_ end of vlax-put
41.       (vlax-put *RX-Link*
42.                 'Global
43.                 (if global
44.                   -1
45.                   0
46.                 ) ;_ end of if
47.       ) ;_ end of vlax-put
48.       (vlax-put *RX-Link*
49.                 'IgnoreCase
50.                 (if ignorecase
51.                   -1
52.                   0
53.                 ) ;_ end of if
54.       ) ;_ end of vlax-put
55.     ) ;_ end of progn
56.   ) ;_ end of if
57. ) ;_ end of defun
58.  
59. ;;; -------------------------------------------------------------------------------------
60. ;;; Find positions matching the pattern in the string
61. ;;; -------------------------------------------------------------------------------------
62. ;;; Arguments:
63. ;;; string      = The string to search through
64. ;;; pattern     = The regular expression patter to search for
65. ;;; -------------------------------------------------------------------------------------
66. ;;; Result: A list containing dotted pairs of (Position . Value)
67. ;;; -------------------------------------------------------------------------------------
68. ;;; Example
69. ;;; (RX:Search "\"Test,6\",34,45.6,\"48\"" "(\\s*\"[^\"]*\"\s*,)|(\\s*[^,]*\\s*,)")
70. ;;; Will return a list containing the positions & values after parsing the CVS string.
71. ;;; ((0 . "\"Test,6\",") (9 . "34,") (12 . "45.6,"))
72. ;;; -------------------------------------------------------------------------------------
73. (defun RX:Search (string pattern / lst col item)
74.   (if (RX:Start)
75.     (progn
76.       (vlax-Put *RX-Link* 'Pattern pattern) ;Set the pattern to match
77.       ;; Get the collection of match objects
78.       (setq col (vl-catch-all-apply 'vlax-Invoke (list *RX-Link* 'Execute string)))
79.       (if (not (vl-catch-all-error-p col))
80.         (progn
81.           ;; Loop through collection & place into return list
82.           (vlax-for item col
83.             ;; Get the position & length
84.             (setq lst (cons (cons (vlax-Get item 'FirstIndex) (vlax-Get item 'Value)) lst))
85.             (vlax-release-object item) ;Release the match object
86.           ) ;_ end of while
87.           (vlax-release-object col) ;Release the collection object
88.         ) ;_ end of progn
89.       ) ;_ end of if
90.       (reverse lst) ;Return list in correct order
91.     ) ;_ end of progn
92.   ) ;_ end of if
93. ) ;_ end of defun

As for the VLA-OBJECT nil error, ensure that vl-load-com is called at least once somewhere in your code. The Regular Expression functions uses the VBScripting RegExp ActiveX library - and you can only use that if the visual lisp com interface is loaded.

It seems to work fine for me with this code:

Code - Auto/Visual Lisp: [Select]

1. (defun AddMetric (str /)
2.   (foreach val (reverse (RX:Search str "((\\d+'[ -]\\d \\d+/\\d+\")|(\\d+'[ -]\\d\")|(\\d+')|(\\d+ \\d+/\\d+\")|(\\d+/\\d+\")|(\\d+\"))"))
3.     (setq str (vl-string-subst (strcat (cdr val) " (" (rtos (cvunit (distof (cdr val) 4) "inch" "mm") 2 0) "mm)") (cdr val) str (car val))))
4.   str)
5.  
6. (defun c:AddMetric (/ ss str)
7.   (if (and (ssget '((0 . "TEXT,MTEXT")))
8.            (setq ss (vla-get-ActiveSelectionSet (vla-get-ActiveDocument (vlax-get-acad-object)))))
9.     (progn
10.       (vlax-for eo ss
11.         (setq str (AddMetric (vla-get-TextString eo)))
12.         (if (not (eq str (vla-get-TextString eo)))
13.           (vla-put-TextString eo str)))
14.       (vla-Delete ss)))
15.   (progn))

[andrew_nao]

got it working, i was missing the vl-load-com

super thanks irneb, much appreciated

[irneb]

Glad you got it working finally. 

[andrew_nao]

ive spoken to soon again


example:
EL. 123'-10"
results in
EL. 123' (37490mm)-10" (254mm)

would this have something to do with the rs:search function inside the addmetric function?


fixed... had to add this in the search
(\\d+'[- ]\\d\\d+ \\d+/\\d+\")|(\\d+'[- ]\\d\\d+\")

[irneb]

Awesome! Glad you could figure out those RegExp codes!

Though my RegExp.LSP contains a comment at the end describing the special characters, I find it useful to search through these 2 sites for some tricks:
http://www.regular-expressions.info/examples.html
http://regexlib.com/?AspxAutoDetectCookieSupport=1