Topic: Error when run lisp on newfile

[HasanCAD]

When run this lisp on a new file comes error
Put in Old file works great

Code: [Select]

Command: OPL
 click first corner
 click second corner; error: Automation Error. Key not found
I belive that it is beacuse of MakeLayer subroutine but do not know why. 

Code - Auto/Visual Lisp: [Select]

1. ;|------------ Opening Lines -------------------
2.             q_|_|| _\|| q_|| _\|               
3.                                                
4.   To add rectangle and crossing lines to show  
5.   opening                                      
6. ------------------------------------------------
7.   Author: Hasan M. Asous, 2013                 
8.         ALL RIGHT RESERVED TO ALL              
9.                                                
10.   Contact: HasanCAD @ TheSwamp.org,            
11.            asos2000 @ CADTutor.net             
12.            HasanCAD@gmail.com                  
13. ------------------------------------------------
14.   Version: 1      2014 05 18                   
15. ________________________________________________
16.                                               |;
17.  
18.  
19.         ;     q_|_|| _\|| q_|| _\|     ;
20.         ;       Mainroutine Start      ;
21.  
22. (defun c:OpeningLines () (c:opl))
23. (defun c:opl ( / clyr l o ortmd p1 p2 p3 p4 ) (vl-load-com)
24.   (setq doc (vla-get-ActiveDocument (setq *acad (vlax-get-Acad-Object)))
25.         spc (if (zerop (vla-get-activespace doc)) (if (= (vla-get-mspace doc) :vlax-true) (vla-get-modelspace doc) (vla-get-paperspace doc)) (vla-get-modelspace doc)))
26.  
27.   (mapcar '(lambda ( a b c d ) (MakeLayer a b "Continuous" c T 0 d))
28.           '("S-OPEN" "S-OPEN-PATT" "S-SLAB-EDGE" "S-STRS-ELEV" "S-STRS-STEP" "S-STRS-IARO")
29.           '(3 1 4 1 212 1)
30.           '(0.3 0.09 0.4 0.15 0.3 0.25)
31.           '("STRUCTURAL OPENING" "STRUCTURAL OPENING HATCH" "EDGE OF SLAB" "STAIR ELEVATION" "STAIR STEP" "INTERNAL STAIR ARROWS")
32.           )
33.  
34.   (while
35.     (if (and (setq p1 (getpoint "\n click first corner"))
36.              (setq ortmd (getvar "orthomode"))
37.              (setvar "orthomode" 0)
38.              (setq p2 (getcorner p1 "\n click second corner"))
39.              (setvar "orthomode" ortmd)
40.              )
41.       (progn
42.         (setq p1 (trans p1 1 0 )
43.               p2 (trans p2 1 0 )
44.               p1X (min (nth 0 p1) (nth 0 p2))
45.               p1Y (min (nth 1 p1) (nth 1 p2))
46.               p2X (max (nth 0 p1) (nth 0 p2))
47.               p2Y (max (nth 1 p1) (nth 1 p2))
48.               )
49.         (setq p1 (list p1X p1Y 0)
50.               p2 (list p2X p2Y 0)
51.               p3 (list p2X p1Y 0)
52.               p4 (list p1X p2Y 0)
53.               ptlist (list p1 p3 p2 p4)
54.               ptlist (apply 'append ptlist)
55.               )
56.         (setq tmp (vlax-make-safearray vlax-vbDouble (cons 0 (- (length ptlist) 1))))
57.         (vlax-safearray-fill tmp ptlist)
58.         (setq obj (vla-addPolyline spc tmp))
59.         (vla-put-closed obj :vlax-true)
60.         (vla-put-layer obj "S-OPEN")
61.         (vla-put-color OBJ 256)
62.         (makeline p1 p2 "Continuous" "S-OPEN-PATT")
63.         (makeline p3 p4 "Continuous" "S-OPEN-PATT")
64.         )
65.       )))
66.  
67. (princ)
68. (princ "\n      q_|_|| _\\|| q_|| _\\|")
69. (princ "\n  Type  OPL  to invoke the lisp ")
70.  
71.         ;     q_|_|| _\|| q_|| _\|     ;
72.         ;       Mainroutine End        ;
73.  
74.  
75.         ;     q_|_|| _\|| q_|| _\|     ;
76.         ;       Subroutine Start       ;
77.  
78. (defun MakeLayer ( name colour linetype lineweight willplot bitflag description )
79.     ;; (MakeLayer name colour linetype lineweight willplot bitflag description )
80.     ;; Specifications:
81.     ;; Description        Data Type        Remarks
82.     ;; -----------------------------------------------------------------
83.     ;; Layer Name          STRING          Only standard chars allowed                 
84.     ;; Layer Colour        INTEGER         may be nil, -ve for Layer Off, Colour < 256 
85.     ;; Layer Linetype      STRING          may be nil, If not loaded, CONTINUOUS.      
86.     ;; Layer Lineweight    REAL            may be nil, 0 <= x <= 2.11                  
87.     ;; Plot?               BOOLEAN         T = Plot Layer, nil otherwise               
88.     ;; Bit Flag            INTEGER         0=None, 1=Frozen, 2=Frozen in VP, 4=Locked  
89.     ;; Description         STRING          may be nil for no description               
90.     ;; Function will return list detailing whether layer creation is successful.       
91.     ;; © Lee Mac 2010
92.  
93.   (or (tblsearch "LAYER" name)
94.     (entmake
95.       (append
96.         (list
97.           (cons 0       "LAYER")
98.           (cons 100     "AcDbSymbolTableRecord")
99.           (cons 100     "AcDbLayerTableRecord")
100.           (cons 2       name)
101.           (cons 70      bitflag)
102.           (cons 290     (if willplot 1 0))
103.           (cons 6       (if (and linetype (tblsearch "LTYPE" linetype)) linetype "CONTINUOUS"))
104.           (cons 62      (if (and colour (< 0 (abs colour) 256)) colour 7))
105.           (cons 370     (fix (* 100 (if (and lineweight (<= 0.0 lineweight 2.11)) lineweight 0.0))))
106.           )
107.         (if description (list (list -3 (list "AcAecLayerStandard" (cons 1000 "") (cons 1000 description)))))
108.         ))))
109.  
110. (defun makeline (str end Ltp lyr )
111.   (entmake (list (cons 0 "LINE")        ; ***
112.                (cons 6 Ltp)             ; Linetype name (present if not BYLAYER)
113.                (cons 8 lyr)             ; Layer
114.                (cons 10 str)            ; Start Point
115.                (cons 11 end)            ; End Point
116.                (cons 39 0.0)            ; Thickness (optional) default = 0
117.                (cons 62 256)            ; Color number (present if not BYLAYER);
118.                (cons 210 (list 0.0 0.0 1.0)))))
119.  
120.         ;     q_|_|| _\|| q_|| _\|     ;
121.         ;        Subroutine End        ;
122.  
123.  

[Lee Mac]

Try adding:

Code - Auto/Visual Lisp: [Select]

1. (regapp "AcAecLayerStandard")

to the start of the MakeLayer function.

[HasanCAD]

Try adding:

Code - Auto/Visual Lisp: [Select]

1. (regapp "AcAecLayerStandard")

to the start of the MakeLayer function.

Working perfect
Thanks LEE

[HasanCAD]

But why is this?
Should I regapp all subroutine? to be aplicable for new files?

[Lee Mac]

Working perfect
Thanks LEE

Excellent, you're welcome 

But why is this?
Should I regapp all subroutine? to be aplicable for new files?

No, the regapp is required in this case because the layer description is stored as xdata attached to the layer record under the AcAecLayerStandard application ID; this App ID may not be registered when the program is first used, hence causing the layer to fail to be created, resulting in the subsequent 'Automation Error. Key not found' error when the ActiveX Layer property is set to a layer which does not exist.

[ChrisCarlson]

The Automation Key not found error is pretty vague (compared to other error codes which help pin-point the issue). How did you determine it was the layer function?

[Lee Mac]

The Automation Key not found error is pretty vague (compared to other error codes which help pin-point the issue). How did you determine it was the layer function?

It is the only call to an ActiveX property which sources the property value from a VL Collection (the 'key not found' error arises when attempting to access an item not present in a collection, e.g. using the ActiveX Item method).

[HasanCAD]

Try adding:

Code - Auto/Visual Lisp: [Select]

1. (regapp "AcAecLayerStandard")

to the start of the MakeLayer function.

I belive that part of code should be added to layersubroutine.
Thats leads us to another enquairy.
Should we register all codes deal with xdata?

[Lee Mac]

Should we register all codes deal with xdata?

Before attaching xdata under a given Application ID, the Application ID must first be registered using regapp (or added to the ActiveX registeredapplications collection); you can test whether the App ID is registered using tblsearch on the APPID table, however, since supplying the regapp function with an already registered App ID has no effect, the tblsearch check may be considered unnecessary.