Topic: DataToBinary?

[highflyingbird]

How to Read a Binary File?

For example: I have a BMP file ,now I want to know its data,so I must translate it into a binary list(or a
hexadecimal list). But when I used  "read-line",I got a strange list that was different from "debug" command.

Is it possible? If it's possible,Auto Lisp will be  stronger and more powerful to deal with a lot of problems.

[MP]

How to Read a Binary File?

For example: I have a BMP file ,now I want to know its data,so I must translate it into a binary list(or a
hexadecimal list). But when I used  "read-line",I got a strange list that was different from "debug" command.

Is it possible? If it's possible,Auto Lisp will be  stronger and more powerful to deal with a lot of problems.

This thread may help you retrieve the raw data.

[highflyingbird]

MP,thans for your fast reply.
I read it,I need more time to understande and test.

[HofCAD]

MP,thans for your fast reply.
I read it,I need more time to understande and test.

For more reading and testing:
http://www.theswamp.org/index.php?topic=17206.0
http://www.theswamp.org/index.php?topic=17265.0

Regards, HofCAD CSI.

[MP]

_ReadStream

Code: [Select]

(defun _ReadStream ( path len / fso file stream result )

    ;;  If the file is successful read the data is returned as
    ;;  a string. Won't be tripped up by nulls, control chars
    ;;  including ctrl z (eof marker). Pretty fast (feel free
    ;;  to bench mark / compare to alternates).
    ;;
    ;;  If the caller wants the result as a list of byte values
    ;;  simply use vl-string->list on the result:
    ;;
    ;;      (setq bytes
    ;;          (if (setq stream (_ReadStream path len))
    ;;              (vl-string->list stream)
    ;;          )
    ;;      )
    ;;
    ;;  Arguments:
    ;;
    ;;      path  <duh>
    ;;      len   Number of bytes to read. If non numeric, less
    ;;            than 1 or greater than the number of bytes in
    ;;            the file everything is returned.

    (vl-catch-all-apply
       '(lambda ( / iomode format size )
            (setq
                iomode  1 ;; 1 = read,   2 = write,    8 = append
                format  0 ;; 0 = ascii, -1 = unicode, -2 = system default
                fso     (vlax-create-object "Scripting.FileSystemObject")
                file    (vlax-invoke fso 'GetFile path)
                stream  (vlax-invoke fso 'OpenTextFile path iomode format)
                size    (vlax-get file 'Size)
                len     (if (and (numberp len) (< 0 len size)) (fix len) size)
                result  (vlax-invoke stream 'read len)
            )
            (vlax-invoke stream 'Close)
        )
    )

    (if stream (vlax-release-object stream))
    (if file (vlax-release-object file))
    (if fso (vlax-release-object fso))

    result

)
_IntToHex

Code: [Select]

(defun _IntToHex ( int / codes hex )

    (setq
        int    (fix int)
        codes '(48 49 50 51 52 53 54 55 56 57 65 66 67 68 69 70)
    )

    (while (< 0 (fix int))
        (setq
            hex (cons (nth (fix (rem int 16.0)) codes) hex)
            int (/ int 16.0)
        )
    )

    (if hex (vl-list->string hex) "0")

)
_RSet

Code: [Select]

(defun _RSet ( str white len )

    ;;  right justify str, padding the result with
    ;;  white chars for a total string ength of len
    ;;
    ;;  (_RSet "right" "_" 10) => "_____right"

    (while (< (strlen white) len) (setq white (strcat white white)))
   
    (substr (setq str (strcat white str)) (- (strlen str) len -1))

)
Quick and Dirty c:Test

Code: [Select]

(defun c:Test ( / filename stream )

    (if (setq filename (getfiled "Select bitmap image:" "c:\\" "bmp" 128))
        (if (setq i 0 stream (_ReadStream filename nil))
            (foreach byte (vl-string->list stream)
                (princ
                    (strcat
                        (_RSet (_IntToHex byte) "0" 2)
                        (cond
                            ((zerop (rem (setq i (1+ i)) 16)) "\n")
                            ((zerop (rem i 8)) " | ")
                            (" ")
                        )
                    )
                )                 
            )
            (princ
                (strcat
                    "Error attempting to read data from <"
                    filename
                    ">.\n"
                )
            )               
        )
    )
   
    (princ)
   
)
c:Test's output assuming a bitmap was selected ...

42 4D 06 39 00 00 00 00 | 00 00 36 04 00 00 28 00
00 00 66 00 00 00 82 00 | 00 00 01 00 08 00 00 00
00 00 D0 34 00 00 00 00 | 00 00 00 00 00 00 00 01
00 00 00 01 00 00 9A 0C | 0F 00 00 00 00 00 11 14
17 00 39 A9 6F 00 BB BE | E8 00 87 77 4F 00 BB A2
6A 00 81 71 3C 00 83 7B | E6 00 3C 50 CC 00 47 AF
B4 00 00 00 00 00 00 00 | 00 00 00 00 00 00 00 00
00 00 00 00 00 00 00 00 | 00 00 00 00 00 00 00 00
00 00 00 00 00 00 00 00 | 00 00 00 00 00 00 00 00
00 00 00 00 00 00 00 00 | 00 00 00 00 00 00 00 00
00 00 00 00 00 00 00 00 | 00 00 00 00 00 00 00 00
00 00 00 00 00 00 00 00 | 00 00 00 00 00 00 00 00
00 00 00 00 00 00 00 00 | 00 00 00 00 00 00 00 00
00 00 00 00 00 00 00 00 | 00 00 00 00 00 00 00 00
00 00 00 00 00 00 00 00 | 00 00 00 00 00 00 00 00
00 00 00 00 00 00 00 00 | 00 00 00 00 00 00 00 00 ...

[highflyingbird]

MP,Thanks for your wonderful program! I tried it,and got my need.
HofCAD,Thanks for your links.I will study from them.

[MP]

You're most welcome HFB, glad you found what you needed.

[xshrimp]

how convert Binarydata "424D0639000000000000360400............" to file??
 

[MP]

Assuming that's a stream of hex data ...

1. Parse it into a list of 2 character strings.
2. Apply a HexToInt function to each element.
3. Use vl-list->string to convert to a string.
4. Write to file using _WriteStream.
5. Have a cookie.

[highflyingbird]

You're most welcome HFB, glad you found what you needed.

Ha,by the way , I want to know what's "HFB"? I asked some foreigners( English teachers),they didn't know its meaning either.

[alanjt]

You're most welcome HFB, glad you found what you needed.

Ha,by the way , I want to know what's "HFB"? I asked some foreigners( English teachers),they didn't know its meaning either.

your name dude. High Fly Bird

thanks for this michael, i was wondering how to achieve this the other day.

[MP]

It's a secret acronym:

HFB = HighFlyBird.

[MP]

your name dude. High Fly Bird

Sorry, didn't see you had responded (blackberry screen is kinda small, ez to miss stuff).

thanks for this michael, i was wondering how to achieve this the other day.

My pleasure AJT.

[highflyingbird]

Oh,It's funny.  I know a song that its name is "high-flying bird", (Music by Elton John ,Lyrics by Bernie Taupin).
Actually,I want to write a lisp to draw in CAD by a picture, so I've to know how to read a binary file. But now I have no free time,so maybe after a few days, I'll think about it.
Is there any suggestions?

[It's Alive!]

Cool! I had tried writing slide files once before but I gave up 
http://www.theswamp.org/index.php?topic=17265.0