Topic: solid face copy ucs problem

[dussla]

hello friend
Thankfully I am testing rjp's code

I found that if I copy the face from the solid, the z value of the ucs is flipped 180 degrees.
So I applied the following code     (command "ucs" "z" "180" "")
But still the z values ​​are not flipped 

do you know problem ?


(defun c:bbb (/ a b e p )
  ;; RJP ≫ 2019-01-30
  (setvar "osmode" 0) ; Set 'osmode' variable to 0
  (while (setq p (getpoint "\nPick a point in a face: ")) ; Repeat until user picks a point
    (setq a (entlast)) ; Store the last entity created, presumably a face
    (vl-cmdf "_.Solidedit" "_Face" "_Copy" p "" '(0 0 0) '(0 0 0) "" "") ; Copy the face
    (cond
      ((eq a (setq e (entlast))) (print "Boundary not created..")) ; If no boundary created
      ((/= "REGION" (cdr (assoc 0 (entget e)))) (entdel e) (print "Boundary created not valid..")) ; If created boundary is not valid
      ((setq b (vlax-invoke (vlax-ename->vla-object e) 'explode)) ; If boundary is valid, explode it
       (command "_.ucs" "_OB" (vlax-vla-object->ename (car b))) ; Set UCS to object
       (mapcar 'vla-delete b) ; Delete exploded objects
       (command "ucsicon" "or" "") ; Turn UCS icon to original position
      (command "ucs" "z" "180" "") ; Rotate UCS by 180 degrees
       (command "UCSICON" "ON"))) ; Turn on UCS icon
    ) ; End of while loop
  ) ; End of defun

[ribarm]

Have you tried to remove all "UCS" statements from *.lsp and leave only one with alignment to REGION face...
Something like this :

Code: [Select]

(defun c:bbb (/ *error* o a e p )
  ;; RJP ≫ 2019-01-30
  ;; mod. M.R.

  (defun *error* ( m )
    (if o
      (setvar (quote osmode) o)
    )
    (if m
      (prompt m)
    )
    (princ)
  )

  (setq o (getvar (quote osmode)))
  (setvar (quote osmode) 0) ; Set 'osmode' variable to 0
  (while (setq p (getpoint "\nPick a point in a face : ")) ; Repeat until user picks a point
    (setq a (entlast)) ; Store the last entity created, presumably a face
    (vl-cmdf "_.Solidedit" "_Face" "_Copy" p "" (list 0.0 0.0 0.0) (list 0.0 0.0 0.0) "" "") ; Copy the face
    (cond
      ( (eq a (setq e (entlast))) (print "Boundary not created..") ) ; If no boundary created
      ( (/= "REGION" (cdr (assoc 0 (entget e)))) ; If created boundary is not valid
        (print "Boundary created not valid..")
      )
      ( t
        (vl-cmdf "_.ucs" "_OB" e) ; created boundary is REGION and UCS aligned to it
      )
    ) ; End of cond
    (if (not (eq a e))
      (while (setq a (entnext a))
        (if (and a (not (vlax-erased-p a)))
          (entdel a)
        )
      ) ; Delete REGION or not valid boundary created after (setq a (entlast))
    ) ; End of if
  ) ; End of while loop
  (*error* nil)
) ; End of defun


[dussla]

Thanks for the reply.

Removing the UCS icon is not what I want.
After copying a face from a solid, the generated UCS will have Y+ facing down.
I want the UCS to always have Y facing up after being copied.

for the next task

[ribarm]

I've changed the code slightly to remove REGION after face is beeing copied...
I don't know how do you get 'ucsydir not aligned to edge of face - region... Both X and Y should be aligned to edges and Z with normal axis from inner to outer of 3dsolid...

[dussla]

I've changed the code slightly to remove REGION after face is beeing copied...
I don't know how do you get 'ucsydir not aligned to edge of face - region... Both X and Y should be aligned to edges and Z with normal axis from inner to outer of 3dsolid...

really thank you your effort
i tested modified code

but still  not work


pls see result attachef file
still  y  down

[ribarm]

Look, I am using BricsCAD and whereever I pick point on 3dsolid - BOX my both X and Y axises are aligned to edges of BOX... Haven't tested it with AutoCAD - give me a minute to try...

[dussla]

Look, I am using BricsCAD and whereever I pick point on 3dsolid - BOX my both X and Y axises are aligned to edges of BOX... Haven't tested it with AutoCAD - give me a minute to try...

ok thank you   for your effort

i wil try ~

[ribarm]

It seems that AutoCAD is buggy with this code... In BricsCAD it alignes UCS to region and in AutoCAD it reports that this object don't define coordinate system... And to be even more buggy it doesn't remove created regions after solidedit - copy - face options...

[dussla]

It seems that AutoCAD is buggy with this code... In BricsCAD it alignes UCS to region and in AutoCAD it reports that this object don't define coordinate system... And to be even more buggy it doesn't remove created regions after solidedit - copy - face options...

Thank you, I learned a lot of information from you.

[ribarm]

Here @dussla, try with this mod...
Should work well in both AutoCAD and BricsCAD...

Code - Auto/Visual Lisp: [Select]

1. (defun c:bbb (/ *error* getlinvetices unique c o p a e v )
2.   ;; RJP ≫ 2019-01-30
3.   ;; mod. M.R.
4.  
5.   (or (not (vl-catch-all-error-p (vl-catch-all-apply (function vlax-get-acad-object) nil))) (vl-load-com))
6.  
7.   (defun *error* ( m )
8.     (if o
9.       (setvar (quote osmode) o)
10.     )
11.     (if c
12.       (setvar (quote cmdecho) c)
13.     )
14.     (if m
15.       (prompt m)
16.     )
17.     (princ)
18.   )
19.  
20.   (defun getlinvetices ( e / x )
21.     (list (cdr (assoc 10 (setq x (entget e)))) (cdr (assoc 11 x)))
22.   )
23.  
24.   (defun unique ( l )
25.     (if l
26.       (cons (car l)
27.         (unique
28.           (vl-remove-if
29.             (function
30.               (lambda ( x ) (equal x (car l) 1e-6))
31.             )
32.             (cdr l)
33.           )
34.         )
35.       )
36.     )
37.   )
38.  
39.   (setq c (getvar (quote cmdecho)))
40.   (setvar (quote cmdecho) 0) ; Set 'cmdecho' variable to 0
41.   (setq o (getvar (quote osmode)))
42.   (setvar (quote osmode) 0) ; Set 'osmode' variable to 0
43.   (while (setq p (getpoint "\nPick a point in a face : ")) ; Repeat until user picks a point
44.     (setq p (trans p 1 0))
45.     (vl-cmdf "_.ucs" "_w") ; Set 'ucs' to 'worlducs'
46.     (setq a (entlast)) ; Store the last entity created, presumably a face
47.     (vl-cmdf "_.Solidedit" "_Face" "_Copy" p "" (list 0.0 0.0 0.0) (list 0.0 0.0 0.0) "" "") ; Copy the face
48.     (cond
49.       ( (eq a (setq e (entlast))) (print "Boundary not created..") ) ; If no boundary created
50.       ( (/= "REGION" (cdr (assoc 0 (entget e)))) ; If created boundary is not valid
51.         (print "Boundary created not valid..")
52.       )
53.       ( t ; If created boundary is valid REGION
54.         (vl-cmdf "_.explode" e)
55.         (setq v nil)
56.         (while (setq e (entnext e))
57.           (setq v (append v (getlinvetices e)))
58.           (if (and e (not (vlax-erased-p e)))
59.             (entdel e)
60.           )
61.         )
62.         (setq v (unique v))
63.         (vl-cmdf "_.ucs" "_3p" (car v) (cadr v) (caddr v)) ; UCS is aligned to face
64.       )
65.     ) ; End of cond
66.     (if (not (eq a e))
67.       (while (setq a (entnext a))
68.         (if (and a (not (vlax-erased-p a)))
69.           (entdel a)
70.         )
71.       ) ; Delete REGION or not valid boundary created after (setq a (entlast))
72.     ) ; End of if
73.   ) ; End of while loop
74.   (*error* nil)
75. ) ; End of defun
76.  

HTH.
M.R.

[dussla]

It works so well
thank thank Thank you so much for your help so far.
But I found one problem.
I'm not very good at it, so I'm asking the question again.
This does not work for objects with joined solids.

So I came up with the following idea:
what do you think?
Still, implementing this in code is too difficult for me