Topic: Upper Left Corner

[cmwade77]

Alright, I know I am probably just missing it in my searches and I know I should be able program it fairly easily, but I have been staring at code for the majority of the day today and I am drawing a blank as a result.
So, I am wondering if any of you out there have a routine that you could share to find where the upper left corner of a set of two coordinates (i.e Pt1 and Pt2) is at. I would greatly appreciate it.

[Lee Mac]

Code: [Select]

(apply 'mapcar (cons 'max (list p1 p2)))

[cmwade77]

Thank you, I was drawing a major blank, I know I have had something similar in my code, but I couldn't find it there either.

[ronjonp]

I think Lee's code will give you upper right corner.

[Lee Mac]

I think Lee's code will give you upper right corner.

Oops! yes it will! I should learn to read 

Not as elegant:

Code: [Select]

(list
  (min (car  p1) (car  p2))
  (max (cadr p1) (cadr p2))
  (caddr p1)
)

[CAB]

Another one

Code: [Select]

(list
  (apply 'min (mapcar 'car (list p1 p2)))
  (apply 'max (mapcar 'cadr (list p1 p2)))
)

[LE3]

?
(setq p (list (car p1) (cadr p2) (caddr p1)))

[alanjt]

Code: [Select]

(apply 'mapcar (cons 'max (list p1 p2)))

Code: [Select]

(apply 'mapcar (list 'max p1 p2))

Code: [Select]

(mapcar 'max p1 p2)

[CAB]

OK, Upper Left 

Code: [Select]

(list
  (car  (mapcar 'min p1 p2))
  (cadr (mapcar 'max p1 p2))
)

[Lee Mac]

Code: [Select]

(apply 'mapcar (cons 'max (list p1 p2)))

Code: [Select]

(apply 'mapcar (list 'max p1 p2))

Code: [Select]

(mapcar 'max p1 p2)

I like the thought progression! 

[Lee Mac]

?
(setq p (list (car p1) (cadr p2) (caddr p1)))

Not if p1 has a greater x-value than p2, or similarly if p2 has a smaller y-value than p1...

[Lee Mac]

Another variation...

Bottom Right & Upper Left:

Code: [Select]

(mapcar 'apply '(max min max) (mapcar 'list p1 p2))
(mapcar 'apply '(min max min) (mapcar 'list p1 p2))
All four:

Code: [Select]

(
  (lambda ( a )
    (mapcar '(lambda ( b ) (mapcar 'apply b a))
     '(
        (min min min)
        (max min max)
        (max max max)
        (min max min)
      )
    )
  )
  (mapcar 'list p1 p2)
)

[SOFITO_SOFT]

for a list of any number of points:

Code: [Select]

Command: ( setq lista ( list '( 10 -1 2 ) '( 34 -54 56 ) '( 34 55.6 56 )))
((10 -1 2) (34 -54 56) (34 55.6 56))
Command: ( list
(_>   ( list ( apply 'min ( mapcar 'car lista ) )
((_>          ( apply 'min ( mapcar 'cadr lista ) )
((_>   )
(_>   ( list ( apply 'max ( mapcar 'car lista ) )
((_>          ( apply 'max ( mapcar 'cadr lista ) )
((_>   )
(_> )
((10 -54.0) (34 55.6))Greetings

[Lee Mac]

For an arbitrary number of points I usually use:

Code: [Select]

(mapcar '(lambda ( a ) (apply 'mapcar (cons a <pointlist>))) '(min max))