Topic: Sorting list of list with Lambda function

[Lost_in_()]

((602 602000002 Unsorted 602 393361.75 6462327.52 1 6 1 0 3C93) (601 6010000000 Unsorted 393362.42 6462545.33 1 6 1 0 3C8C) (601 6010006007
Mercure Perth 392616.99 6463873.02 0.5 6 1 0 2D44) (602 6020049148 The Royal On The Waterfront  393962.19 6464248.67 1 6 1 0 2AD5) (602 6020007831 The
Dutch Trading Co 395487.69 6462162.6 1 6 1 0 2827) (602 6020137456 Rockpool Bar & Grill Perth 395512.04 6463352.84 1 6 1 0 2819) (603 6030130659 CBD IGA Plus
Liquor 392447.72 6463977.38 0.5 6 1 0 2587) (603 6030138819 Vintage Wine Sales 393439.89 6464831.22 1 6 1 0 2580) (603 6030002774 John's Food & Liquor Store 
393555.46 6464035.13 1 6 1 0 2564) (603 6030002915 BWS - Beer Wine Spirits East Perth  393358.98 6463605.11 0.5 6 1 0 255D) (603 6030004192 Vintage Cellars East Perth  393982.2 6464188.84 1 6 1 0 2556) ) (622 6220047894 Goodearth Hotel 393142.4 6463525.9 0.5 6 1 0 1B00) (622 6220029587 Crown Metropol 395493.24 6463374.86 1 6 1 0 1A90) (636 6360028324 Badlands Bar 392956.22 6464465 0.5 6 1 0 1A58) (637 6370029082 Gilkison Dance Studio 392626.21 6464016.45 0.5 6 1 0 1A3C))
Given the above list I am trying to write a sorted list of list routine and think I am nearly there, but I keep getting an error in the Lambda function - should be all 601's first , then 602's and so on.  Never used lambda before and getting a headache    Any help appreciated

Code - Auto/Visual Lisp: [Select]

1. (defun orderlist()  ;; takes p_str_list and orders list by p_lic_type
2.   (princ "\nOrder list ")
3.   (disp "p_str_list" p_str_list)
4.   (setq p_sort nil)
5.   (setq p_index (vl-sort-i p_str_list
6.                  (lambda (p_a p_b)
7.                    (< (nth 0 p_a) (nth 0 p_b))
8.                    )
9.                   )
10.         )
11.   (disp "p_str_list" p_str_list)
12.   (disp "p_index " p_index)
13.   (foreach p_n p_index (setq p_sort (cons (nth p_n p_str_list) p_sort)))
14.   (reverse p_sort)
15.   (disp "p_sort" p_sort)
16.   )
17.  

[Lost_in_()]

Think it's sorted - missed having a function call to the lambda!

Code - Auto/Visual Lisp: [Select]

1. (function (lambda (p_a p_b)
2.  

[kpblc]

Check this

[Lost_in_()]

Thanks Kpblc - much smaller than my effort

[ronjonp]

Could also do this to do some more sorting

Code - Auto/Visual Lisp: [Select]

1. (vl-sort lst
2.          (function (lambda (a b)
3.                      (< (apply 'strcat (mapcar 'vl-princ-to-string a))
4.                         (apply 'strcat (mapcar 'vl-princ-to-string b))
5.                      )
6.                    )
7.          )
8. )

[Lost_in_()]

According to my documentation vl-sort may remove duplicates (I am using Autocad 2008 - don't ask!) which would not be acceptable.

from the help file -
Return Values

A list containing the elements of list in the order specified by comparison-function. Duplicate elements may be eliminated from the list.

Regards
Pete

[MP]

Could also do this to do some more sorting

Code - Auto/Visual Lisp: [Select]

1. (vl-sort lst
2.          (function (lambda (a b)
3.                      (< (apply 'strcat (mapcar 'vl-princ-to-string a))
4.                         (apply 'strcat (mapcar 'vl-princ-to-string b))
5.                      )
6.                    )
7.          )
8. )

Indeed. Specialized temporary sorting keys can be constructed that are specific to the data / app.

That said, better to apply it once, use it, then discard it, rather than suffer a performance hit each iteration thru the sort algorythm.

Simplified demo for ease of understanding for the op:

Code: [Select]

(mapcar 'cdr
    (vl-sort
        (mapcar
            (function (lambda (i) (cons (vl-princ-to-string i) i)))
            lst
        )           
        (function (lambda (a b) (< (car a) (car b))))
    )
)
Cheers.

[ronjonp]

That's why you're the OG .  thanks.

[MP]

lol -- thanks Ron (I think) -- I'm scared to ask -- what is OG -- Old/Original Geezer? Goof? Goober? Gaffe? Grump? Grok?

[ronjonp]

Original Gangster 😎

[MP]

Ha, too kind / cool. 

[Lee Mac]

FWIW, an alternative might be to use vl-sort-i, e.g.:

Code - Auto/Visual Lisp: [Select]

1. (mapcar '(lambda ( n ) (nth n lst)) (vl-sort-i (mapcar 'vl-princ-to-string lst) '<))

[Lost_in_()]

Thanks for that Lee.  As I have that part of the code running now so will leave alone   

[ronjonp]

Could also do this to do some more sorting

Code - Auto/Visual Lisp: [Select]

1. (vl-sort lst
2.     (function (lambda (a b)
3.            (<   (apply 'strcat (mapcar 'vl-princ-to-string a))
4.          (apply 'strcat (mapcar 'vl-princ-to-string b))
5.            )
6.          )
7.     )
8. )

Indeed. Specialized temporary sorting keys can be constructed that are specific to the data / app.

That said, better to apply it once, use it, then discard it, rather than suffer a performance hit each iteration thru the sort algorythm.

Simplified demo for ease of understanding for the op:

Code: [Select]

(mapcar 'cdr
    (vl-sort
        (mapcar
            (function (lambda (i) (cons (vl-princ-to-string i) i)))
            lst
        )           
        (function (lambda (a b) (< (car a) (car b))))
    )
)
Cheers.

Just for grins, I benched the two functions with that short list ... quite a difference! 

    (MAPCAR (QUOTE CDR) (VL-SORT (MAPCAR...)......1422 / 16.70 <fastest>
    (VL-SORT LST (FUNCTION (LAMBDA (A B)...).....23750 / 1.00 <slowest>

[MP]

Cool, who knew. Thanks Ron