Topic: Help to Modify a LISP

[RolandOrzabal]

can somebody help me to modify a lisp i found at cadalyst. This is useful but after issuing the command and the routine thawing the drawing, if the user accidentally hits escape key, it does not revert back to its old state and shows all the frozen layers. Maybe an error tap will solve this but am not that good at that...

here's the code :

Code: [Select]


;;;========================================================================
;;;                    *** LYR-UNHIDE.LSP ***
;;;========================================================================
;;;
;;; This function dynamicaly "TURN ON" frozen layers by selecting objects
;;; lying on these layers. The procedure is achieved by temporary turning
;;; on all layers to enable selection.
;;;
;;;
;;; "Specially recommanded to use on Xrefs" - Raymond Rizkallah, Aug. 2007
;;;========================================================================

(defun C:LUH (/ entsll laynam laypmt  )

  (setq orgm (getvar "regenmode"))
  (setq laylst nil laypmt " ")
  (command "undo" "m" "undo" "g")

    (setvar "regenmode" 1)
  (command "layer" "t" "*" "on" "*" "")
  (while
    (setq entsll (nentsel "\n Select object on layer to be unhidden: "))
    (setq laynam (cdr (assoc 8 (entget (car entsll)))))
    (if (null laylst) (setq laylst (strcat laynam ",")) (setq laylst (strcat laylst laynam ",")))
    ;(prompt (strcat "\n   <" (substr laylst 1 (1- (strlen laylst))) ">"))

    (setq laypmt (strcat laypmt "<" laynam "> ; "))    (prompt (strcat "\n" laypmt))

  ) ;end while

  ; (command "undo" "end" "undo" "1")   
  (if laylst (command "layer" "t" laylst "on" laylst "u" laylst ""))  ;end if
 
  (setvar "regenmode" orgm)
  (princ)

) ;end function

;;;========================================================================

(prompt "\n Use [C:LUH] to dynamicaly reveal hidden layers. ")
(princ)



[cadplayer]

I´m little confuse what you want to do ... is it another to isolate or unisolate layers?

[RolandOrzabal]

I´m little confuse what you want to do ... is it another to isolate or unisolate layers?

Hi Cadplayer, just wanted to have a error trap in which when the user hit the escape key, those layers that were temporarily thawed will be frozen/hidden again.

if you try running the program, after issuing the command and hitting the escape key, it does not restore the previous state of the layers.
you will need to run undo command first for it to restore the previous layer states...

is it possible that after you hit escape and the routine stopped, it will automatically restore the layer state and no need for the undo command....

[Stefan]

Try this (as an example to fix your routine, or use it if you like it)

Code - Auto/Visual Lisp: [Select]

1. (defun C:THAWLAY (/ *error* acDoc layers layer freez_list on_list e)
2.   (setq acDoc  (vla-get-ActiveDocument (vlax-get-acad-object))
3.         layers (vla-get-layers acDoc)
4.   )
5.   (vla-StartUndoMark acDoc)
6.  
7.   (defun *error* (msg)
8.     (foreach x on_list (vla-put-LayerOn (vla-item layers x) :vlax-true))
9.     (foreach x freez_list (vla-put-Freeze (vla-item layers x) :vlax-true))
10.     (vla-regen acDoc acActiveViewport)
11.     (vla-EndUndoMark acDoc)
12.   )
13.  
14.   (vlax-for layer layers
15.     (if
16.       (= (vla-get-Freeze layer) :vlax-true)
17.        (progn
18.          (vla-put-Freeze layer :vlax-false)
19.          (setq freez_list (cons (vla-get-Name layer) freez_list))
20.        )
21.        (progn
22.          (vla-put-LayerOn layer :vlax-false)
23.          (setq on_list (cons (vla-get-Name layer) on_list))
24.        )
25.     )
26.   )
27.  
28.   (vla-regen acDoc acActiveViewport)
29.  
30.   (while
31.     (or
32.       (setq e (car (nentsel)))
33.       (and (= (getvar 'errno) 7) (setvar 'errno 0))
34.     )
35.      (if e
36.        (progn
37.          (setq layer      (cdr (assoc 8 (entget e)))
38.                freez_list (vl-remove layer freez_list)
39.                on_list    (cons layer on_list)
40.          )
41.          (vla-put-LayerOn (vla-item layers layer) :vlax-false)
42.        )
43.      )
44.   )
45.  
46.   (*error* nil)
47.   (princ)
48. )

[RolandOrzabal]

@stefan, what does your routine do? i've tried it and it does nothing...or maybe i've done something wrong....

what the routine does is that it "temporarily" turns on frozen and off layers, then you select which layers you want to turn on/thaw then it reverts back to the previous layer state except for the ones you pick.

the problem is that after you "temporarily" turn on the frozen/off layers and you hit escape, the frozen/off layers are all thawed/on and you need to issue undo command to turn them back to their state.

what i want if possible is that when you hit escape key, it reverts back to its previous state and no need to issue the undo command.

[Stefan]

@stefan, what does your routine do? i've tried it and it does nothing...or maybe i've done something wrong....

Works only for frozen layers. On error (or hitting escape) will turn on temporary hidden layers, but will keep changes already made.

[Stefan]

To answer your fist post, try this

Code - Auto/Visual Lisp: [Select]

1. ;;;========================================================================
2. ;;;                    *** LYR-UNHIDE.LSP ***
3. ;;;========================================================================
4. ;;;
5. ;;; This function dynamicaly "TURN ON" frozen layers by selecting objects
6. ;;; lying on these layers. The procedure is achieved by temporary turning
7. ;;; on all layers to enable selection.
8. ;;;
9. ;;;
10. ;;; "Specially recommanded to use on Xrefs" - Raymond Rizkallah, Aug. 2007
11. ;;;========================================================================
12.  
13. (defun C:LUH (/ *error* entsll laynam laypmt  )
14.  
15.   (setq orgm (getvar "regenmode"))
16.   (setq laylst nil laypmt " ")
17.   (command "undo" "m")
18.  
19.   (defun *error* (msg)
20.     (command "undo" "b")
21.     )
22.  
23.     (setvar "regenmode" 1)
24.   (command "layer" "t" "*" "on" "*" "")
25.   (while
26.     (setq entsll (nentsel "\n Select object on layer to be unhidden: "))
27.     (setq laynam (cdr (assoc 8 (entget (car entsll)))))
28.     (if (null laylst) (setq laylst (strcat laynam ",")) (setq laylst (strcat laylst laynam ",")))
29.     ;(prompt (strcat "\n   <" (substr laylst 1 (1- (strlen laylst))) ">"))
30.  
31.     (setq laypmt (strcat laypmt "<" laynam "> ; "))    (prompt (strcat "\n" laypmt))
32.  
33.   ) ;end while
34.  
35.   ; (command "undo" "end" "undo" "1")
36.   (command "undo" "b")
37.   (if laylst (command "layer" "t" laylst "on" laylst "u" laylst ""))  ;end if
38.  
39.   (setvar "regenmode" orgm)
40.   (princ)
41.  
42. ) ;end function
43.  
44. ;;;========================================================================
45.  
46. (prompt "\n Use [C:LUH] to dynamicaly reveal hidden layers. ")
47. (princ)
48.  

[RolandOrzabal]

To answer your fist post, try this

Code - Auto/Visual Lisp: [Select]

1. ;;;========================================================================
2. ;;;                    *** LYR-UNHIDE.LSP ***
3. ;;;========================================================================
4. ;;;
5. ;;; This function dynamicaly "TURN ON" frozen layers by selecting objects
6. ;;; lying on these layers. The procedure is achieved by temporary turning
7. ;;; on all layers to enable selection.
8. ;;;
9. ;;;
10. ;;; "Specially recommanded to use on Xrefs" - Raymond Rizkallah, Aug. 2007
11. ;;;========================================================================
12.  
13. (defun C:LUH (/ *error* entsll laynam laypmt  )
14.  
15.   (setq orgm (getvar "regenmode"))
16.   (setq laylst nil laypmt " ")
17.   (command "undo" "m")
18.  
19.   (defun *error* (msg)
20.     (command "undo" "b")
21.     )
22.  
23.     (setvar "regenmode" 1)
24.   (command "layer" "t" "*" "on" "*" "")
25.   (while
26.     (setq entsll (nentsel "\n Select object on layer to be unhidden: "))
27.     (setq laynam (cdr (assoc 8 (entget (car entsll)))))
28.     (if (null laylst) (setq laylst (strcat laynam ",")) (setq laylst (strcat laylst laynam ",")))
29.     ;(prompt (strcat "\n   <" (substr laylst 1 (1- (strlen laylst))) ">"))
30.  
31.     (setq laypmt (strcat laypmt "<" laynam "> ; "))    (prompt (strcat "\n" laypmt))
32.  
33.   ) ;end while
34.  
35.   ; (command "undo" "end" "undo" "1")
36.   (command "undo" "b")
37.   (if laylst (command "layer" "t" laylst "on" laylst "u" laylst ""))  ;end if
38.  
39.   (setvar "regenmode" orgm)
40.   (princ)
41.  
42. ) ;end function
43.  
44. ;;;========================================================================
45.  
46. (prompt "\n Use [C:LUH] to dynamicaly reveal hidden layers. ")
47. (princ)
48.  

Thanks a lot! it's just how i wanted it to be....
thanks again stefan

[irneb]

Perhaps this:

Code - Auto/Visual Lisp: [Select]

1. (vl-load-com)
2. (defun c:LayAllThaw  ()
3.   (vlax-for lay  (vla-get-Layers (vla-get-ActiveDocument (vlax-get-acad-object)))
4.     (vla-put-Freeze lay :vlax-false))
5.   (princ))
6.  
7. (defun c:LayAllOn  ()
8.   (vlax-for lay  (vla-get-Layers (vla-get-ActiveDocument (vlax-get-acad-object)))
9.     (vla-put-LayerOn lay :vlax-true))
10.   (princ))
11.  
12. (defun c:LayAllShow () (c:LayAllThaw) (c:LayAllOn))
13.  
14. (setq *LayUnHide-StateName* "*LayerUnHide*")
15. (defun c:LayUnHide  (/ *error* LayersToTurnOn en)
16.   (defun *error*  (msg)
17.     (if (layerstate-has *LayUnHide-StateName*)
18.       (progn (layerstate-restore *LayUnHide-StateName* nil) (layerstate-delete *LayUnHide-StateName*)))
19.     (cond ((or (not msg) (wcmatch (strcase msg "EXIT,QUIT,ABORT"))))
20.           (t (prompt (strcat "*** Error: " msg " ***"))))
21.     (princ))
22.   (layerstate-save *LayUnHide-StateName* 3 nil)
23.   (c:LayAllShow)
24.   (while (setq en (entsel "\nSelect object on layer to unhide: "))
25.     (setq LayersToTurnOn (cons (cdr (assoc 8 (entget en))) LayersToTurnOn)))
26.   (*error* nil)
27.   (vlax-for lay  (vla-get-Layers (vla-get-ActiveDocument (vlax-get-acad-object)))
28.     (if (vl-position (vla-get-Name lay) LayersToTurnOn)
29.       (progn (vla-put-LayerOn lay :vlax-true) (vla-put-Freeze lay :vlax-false))))
30.   (princ))

[RolandOrzabal]

irneb; am getting this error :

Code: [Select]

; error: An error has occurred inside the *error* functiontoo few arguments

[Lee Mac]

After a quick glance, change:

Code - Auto/Visual Lisp: [Select]

1. (wcmatch (strcase msg "EXIT,QUIT,ABORT"))

to:

Code - Auto/Visual Lisp: [Select]

1. (wcmatch (strcase msg) "*EXIT*,*QUIT*,*ABORT*")

[CAB]

First test & this fails for me on ACAD 2006.
Can not change the current layer.

Code: [Select]

(defun c:layallon ()
  (vlax-for lay (vla-get-layers (vla-get-activedocument (vlax-get-acad-object)))
    (vla-put-layeron lay :vlax-true)
  )
  (princ)
)

[CAB]

Where are these routines?
layerstate-has
layerstate-save

[Lee Mac]

Where are these routines?
layerstate-has
layerstate-save

Those are part of the layerstate-* AutoLISP functions, but I'm not sure in which version they were introduced:

[CAB]

Thanks Lee, they don't exist in vanilla 2006.

Perhaps one of those calls withing the error handler is throwing the error.

[RolandOrzabal]

Thanks Lee! revised code below but nothings happening...wonder whats wrong..

or is it on my side?

Code: [Select]


 (vl-load-com)
 (defun c:LayAllThaw  ()
   (vlax-for lay  (vla-get-Layers (vla-get-ActiveDocument (vlax-get-acad-object)))
     (vla-put-Freeze lay :vlax-false))
   (princ))
 
 (defun c:LayAllOn  ()
   (vlax-for lay  (vla-get-Layers (vla-get-ActiveDocument (vlax-get-acad-object)))
     (vla-put-LayerOn lay :vlax-true))
   (princ))
 
 (defun c:LayAllShow () (c:LayAllThaw) (c:LayAllOn))
 
 (setq *LayUnHide-StateName* "*LayerUnHide*")
 (defun c:LayUnHide  (/ *error* LayersToTurnOn en)
   (defun *error*  (msg)
     (if (layerstate-has *LayUnHide-StateName*)
       (progn (layerstate-restore *LayUnHide-StateName* nil) (layerstate-delete *LayUnHide-StateName*)))
     (cond ((or (not msg) (wcmatch (strcase msg) "*EXIT*,*QUIT*,*ABORT*"))))
           (t (prompt (strcat "*** Error: " msg " ***"))))
     (princ))
   (layerstate-save *LayUnHide-StateName* 3 nil)
   (c:LayAllShow)
   (while (setq en (entsel "\nSelect object on layer to unhide: "))
     (setq LayersToTurnOn (cons (cdr (assoc 8 (entget en))) LayersToTurnOn)))
   (*error* nil)
   (vlax-for lay  (vla-get-Layers (vla-get-ActiveDocument (vlax-get-acad-object)))
     (if (vl-position (vla-get-Name lay) LayersToTurnOn)
       (progn (vla-put-LayerOn lay :vlax-true) (vla-put-Freeze lay :vlax-false))))
   (princ))
 

[irneb]

Sorry about the typo, thanks Lee for catching it. I'll have to do a bit of testing on this, it seems the parentheses are wrong elsewhere too.

[CAB]

Replace this :

Code: [Select]

      (if (layerstate-has *LayUnHide-StateName*)
         (progn (layerstate-restore *LayUnHide-StateName* nil) (layerstate-delete *LayUnHide-StateName*)))
with this to see it that is where the error is:

Code: [Select]

      (vl-catch-all-apply '(lambda ()
      (if (layerstate-has *LayUnHide-StateName*)
         (progn (layerstate-restore *LayUnHide-StateName* nil) (layerstate-delete *LayUnHide-StateName*)))
      ))

[RolandOrzabal]

still nothing happens...

LayAllShow returns an Invalid Layer Error

[irneb]

OK, fixed it ... sorry real stupid mistakes. Comes from trying to program without debugging inside VLIDE.

Code - Auto/Visual Lisp: [Select]

1. (vl-load-com)
2. (defun c:LayAllThaw  ()
3.   (vlax-for lay  (vla-get-Layers (vla-get-ActiveDocument (vlax-get-acad-object)))
4.     (vl-catch-all-apply 'vla-put-Freeze (list lay :vlax-false)))
5.   (vla-Regen (vla-get-ActiveDocument (vlax-get-acad-object)) acAllViewports)
6.   (princ))
7.  
8. (defun c:LayAllOn  ()
9.   (vlax-for lay  (vla-get-Layers (vla-get-ActiveDocument (vlax-get-acad-object)))
10.     (vl-catch-all-apply 'vla-put-LayerOn (list lay :vlax-true)))
11.   (princ))
12.  
13. (defun c:LayAllShow () (c:LayAllThaw) (c:LayAllOn))
14.  
15. (setq *LayUnHide-StateName* "_LayerUnHide_")
16. (defun c:LayUnHide  (/ *error* LayersToTurnOn en)
17.   (defun *error*  (msg)
18.     (if (layerstate-has *LayUnHide-StateName*)
19.       (progn (layerstate-restore *LayUnHide-StateName* nil)
20.       (layerstate-delete *LayUnHide-StateName*)))
21.     (cond ((or (not msg) (wcmatch (strcase msg) "*EXIT*,*QUIT*,*ABORT*")))
22.    (t (prompt (strcat "*** Error: " msg " ***"))))
23.     (princ))
24.   (layerstate-save *LayUnHide-StateName* 3 nil)
25.   (c:LayAllShow)
26.   (while (setq en (entsel "\nSelect object on layer to unhide: "))
27.     (setq LayersToTurnOn (cons (cdr (assoc 8 (entget (car en)))) LayersToTurnOn)))
28.   (*error* nil)
29.   (vlax-for lay  (vla-get-Layers (vla-get-ActiveDocument (vlax-get-acad-object)))
30.     (if (vl-position (vla-get-Name lay) LayersToTurnOn)
31.       (progn (vla-put-LayerOn lay :vlax-true) (vla-put-Freeze lay :vlax-false))))
32.   (princ))

Firstly the cond inside the *error* handler was simply incorrect! 2nd had to add the catch into the All on/thaw defuns. 3rd add a regen after thawing. And lastly car of the entsel  :-[
 
Edit: [RANT]And WTH? I'm attempting to do this from IE9 today. On the office PC. Now I can fully realize just how much suffering the guys complaining about the forum's code blocks have. It's not just copying the code from the post, it's also issues with pasting the code into the edit box. You keep losing formatting - line feeds and tabs just go crazy! I've never had such issues with FF! ... [/RANT]

[RolandOrzabal]

OK, fixed it ... sorry real stupid mistakes. Comes from trying to program without debugging inside VLIDE.

Code - Auto/Visual Lisp: [Select]

1. (vl-load-com)
2. (defun c:LayAllThaw  ()
3.   (vlax-for lay  (vla-get-Layers (vla-get-ActiveDocument (vlax-get-acad-object)))
4.     (vl-catch-all-apply 'vla-put-Freeze (list lay :vlax-false)))
5.   (vla-Regen (vla-get-ActiveDocument (vlax-get-acad-object)) acAllViewports)
6.   (princ))
7.  
8. (defun c:LayAllOn  ()
9.   (vlax-for lay  (vla-get-Layers (vla-get-ActiveDocument (vlax-get-acad-object)))
10.     (vl-catch-all-apply 'vla-put-LayerOn (list lay :vlax-true)))
11.   (princ))
12.  
13. (defun c:LayAllShow () (c:LayAllThaw) (c:LayAllOn))
14.  
15. (setq *LayUnHide-StateName* "_LayerUnHide_")
16. (defun c:LayUnHide  (/ *error* LayersToTurnOn en)
17.   (defun *error*  (msg)
18.     (if (layerstate-has *LayUnHide-StateName*)
19.       (progn (layerstate-restore *LayUnHide-StateName* nil)
20.       (layerstate-delete *LayUnHide-StateName*)))
21.     (cond ((or (not msg) (wcmatch (strcase msg) "*EXIT*,*QUIT*,*ABORT*")))
22.    (t (prompt (strcat "*** Error: " msg " ***"))))
23.     (princ))
24.   (layerstate-save *LayUnHide-StateName* 3 nil)
25.   (c:LayAllShow)
26.   (while (setq en (entsel "\nSelect object on layer to unhide: "))
27.     (setq LayersToTurnOn (cons (cdr (assoc 8 (entget (car en)))) LayersToTurnOn)))
28.   (*error* nil)
29.   (vlax-for lay  (vla-get-Layers (vla-get-ActiveDocument (vlax-get-acad-object)))
30.     (if (vl-position (vla-get-Name lay) LayersToTurnOn)
31.       (progn (vla-put-LayerOn lay :vlax-true) (vla-put-Freeze lay :vlax-false))))
32.   (princ))

Firstly the cond inside the *error* handler was simply incorrect! 2nd had to add the catch into the All on/thaw defuns. 3rd add a regen after thawing. And lastly car of the entsel  :-[

irneb thanks a lot for your effort,
am getting this error

after issuing the command it will show all off/frozen layers,
after picking the layer to turn-on/thaw, this error shows up

Code: [Select]

Command: layunhide
Regenerating model.

Command:
Select object on layer to unhide:
Select object on layer to unhide:
*** Error: Automation Error. Invalid layer ***

[irneb]

Replacement for lines 29-31:

Code - Auto/Visual Lisp: [Select]

1. (vlax-for lay  (vla-get-Layers (vla-get-ActiveDocument (vlax-get-acad-object)))
2.     (if (vl-position (vla-get-Name lay) LayersToTurnOn)
3.       (foreach func '((vla-put-LayerOn . :vlax-true) (vla-put-Freeze . :vlax-false))
4.  (vl-catch-all-apply (car func) (list lay (cdr func))))))
5.   (vla-Regen (vla-get-ActiveDocument (vlax-get-acad-object)) acAllViewports)

Again, for some reason certain layers cause errors - perhaps current layer? Or locked? Or defpoints / 0? Anyhow the catch should perform correctly. Also added another regen, otherwise the thaw doesn't display imediately after completing.
 
Edit: Again! See how screwed up IE's working with the forum editor? Tab indents just go silly!  :realmad:

[RolandOrzabal]

irneb...no error this time

LayAllShow shows all frozen/off layers

but after picking the layer to turn on/thaw
nothing happens...it is still OFF/frozen

0 is not my current Layer.
tried it on other drawings but still the same

[irneb]

I don't know what to tell you. It seems to work fine here in ACA 2013 (sorry don't have a Vanilla here) ... for a while. Though sometimes I have to do it twice to the same layer before it catches. It's as if the first time round the layer doesn't allow itself to be "shown", but the second time round it says: "Agh alright ... if you want it so much then FINE!!!"  :realmad: Bloody lazy layers  :pissed:
 
It doesn't happen on all layers, just some of them. I can't figure out why this happens. Nothing locked or any such. It seems to happen on layers which were frozen or off - makes no difference. Anyone know why this occurs?

[RolandOrzabal]

I don't know what to tell you. It seems to work fine here in ACA 2013 (sorry don't have a Vanilla here) ... for a while. Though sometimes I have to do it twice to the same layer before it catches. It's as if the first time round the layer doesn't allow itself to be "shown", but the second time round it says: "Agh alright ... if you want it so much then FINE!!!"  :realmad: Bloody lazy layers  :pissed:
 
It doesn't happen on all layers, just some of them. I can't figure out why this happens. Nothing locked or any such. It seems to happen on layers which were frozen or off - makes no difference. Anyone know why this occurs?

don't know too why...am using 2010
on my side even though i select the layers i want to show multiple time..still nothing happens.

I tried it on somebody else's pc and somebody else's file
same problem

[irneb]

When I say multiple times, I don't mean pick the layer numerous times. I mean run the LayUnHide command twice, pick the same object again & press enter again. After the 2nd run the layer turns on ... extremely strange!
 
I even thought it might be due to the Layer Manager Palette (since that sometimes causes these "cannot change layer properties" issues). But turning it off didn't do anything. Unfortunately I can't check if the ribbon has an effect, since there's no "Classic" setup in ACA - no menu bar either! I'm lost on this.
 
I was thinking of adding a repeat loop to perform the change multiple times, or even testing if the catch failed and repeat until it doesn't. That seems to work:

Code - Auto/Visual Lisp: [Select]

1. (vl-load-com)
2. (defun c:LayAllThaw  ()
3.   (vlax-for lay  (vla-get-Layers (vla-get-ActiveDocument (vlax-get-acad-object)))
4.     (vl-catch-all-apply 'vla-put-Freeze (list lay :vlax-false)))
5.   (vla-Regen (vla-get-ActiveDocument (vlax-get-acad-object)) acAllViewports)
6.   (princ))
7. (defun c:LayAllOn  ()
8.   (vlax-for lay  (vla-get-Layers (vla-get-ActiveDocument (vlax-get-acad-object)))
9.     (vl-catch-all-apply 'vla-put-LayerOn (list lay :vlax-true)))
10.   (princ))
11. (defun c:LayAllShow () (c:LayAllThaw) (c:LayAllOn))
12. (setq *LayUnHide-StateName* "_LayerUnHide_")
13. (defun c:LayUnHide  (/ *error* LayersToTurnOn en)
14.   (defun *error*  (msg)
15.     (if (layerstate-has *LayUnHide-StateName*)
16.       (progn (layerstate-restore *LayUnHide-StateName* nil)
17.       (layerstate-delete *LayUnHide-StateName*)))
18.     (cond ((or (not msg) (wcmatch (strcase msg) "*EXIT*,*QUIT*,*ABORT*")))
19.    (t (prompt (strcat "*** Error: " msg " ***"))))
20.     (princ))
21.   (layerstate-save *LayUnHide-StateName* 3 nil)
22.   (c:LayAllShow)
23.   (while (setq en (entsel "\nSelect object on layer to unhide: "))
24.     (setq LayersToTurnOn (cons (cdr (assoc 8 (entget (car en)))) LayersToTurnOn)))
25.   (*error* nil)
26.   (vlax-for lay  (vla-get-Layers (vla-get-ActiveDocument (vlax-get-acad-object)))
27.     (if (vl-position (vla-get-Name lay) LayersToTurnOn)
28.       (foreach func '((vla-put-LayerOn . :vlax-true) (vla-put-Freeze . :vlax-false))
29.  (while (vl-catch-all-error-p (vl-catch-all-apply (car func) (list lay (cdr func))))))))
30.   (vla-Regen (vla-get-ActiveDocument (vlax-get-acad-object)) acAllViewports)
31.   (princ))

Though I really don't like the idea of looping until some weird thing stops happening ... or rather not-happening. It's like a cop-out and could lead to an infinite loop.