Topic: How to enter Block definition to dedelte an entity

[Coder]

I am trying to delete a LWpolylines from the existed blocks in a dwg, but something wrong with it .

Would anyone check these codes for me please ?

Code: [Select]

(vl-load-com)
(vlax-for blks
          (vla-get-Blocks
                       (vla-get-ActiveDocument (vlax-get-Acad-Object)))
    (vlax-for i blks
        (if (setq ss
                        (ssget "_X" '((0 . "LWPOLYLINE"))))
  (command "_.erase" ss "")
  (princ "\n No LWpolylines found")
         )
      )
  )
 (vla-regen (vla-get-ActiveDocument   (vlax-get-acad-object)) acAllViewports)



[MP]

<coded blind> this should work:

Code: [Select]

(vlax-for block (vla-get-blocks (vla-get-activedocument (vlax-get-acad-object)))
    (vlax-for object block
        (if (eq "AcDb2dPolyline" (vla-get-objectname object))
            (vla-delete object)
        )
    )
)
will delete lwpolylines from all blocks, including modelspace, paperspace

bare minimum code / no error trapping: e.g. will get a shovel in the face if the polyline is on a locked layer

[Coder]

Thanks a lot .

It did not delete any LWpolyline from the block .

and it returns "nil"

[MP]

do a regen then report back  

what did you expect it to return?

[Coder]

I already did regen after implementing these codes .

And I do expect codes to delete the LWpolyline or as you call it "AcDb2dPolyline" .

[Lee Mac]

Try:

Code: [Select]

(vlax-for block (vla-get-blocks (setq doc (vla-get-activedocument (vlax-get-acad-object))))
    (vlax-for object block
        (if (eq "AcDbPolyline" (vla-get-objectname object))
            (vla-delete object)
        )
    )
)

(vla-regen doc acallviewports)


[MP]

Code: [Select]

[quote author=coder link=topic=36695.msg416891#msg416891 date=1295205217]
I already did regen after implementing these codes .
lee's code suggests my algo was proper, so it implies the objects you want to delete in your blocks are not lwpolylines if they are still there after a regen / regenall

And I do expect codes to delete the LWpolyline or as you call it "AcDb2dPolyline" .

wut

[Coder]

Try:

Code: [Select]

(vlax-for block (vla-get-blocks (setq doc (vla-get-activedocument (vlax-get-acad-object))))
    (vlax-for object block
        (if (eq "AcDbPolyline" (vla-get-objectname object))
            (vla-delete object)
        )
    )
)
(vla-regen doc acallviewports)


Waw that's it .

Thank you so much mr Lee.

And thanks for MP

Appreciated guys

[MP]

oh, I see the error, I should have used "AcDbPolyline" instead of "AcDb2dPolyline"

sorry for the misdirection

so much for coding blind

leaving posts in err intact for thread continuity

[Lee Mac]

and it returns "nil"

Just to clarify: the vla-delete method should return nil.

[Lee Mac]

so much for coding blind

Happens to the best of us 

[MP]

[Coder]

Is it possible to be made with Vanilla  ?

[MP]

If by vanilla you mean "not activex based" it's harder, as my recollection is that entdel won't work on entities in block definitions (could be wrong, try it and confirm / refute), so you have to fake it by walking thru each block definition, collect the entities that are not lwpolylines, and then redefine the block with the remaining entities.

[Lee Mac]

entdel won't work on entities in block definitions, so you have to fake it by walking thru each block definition

Correct 

Messy...

Code: [Select]

(
  (lambda ( / block )
    (while (setq block (tblnext "BLOCK" (null block))) (entmake block)
      (
        (lambda ( block )
          (while block
            (if (not (eq "LWPOLYLINE" (cdr (assoc 0 (entget block)))))
              (entmake (entget block))
            )
            (setq block (entnext block))
          )
          (entmake (list (cons 0 "ENDBLK") (cons 8 "0")))
        )
        (cdr (assoc -2 block))
      )
    )
  )
)

[Coder]

In genera , how to implement the action at the picked block only . ?

Great thanks.

[Lee Mac]

In VL, a neat trick:

Code: [Select]

(if (setq e (car (nentsel))) (vla-delete (vlax-ename->vla-object e)))
This will apply the change to all block references of the block definition relating to the picked block.

If you want the change to apply to a single reference you will need to re-make the block definition with a new name without the object in question. This is better accomplished by copying the block definition (perhaps using my program here), and then applying the necessary changes, this way, Dynamic blocks would still work.

Lee

[MP]

In VL, a neat trick:

Code: [Select]

(if (setq e (car (nentsel))) (vla-delete (vlax-ename->vla-object e)))
This will apply the change to all block references of the block definition relating to the picked block.

If you want the change to apply to a single reference you will need to re-make the block definition with a new name without the object in question. This is better accomplished by copying the block definition (perhaps using my program here), and then applying the necessary changes, this way, Dynamic blocks would still work.

Lee

yep, I have a tool called bnuke built around that very algorithm -- but I didn't give it out to my (former) users -- too many people already already have enough rope to hang themselves