Topic: Attribute delete

[Shade]

Does anyone have a lisp that will remove all the attributes from selected blocks.

Our Furniture consultant uses another application that automatically tags all her furniture blocks.
We would like to remove the attribute removed from the blocks, for they show on plotting and are rather large and cluttered the drawings.
Also the attribute I believe is hidden.

Thanks
Shade

[Lee Mac]

Hmm... this deletes the attribute in the definition... but not in existing..

Code: [Select]

(defun LM::RemoveAtt (obj / sub)
  (vlax-for sub (vla-item
                  (vla-get-Blocks
                    (vla-get-ActiveDocument
                      (vlax-get-acad-object))) (vla-get-Name obj))
    (and (eq "AcDbAttributeDefinition" (vla-get-Objectname sub))
         (vla-delete sub))))

(defun c:test (/ ent)
  (vl-load-com)
 
  (and (setq ent (car (entsel "\nSelect Block: ")))
       (eq "INSERT" (cdr (assoc 0 (entget ent))))
       (LM::RemoveAtt (vlax-ename->vla-object ent)))

  (princ))



[David Bethel]

Kind of a dangerous thing to do but, here's another approach:

Code: [Select]

(defun c:delinsat (/ ss i en ed)
  (and (setq ss (ssget (list (cons 0 "INSERT")
                             (cons 66 1))))
       (setq i (sslength ss))
       (while (not (minusp (setq i (1- i))))
              (setq en (ssname ss i)
                    ed (entget en))
              (entmake (subst '(66 . 0) '(66 . 1) ed))
              (entdel en)))
  (command "_.REGENALL")
  (prin1))

-David

[alanjt]

Wrote these earlier, but had to help the wife.

Code: [Select]

(defun c:Test (/ e)
  (and (setq e (car (entsel "\nSelect block: ")))
       (setq e (vlax-ename->vla-object e))
       (eq "AcDbBlockReference" (vla-get-objectname e))
       (eq (vla-get-hasattributes e) :vlax-true)
       (mapcar 'vla-delete
               (vlax-safearray->list
                 (vlax-variant-value
                   (vla-getattributes e)
                 ) ;_ vlax-variant-value
               ) ;_ vlax-safearray->list
       ) ;_ mapcar
  ) ;_ and
  (princ)
) ;_ defun



(defun c:Test (/ ss)
  (and (setq ss (ssget "_:L" '((0 . "INSERT") (66 . 1))))
       (foreach x (vl-remove-if 'listp (mapcar 'cadr (ssnamex ss)))
         (mapcar 'vla-delete
                 (vlax-safearray->list
                   (vlax-variant-value
                     (vla-getattributes
                       (vlax-ename->vla-object x)
                     ) ;_ vla-getattributes
                   ) ;_ vlax-variant-value
                 ) ;_ vlax-safearray->list
         ) ;_ mapcar
       ) ;_ foreach
  ) ;_ and
) ;_ defun


[Lee Mac]

Oh, of course Alan - not sure why I didn't think of that   

[Lee Mac]

Just a modification of yours Alan, but thought I'd make it shorter 

Code: [Select]

(defun c:test (/ ss)
  (and (setq ss (ssget "_:L" '((0 . "INSERT") (66 . 1))))
       (foreach x (vl-remove-if 'listp (mapcar 'cadr (ssnamex ss)))
         (mapcar 'vla-delete (vlax-invoke (vlax-ename->vla-object x) 'GetAttributes))))
  (princ))


[Lee Mac]

Perhaps another way around it?

Code: [Select]

(defun c:test (/ ss)
  (and (setq ss (ssget "_:L" '((0 . "INSERT") (66 . 1))))
       (foreach x (vl-remove-if 'listp (mapcar 'cadr (ssnamex ss)))
         (mapcar (function (lambda (x) [color=red](vla-put-invisible x :vlax-true)[/color]))
                 (vlax-invoke (vlax-ename->vla-object x) 'GetAttributes))))
  (princ))


[alanjt]

Just a modification of yours Alan, but thought I'd make it shorter 

Code: [Select]

(defun c:test (/ ss)
  (and (setq ss (ssget "_:L" '((0 . "INSERT") (66 . 1))))
       (foreach x (vl-remove-if 'listp (mapcar 'cadr (ssnamex ss)))
         (mapcar 'vla-delete (vlax-invoke (vlax-ename->vla-object x) 'GetAttributes))))
  (princ))


Code: [Select]

[color=red](vlax-invoke (vlax-ename->vla-object x) 'GetAttributes))))[/color]That's the one I was trying to remember!! I'm such a retard.

[alanjt]

Perhaps another way around it?

Code: [Select]

(defun c:test (/ ss)
  (and (setq ss (ssget "_:L" '((0 . "INSERT") (66 . 1))))
       (foreach x (vl-remove-if 'listp (mapcar 'cadr (ssnamex ss)))
         (mapcar (function (lambda (x) [color=red](vla-put-invisible x :vlax-true)[/color]))
                 (vlax-invoke (vlax-ename->vla-object x) 'GetAttributes))))
  (princ))


Oooo, nice one.

[Lee Mac]

Code: [Select]

[color=red](vlax-invoke (vlax-ename->vla-object x) 'GetAttributes))))[/color]That's the one I was trying to remember!! I'm such a retard.

So am I judging by my first post... 

[alanjt]

Code: [Select]

[color=red](vlax-invoke (vlax-ename->vla-object x) 'GetAttributes))))[/color]That's the one I was trying to remember!! I'm such a retard.

So am I judging by my first post... 

LoL
It's always nice to laugh at ourselves. 

[CAB]

Just a modification of yours Alan, but thought I'd make it shorter 

Code: [Select]

(defun c:test (/ ss)
  (and (setq ss (ssget "_:L" '((0 . "INSERT") (66 . 1))))
       (foreach x (vl-remove-if 'listp (mapcar 'cadr (ssnamex ss)))
         (mapcar 'vla-delete (vlax-invoke (vlax-ename->vla-object x) 'GetAttributes))))
  (princ))


Code: [Select]

(defun c:test ()
  (foreach x (vl-remove-if 'listp (mapcar 'cadr (ssnamex (ssget "_:L" '((0 . "INSERT") (66 . 1))))))
         (mapcar 'vla-delete (vlax-invoke (vlax-ename->vla-object x) 'GetAttributes))))
  (princ))

[alanjt]

Just a modification of yours Alan, but thought I'd make it shorter  

Code: [Select]

(defun c:test (/ ss)
  (and (setq ss (ssget "_:L" '((0 . "INSERT") (66 . 1))))
       (foreach x (vl-remove-if 'listp (mapcar 'cadr (ssnamex ss)))
         (mapcar 'vla-delete (vlax-invoke (vlax-ename->vla-object x) 'GetAttributes))))
  (princ))


Code: [Select]

(defun c:test ()
  (foreach x (vl-remove-if 'listp (mapcar 'cadr (ssnamex (ssget "_:L" '((0 . "INSERT") (66 . 1))))))
         (mapcar 'vla-delete (vlax-invoke (vlax-ename->vla-object x) 'GetAttributes))))
  (princ))

Code: [Select]

Error: bad argument type: lselsetp nil  

Just nit-picking for not accounting for a nil ssget.

[CAB]

Well shoot.

 

[alanjt]

Well shoot.

 

:whistle: