Topic: remove similar sub-lists from one list

[robertocuba]

hello:

I'm trying to write a test function which remove similar sub-lists from one liste.

Example: (("m1-1" 10 20) ("m1-2" 50 20) ("m1-3" 45 67) ("m1-1" 10 20) ("m1-2" 2 4) ("m1-1" 20 20))

Must be return:

(("m1-1" 10 20) ("m1-2" 50 20) ("m1-3" 45 67) ("m1-2" 2 4))

Thanks !

[MP]

By "similar" do you mean "comparing only the key, or first item in each sub list" and does "remove similar sub-lists" mean "keep the first instance"?

[gile]

Hi

My 'favorite'

Code: [Select]

(defun remove_doubles (lst)
  (if lst
    (cons (car lst) (remove_doubles (vl-remove (car lst) lst)))
  )
)
EDIT: I read too fast.

If The answer to MP's questions in "yes", this should be:

Code: [Select]

(defun remove_same_car (l)
  (if lst
    (cons (car l)
  (remove_same_car
    (vl-remove-if
      (function (lambda (x) (equal (caar l) (car x))))
      (cdr l)
    )
  )
    )
  )
)
But none of these returns the expected result whith the example list:

(remove_doubles lst) --> (("m1-1" 10 20) ("m1-2" 50 20) ("m1-3" 45 67) ("m1-2" 2 4) ("m1-1" 20 20))
(remove_same_car lst) --> (("m1-1" 10 20) ("m1-2" 50 20) ("m1-3" 45 67))

[robertocuba]

Why not function with this:

(defun remove_doubles (lst)
  (if lst
    (cons (car lst) (remove_doubles (vl-remove (car lst) lst)))
  )
  (princ lst)
)

(defun c:a ()
  (setq a (list '(("m1-1" 20 20) ("m1-2" 50 20) ("m1-3" 45 67) ("m1-1" 20 20) ("m1-2" 2 4))))

  (remove_doubles a)
)

[MP]

It would appear this is the solution but naming it eludes me:

Code: [Select]

(defun foo ( lst / a )

    ;; An abused variant of a function penned/posted by Gile

    (if lst
        (cons
            (setq a (car lst))
            (foo
                (vl-remove-if
                    (function
                        (lambda ( b )
                            (and
                                (eq (car a) (car b))
                                (eq (last a) (last b))
                            )
                        )
                    )
                    (cdr lst)
                )
            )
        )
    )
)
(foo '(("m1-1" 10 20) ("m1-2" 50 20) ("m1-3" 45 67) ("m1-1" 10 20) ("m1-2" 2 4) ("m1-1" 20 20)))

(("m1-1" 10 20) ("m1-2" 50 20) ("m1-3" 45 67) ("m1-2" 2 4))

[robertocuba]

Yes !

With the foo function is ok !!!!

Thanks

[MP]

A little tighter but not much:

Code: [Select]

(defun foo ( lst )
    (if lst
        (cons (car lst)
            (foo
                (vl-remove-if
                   '(lambda (b)
                        (and
                            (eq (caar lst) (car b))
                            (eq (caddar lst) (caddr b))
                        )
                    )
                    (cdr lst)
                )
            )
        )
    )
)