Topic: Lisp Objects

[Jeff H]

Out of curiosity,

No code needed unless you feel like posting code,
but was wondering if someone could explain briefly how you would go about doing this.


How would you print 10 people's First Name, Last Name, and age.

By print I meant to console or acad, but does not matter more interested in how you do it.

Do you create 10 people objects?
Or 3 separate list containing the info for each person at the same nth in each list?

As mentioned earlier not asking for someone to code for me just wondering if it was not to trouble to explain in a sentence or two.

Thanks

[gile]

Hi,

AutoLISP do not know 'objects'. It only knows few types:

integer: INT (int32)
double: REAL
string: STR
symbol: SYM

and somme others related to AuoCAD:

entity name: ENAME (close to ObjectId)
selection set: PICKSET
functions: SUBR, USUBR, EXRXSUBR
ActiveX object: VLA-OBJECT
variant: VARIANT
safearray: SAFEARRAY

An, of course, list: LIST.

IMO the closest AutoLISP 'thing' to an object with properties should be an association list (which are closed to .NET Dictionaries). It's the way used by AutoLISP to expose entities DXF properties.

So an AutoLISP 'Person' could a list like:

Code: [Select]

((0 . lastName) (1 . firstName) (70 . age))or more explicitly:

Code: [Select]

(("LastName" . lastName) ("FirstName" . firstName) ("Age" . age))

[Kerry]

I would use the second example from gile ..

< .. > or more explicitly:

Code: [Select]

(("LastName" . lastName) ("FirstName" . firstName) ("Age" . age))

persons can be collected into a list of people easily

a collection can be sorted or searched relatively easily

not at efficient or self contained as objects, but 'functional' to suit the language.

[Jeff H]

Thanks guys

So something like

Code: [Select]

((("1LastName" . lastName) ("1FirstName" . firstName) ("1Age" . age)) (("2LastName" . lastName) ("2FirstName" . firstName) ("2Age" . age)))......more parenthess

[dgorsman]

For only ten names, dotted pair list indexed by a unique "username" e.g.

Code: [Select]

(("username1" ("Lastname" . "Some last name") ("Firstname" . "Some other first name"))("username2" ("Lastname" . "A last name")))

[Kerry]

I'd probably start something like this :

Code: [Select]

(setq var:people '())


(defun make_person (LastName FirstName Age / index perp perpDef )
  (setq index      (1+ (length var:people))
        perp       (list (cons "LastName" LastName) (cons "FirstName" FirstName) (cons "Age" Age))
        perpDef    (cons (cons "ID" index) list perp)
        var:people (cons perpDef var:people)
  )
)


(defun define_person ( / LastName FirstName Age)
  (if
    (and (and (setq LastName (getstring nil "\nLastName ")) (/= (strlen LastName) 0))
         (and (setq FirstName (getstring nil "\nFirstName ")) (/= (strlen FirstName) 0))
         (or (initget 7) (setq Age (getint "\nAge ")))
    )
     (make_person LastName FirstName Age)
  )
)


(defun count_population ()
  (alert (strcat "Population is " (itoa (length var:people))))
)

(defun initial_populate ()
  (make_person "Bloggs" "Joe" 42)
  (make_person "Duck" "Fred" 5)
  (make_person "Mouse" "Minnie" 69)
)

;;----------------------------
(defun c:doit ()
  (initial_populate)
  (count_population)
  (while (define_person) (count_population))
  (princ)
)
(princ)


;;----------------------------





[Kerry]

Then something like :

Code: [Select]



(defun peep_census ()
  (foreach peep var:people    
    (princ (cdr (assoc "ID" peep)))
    (terpri)
    (princ (strcat (cdr (assoc "LastName" peep))
                   ", "
                   (cdr (assoc "FirstName" peep))
                   ": "
                   (itoa (cdr (assoc "Age" peep)))
           )
    )
    (terpri)
  )
  (princ)
)


Command: (peep_census)
4
Roark, Howard: 68
3
Mouse, Minnie: 69
2
Duck, Fred: 5
1
Bloggs, Joe: 42

Of course, these are all very primitive and far from bomb-proof but could be a place to start.

[CAB]

I tend to use fixed list structures

Code: [Select]

(defun c:test()
;;  Fixed List structure
;; ("LastName"  ; string
;;  "FirstName" ; string
;;   Age        ; intiger
;;  )
(setq data
       (list
         '("Bloggs" "Joe" 42)
         '("Duck" "Fred" 5)
         '("Mouse" "Minnie" 69)

       )
)
;;  print to command line, you know th position of each item
(foreach person data
  (princ "\nLast name: ")
  (princ (car person))
  (princ "\nFirst name: ")
  (princ (cadr person))
  (princ "\nLast name: ")
  (princ (itoa (caddr person)))
)

;;  If you need to impliment an index
(setq PersonIndex '("LastName" "FirstName" "Age"))

;; find first names
(setq ptr (vl-position "FirstName" PersonIndex))

;;  find Fred
(setq idx -1
      item "Fred"
      )
(vl-some
  (function
    (lambda (person)
       (and (= item (nth ptr person))
            (setq result person)))) data)
  (vl-princ-to-string result)
  (princ)
)

[hermanm]

As Gile said...

AutoLISP has no built-in objects, so if you want them, you'll have to create them.

For example:

http://www.theswamp.org/index.php?topic=29356.0

Code: [Select]

Command: (axstruct 'person (list 'FirstName 'LastName 'Age))
SET-PERSON-AGE

Command: (axstruct-get-type 'person)
(PERSON (FIRSTNAME . 0) (LASTNAME . 1) (AGE . 2))

Command: (setq JoeBlack (axstruct-new 'person '("Joe" "Black" 1000000)))
(PERSON #<safearray...>)

Command: (axstruct-getval joeblack 'firstname)
"Joe"

Command: (axstruct-getval joeblack 'age)
1000000

Command: (get-person-age joeblack)
1000000



[hermanm]

Here is a slight update:

Code: [Select]

Command: (setq Amelia (person-new '("Amelia" "Earhart" 29)))
(PERSON #<safearray...>)

Command: (person amelia)
(PERSON "Amelia" "Earhart" 29)

Command: (person-list amelia)
(PERSON "Amelia" "Earhart" 29)

Command: (person-age amelia)
29

Command: (person-get-age amelia)
29