Topic: Perform operation to a single item in list

[Binky]

Hello folks,

New State, City, Job, Home, and everything else.  Took nearly a year but things have settled down enough to get back to coding so here I am again asking for your guidence.

I am kind of surprised that I have not needed/wanted to do this yet, but here I am trying to find a way to add a value to an existing value inside a list.

original list
(1 2 3 4 5)

I want to add 7 to the  3rd element something like this(only a version that works)
(setq (nth 2 list) (+(nth 2 list) 7))

list afterwards
(1 2 10 4 5 )

I can imagine ways to do this but they all involve creating a new list with the adjusted value.  Hoping for a easier solution, just drawing a blank today.

[Lee Mac]

I think I am drawing a blank too...

this is the best I have so far...   

Code: [Select]

(defun add (lst i)
  (mapcar
    (function
      (lambda (x)
        (if (eq i (vl-position x lst))
          (+ 7 x) x))) lst))

(add '(1 2 3 4 5) 2)
(1 2 10 4 5)

[T.Willey]

You may want to change the order of the arguments, so they flow better.

Code: [Select]

(defun AddAt ( inList loc num / cnt )
   
    (setq cnt -1)
    (mapcar
        (function
            (lambda ( x )
                (setq cnt (1+ cnt))
                (if (equal cnt loc)
                    (+ num x)
                    x
                )
            )
        )
        inList
    )
)

Command: (AddAt '(1 2 3 4 5) 2 7)

(1 2 10 4 5)

[T.Willey]

Another, more versatile, function.

Code: [Select]

(defun PerformAt ( func loc inList / cnt )
   
    (setq cnt -1)
    (mapcar
        (function
            (lambda ( x )
                (setq cnt (1+ cnt))
                (if (equal cnt loc)
                    (func x)
                    x
                )
            )
        )
        inList
    )
)

Command: (performat (lambda (x) (+ 3 x)) 3 '(1 2 3 4 5 6 7))
(1 2 3 7 5 6 7)

[VovKa]

Code: [Select]

(defun test (lst n func)
  (if lst
    (if (zerop n)
      (cons (func (car lst)) (cdr lst))
      (cons (car lst) (test (cdr lst) (1- n) func))
    )
  )
)
;;;(test '(1 2 3 4 5) 2 (lambda (e) (+ e 7)))


[CAB]

Code: [Select]

;; variation by CAB
(defun adjust_nth (opr num lst i)
  (setq i (1+ i))
  (mapcar '(lambda (x) (if (zerop (setq i (1- i))) (opr num x) x)) lst)
)

Code: [Select]

_$ (adjust_nth + 3 '(1 2 3 4 5 6 7) 4)
(1 2 3 4 8 6 7)

[Lee Mac]

Nice Alan, I've seen you use that method before, in your remove_nth function 

[Lee Mac]

You may want to change the order of the arguments, so they flow better.

I don't understand what you mean Tim 

[Binky]

Humbled and grateful

Thanks tons!!!!

[T.Willey]

You may want to change the order of the arguments, so they flow better.

I don't understand what you mean Tim 

The way it is written is ' add at list location number '.  It might be better written ' add at location number list '.  Slight modification, but will sound better when you say it, or think about it.  At least I think so.

[Lee Mac]

You may want to change the order of the arguments, so they flow better.

I don't understand what you mean Tim 

The way it is written is ' add at list location number '.  It might be better written ' add at location number list '.  Slight modification, but will sound better when you say it, or think about it.  At least I think so.

Ahh, I see 

[curmudgeon]

Code: [Select]

;; variation by CAB
(defun adjust_nth (opr num lst i)
  (setq i (1+ i))
  (mapcar '(lambda (x) (if (zerop (setq i (1- i))) (opr num x) x)) lst)
)

Code: [Select]

_$ (adjust_nth + 3 '(1 2 3 4 5 6 7) 4)
(1 2 3 4 8 6 7)

man!
that is clean. bravo.

[MP]

A different twist on a generic solution, Q+D, coded lean, no error checking etc.

Code: [Select]

(defun ApplyFooToNth ( [color=red]foo[/color] [color=green]n[/color] [color=blue]lst[/color] )
    (   (lambda ( bar i ) (mapcar 'bar lst))
        (lambda ( a )
            (if (eq n (setq i (1+ i)))
                (progn (defun bar (a) a) (foo a))
                a
            )
        )
        -1
    )    
)
Looks verbose but should perform reasonably.

(ApplyFooToNth (lambda (x) (+ 7 x)) 2 '(1 2 3 4 5))

=> (1 2 10 4 5)

Edit: Revised specifically to tease se7en.

[Lee Mac]

    (defun bar ( a )
        (if (eq n (setq i (+ i j)))
            (progn (defun bar (a) a) (foo a))
            a
        )
    )

I think my head just exploded...   

Nice use of colours though 

[JohnK]

Binky, where da-hell you been?! Ive tried several times to get a hold of you.
Hows things?