Topic: Find Text in a Closed Drawing

[CAB]

I need to search a group of closed drawings for a text phrase. '30" ABOVE SLAB'
I don't necessarily need to change it, although it would be nice, but I do
need to identify which files it is in.
I don't have SuperFind and I believe it is no longer available.

Any ideas?

[M-dub]

Docupoint Discovery
www.docupoint.com

It's not a simple little app, but it works very well.  We use it here for all of our drawing searching and viewing needs.  I think eloquintet is now using it as well.

[CAB]

Thanks I'll give it a try.

[M-dub]

I really do like the program.  THIS thread might be of some help if you decide to try it out...

[ronjonp]

Also try http://www.knownsoft.com/. Works well and is very fast.

[CAB]

Try Superior Search found here
http://www.freewareseek.com/utils/filemanagers/S/0-3.html

Lot easyer to use.
Make sure you uncheck 'Skip Binary files' in the Advanced tab.

[CAB]

Also try http://www.knownsoft.com/. Works well and is very fast.

Thanks I'll try it too.

[ELOQUINTET]

yeah sounds like a job for drawing searcher to me but hmmm you'd have to index all the drawing first how many drawings you need to search cab?

[Davez]

Those work great!!

Now if there was one that could modify the string of text that was searched for, that would be awesome.

[MP]

ObjectDBX can scan drawings very quickly (without opening in them in the AutoCAD edit window) and it's free, though you'll have to roll yer own code (and have to run said code from a running instance of AutoCAD). I can scan drawings in the order of 10 to 100 per minute depending on size and what I'm scanning for.

[hendie]

I have a copy of superfind somewhere.. if I can find it (heh), but I can't remember which version of Acad it stops working on...

[Jeff_M]

I need to search a group of closed drawings for a text phrase. '30" ABOVE SLAB'
Any ideas?

I just placed a VBA project file "TextFind&Replace.dvb" to The Pond that allows you to select which directory to find drawings in, select which drawings to search, what search phrase and what to replace it with.

At this point it doesn't list which drawings it found the text and modified it, but it won't be too hard too add that feature. This is a work in progress and is based on code found at CADVault.com. In fact the entire browse for folders/files is all code from there.

If you'd like to try it out, I do suggest trying it on some 'sample' drawings first. Wildcrds for the search string are NOT supported, so be as complet in your string to search for as you must. For instance, just entering an "e" for the search and replacing it with "AB", will replace ALL e's in the drawing(s) with AB......

Feedback is welcome and will result in a more polished end product.

Oh, users of ACAD prior to 2004 must make sure that Object.DBX is available to use. If you aren't sure, run this little code snippet to be sure.

Code: [Select]


 (if (and (= (atoi (getvar "AcadVer")) 15)
      (not (vl-registry-read "HKEY_CLASSES_ROOT\\ObjectDBX.AxDbDocument\\CLSID"))
      )
(startapp "regsvr32.exe" (strcat "/s \"" (findfile "axdb15.dll") "\""))
)


Jeff

[CAB]

Jeff
It stoped here
Dim bolMod As Boolean: bolMod = False

Compile Error
Invalid Outside Procedure

[Jeff_M]

Sorry CAB-
I had moved a line to the public area after testing that was supposed to be split up. If you edit the code to this it will work.

Code: [Select]


Dim strNew As String
Dim bolMod As Boolean 'EDIT this line


Private Sub UserForm_Initialize()
  'Set up
  Set objDbx = GetInterfaceObject("ObjectDBX.AxDbDocument")
  Me.Caption = "Object DBX Batch Process"
  ListBox1.MultiSelect = fmMultiSelectMulti
  CommandButton1.Caption = "Browse for folder"
  CommandButton2.Caption = "Process Selection"
  CommandButton3.Caption = "Exit"
  bolMod = False 'ADD this line
End Sub


[whdjr]

CAB,
Here is an ObjectDBX method thru vlisp.  Try it and let me know how it does for you.

Code: [Select]

(vl-load-com)

(defun *error* (msg)
  (princ "\nError: ")
  (princ msg)
  (princ)
  (if (and dbxdoc (not (vlax-object-released-p dbxdoc)))
    (vlax-release-object dbxdoc)
  )
  (gc)
  (princ)
)

(defun DLLRegister (dll)
  (startapp "regsvr32.exe" (strcat "/s \"" dll "\""))
)

(defun ProgID->ClassID (ProgID)
  (vl-registry-read
    (strcat "HKEY_CLASSES_ROOT\\" progid "\\CLSID")
  )
)

(defun DBX-Register (/)
  (if (/= (getvar "ACADVER") "15.0")
    (setq classname "ObjectDBX.AxDbDocument.16")
    (setq classname "ObjectDBX.AxDbDocument")
  )
  (cond
    ((ProgID->ClassID classname))
    ((and
       (setq server (findfile "AxDb15.dll"))
       (DLLRegister server)
       (ProgID->ClassID classname)
     )
     (ProgID->ClassID classname)
    )
    ((not (setq server (findfile "AxDb15.dll")))
     (alert
       "Error: Cannot locate ObjectDBX Type Library (AxDb15.dll)..."
     )
    )
    (T
     (DLLRegister "ObjectDBX.AxDbDocument")
     (or
       (ProgID->ClassID "ObjectDBX.AxDbDocument")
       (alert
"Error: Failed to register ObjectDBX ActiveX services..."
       )
     )
    )
  )
)

(defun findphrase (phrase document / count)
  (setq count 0)
  (vlax-for item (vla-get-modelspace document)
    (cond ((or (eq (vla-get-ObjectName item) "AcDbText")
      (eq (vla-get-ObjectName item) "AcDbMText")
  )
  (if (vl-string-search phrase (vla-get-textstring item))
    (setq count (1+ count))
  )
 )
 ((and (eq (vla-get-Objectname item) "AcDbBlockReference")
(eq (vla-get-hasattributes item) :vlax-true)
  )
  (foreach for-item (get_atts item)
    (if (vl-string-search phrase (vla-get-textstring for-item))
      (setq count (1+ count))
    )
  )
 )
    )
  )
  count
)

(defun get_atts (obj)
  (vlax-safearray->list
    (vlax-variant-value
      (vla-getattributes obj)
    )
  )
)

(defun c:tfar (/ file files str dbxdoc of lst wil classname)
  (setq file "")
  (while (setq file (getfiled "Select a file to replace text in" file "dwg" 128))
    (setq files (cons file files))
  )
  (cond ((not files) (princ "No files were selected."))
((not (setq str (getstring T "Enter search phrase?  ")))
(princ "\nSearch phrase is missing. ")
)
((not (DBX-Register)) (princ "Unable to load ObjectDBX."))
((not (setq dbxdoc (vla-GetInterfaceObject
    (vlax-get-acad-object)
    classname
  )
     )
)
(princ "Unable to load ObjectDBX.")
)
(T
(foreach f (reverse files)
  (setq of  (vl-catch-all-apply
      '(lambda ()
 (vlax-invoke-method dbxdoc 'open f)
)
    )
lst (if (vl-catch-all-error-p of)
      (list f "File was read only. ")
      (list f (findphrase str dbxdoc))
    )
wil (cons lst wil)
  )
)
)
  )
  (if (and dbxdoc (not (vlax-object-released-p dbxdoc)))
    (vlax-release-object dbxdoc)
  )
  (gc)
  (textscr)
  (mapcar '(lambda (x)
    (princ
      (strcat "\n"
      (car x)
      "\n"
      (cond ((eq (type (cadr x)) 'INT)
     (strcat (itoa (cadr x))
     " text entities matched your phrase."
     )
    )
    (T (cadr x))
      )
      )
    )
  )
 wil
  )
  (princ)
)

[CAB]

Sorry CAB-
I had moved a line to the public area after testing that was supposed to be split up. If you edit the code to this it will work.

No workie
  Error
  Subfunction not defined
 
  REPLACE
 
 

Code: [Select]

objDbx.Open strFile
    For Each objEnt In objDbx.ModelSpace
      If TypeOf objEnt Is AcadMText Then
          Set objMtext = objEnt
          strTemp = objMtext.TextString
          intStr = InStr(1, strTemp, strOld, vbTextCompare)
          If intStr > 0 Then
              objMtext.TextString =   *** Replace  ***  (strTemp, strOld, strNew)
              bolMod = True
          End If
      ElseIf TypeOf objEnt Is AcadText Then

[CAB]

CAB,
Here is an ObjectDBX method thru vlisp.  Try it and let me know how it does for you.

Looks interesting, I'll give it a try tonight. ( Work gets in the way )

[whdjr]

I forgot to give the instructions on how to use it.  When you run it it starts with a file open box and select a file to search in.  Then it returns to the file open box for another selection.  It continues this until you click cancel, then it continues the rest of the routine.

I can change this to select all dwg's within a folder if you want that functionality.
CHANGE THIS:

Code: [Select]

(defun c:tfar (/ file files str dbxdoc of lst wil classname)
  (setq file "")
  (while (setq file (getfiled "Select a file to replace text in" file "dwg" 128))
    (setq files (cons file files))
  )
TO THIS:

Code: [Select]

(defun c:tfar (/ path folder file files str dbxdoc of lst wil classname)
  (if (setq path (getfiled "Select a File" "" "dwg" (+ 4 128)))
    (setq folder (vl-filename-directory path)
 files (vl-directory-files folder "*.dwg" 1)
 files (mapcar '(lambda (x)
   (strcat folder "\\" x)
 )
files
)
    )
  )
For all files in a folder.

[Jeff_M]

No workie
  Error
  Subfunction not defined
 
  REPLACE
 
 

What the hey?!?! Which version was this in (your sig line shows 2000 & 2004)? The REPLACE is a built-in Function to the VBA that shipped with 2002, and I'd imagine it should still work with 2004. If it's the 2000 version, a special function would need to be written (which I did before I found the Replace function and, stupidly, discarded since it obviously wasn't needed.....)  

As I said, "A work in progress". Thanks for trying though. Will try to play with it tonight after my wife goes to work (she got bumped to the graveyard shift, yuck).

[CAB]

jEFF,
yES i WAS USING acad2000  Uggh-caps

[CAB]

Will got this:

Command: tfar
Enter search phrase?  trusses @ 16" oc

Error: ActiveX Server returned an error: Invalid index; reset after error

[whdjr]

CAB,

Are you trying this on A2K or A2004?
I couldn't reproduce the error.  Can you follow this in the VLIDE
and let me know where it hangs up at.

If A2K, then try this:
change:

Code: [Select]

(if (/= (getvar "ACADVER") "15.0")
    (setq classname "ObjectDBX.AxDbDocument.16")
    (setq classname "ObjectDBX.AxDbDocument")
  )
to:

Code: [Select]

(setq classname "ObjectDBX.AxDbDocument")
If A2004 then comment out this

Code: [Select]

;((not (DBX-Register)) (princ "Unable to load ObjectDBX."))
and change:

Code: [Select]

((not (setq dbxdoc (vla-GetInterfaceObject
    (vlax-get-acad-object)
    classname
  )
     )
to this:

Code: [Select]

((not (setq dbxdoc (vla-GetInterfaceObject
    (vlax-get-acad-object)
    "ObjectDBX.AxDbDocument.16"
  )
     )
Let me know what else happens.

[CAB]

Command: tfar
Enter search phrase?  trusses @ 16" oc

Error: ActiveX Server returned an error: Invalid index; reset after error

Command:

Error occurs here

Code: [Select]

(vlax-safearray->list
    (vlax-variant-value
      (vla-getattributes obj)
    )
  )

Using ACAD 2000, made the changes you suggested.
Do you want the DWG file?

[whdjr]

I still can't find an error.

Yes please send or post the drawing and the search phrase.

[CAB]

http://theswamp.org/lilly_pond/cab/Morrison%201.zip?nossi=1

trusses @16" oc

[whdjr]

CAB,

I looked over your drawing and it keeps crashing when it comes across your block "20GOBLT01".  I can't figure out why except that it says it has attributes, but when the program tries to get them its empty and therefore crashes.  I think I can catch the error with
vl-catch-all-apply and then I'll post the revision.

That's a strange one.  Anyone else got any ideas why a block would show a True flag for attributes, but then wouldn't have any?    

[whdjr]

CAB,

Here is the revised code that works on your file here in my office.  I made a few modifications to show how many pieces of text, mtext, or attdefs you had in a drawing or wether that dwg was already open.

Give this one a spin and let me know.

Code: [Select]

(vl-load-com)

(defun *error* (msg)
  (princ "\nError: ")
  (princ msg)
  (princ)
  (if (and dbxdoc (not (vlax-object-released-p dbxdoc)))
    (vlax-release-object dbxdoc)
  )
  (gc)
  (princ)
)

(defun DLLRegister (dll)
  (startapp "regsvr32.exe" (strcat "/s \"" dll "\""))
)

(defun ProgID->ClassID (ProgID)
  (vl-registry-read
    (strcat "HKEY_CLASSES_ROOT\\" progid "\\CLSID")
  )
)

(defun DBX-Register (/)
  (setq classname "ObjectDBX.AxDbDocument")
  (cond
    ((ProgID->ClassID classname))
    ((and
       (setq server (findfile "AxDb15.dll"))
       (DLLRegister server)
       (ProgID->ClassID classname)
     )
     (ProgID->ClassID classname)
    )
    ((not (setq server (findfile "AxDb15.dll")))
     (alert
       "Error: Cannot locate ObjectDBX Type Library (AxDb15.dll)..."
     )
    )
    (T
     (DLLRegister "ObjectDBX.AxDbDocument")
     (or
       (ProgID->ClassID "ObjectDBX.AxDbDocument")
       (alert
"Error: Failed to register ObjectDBX ActiveX services..."
       )
     )
    )
  )
)

(defun findphrase (phrase document / txtcount mtxtcount attcount oName)
  (setq txtcount 0
mtxtcount 0
attcount 0
  )
  (vlax-for item (vla-get-modelspace document)
    (setq oName (vla-get-ObjectName item))
    (cond ((eq oName "AcDbText")
  (if (vl-string-search phrase (vla-get-textstring item))
    (setq txtcount (1+ txtcount))
  )
 )
 ((eq oName "AcDbMText")
  (if (vl-string-search phrase (vla-get-textstring item))
    (setq mtxtcount (1+ mtxtcount))
  )
 )
 ((and (eq oName "AcDbBlockReference")
(eq (vla-get-hasattributes item) :vlax-true)
  )
  (foreach for-item (get_atts item)
    (if (vl-string-search phrase (vla-get-textstring for-item))
      (setq attcount (1+ attcount))
    )
  )
 )
    )
  )
  (list txtcount mtxtcount attcount)
)

(defun get_atts (obj / val)
  (if (vl-catch-all-error-p
(vl-catch-all-apply
 '(lambda ()
    (setq val (vlax-safearray->list
(vlax-variant-value
  (vla-getattributes obj)
)
      )
    )
  )
)
      )
    nil
    val
  )
)

(defun c:tfar (/ file files str dbxdoc of lst wil classname)
  (setq file "")
  (while (setq file (getfiled "Select a file to replace text in" file "dwg" 128))
    (setq files (cons file files))
  )
  (cond ((not files) (princ "No files were selected."))
((not (setq str (getstring T "Enter search phrase?  ")))
(princ "\nSearch phrase is missing. ")
)
((not (DBX-Register)) (princ "Unable to load ObjectDBX."))
((not (setq dbxdoc (vla-GetInterfaceObject
    (vlax-get-acad-object)
    classname
  )
     )
)
(princ "Unable to load ObjectDBX.")
)
(T
(foreach f (reverse files)
  (setq of  (vl-catch-all-apply
      '(lambda ()
 (vlax-invoke-method dbxdoc 'open f)
)
    )
lst (if (vl-catch-all-error-p of)
      (list f "File was read only. ")
      (list f (findphrase str dbxdoc))
    )
wil (cons lst wil)
  )
)
)
  )
  (if (and dbxdoc (not (vlax-object-released-p dbxdoc)))
    (vlax-release-object dbxdoc)
  )
  (gc)
  (textscr)
  (mapcar '(lambda (x)
    (princ
      (strcat "\n"
      (car x)
      (cond ((eq (type (cadr x)) 'LIST)
     (apply 'strcat
    (mapcar '(lambda (y z)
(strcat "\n" (itoa y) z)
     )
    (cadr x)
    '(" text entities matched your phrase."
      " mtext entities matched your phrase."
      " attribute reference entities matched your phrase.\n"
     )
    )
     )
    )
    (T (strcat "\n" (cadr x))
      )
      )
    )
  )
 wil
  )
  (princ)
)

[CAB]

CAB,

I looked over your drawing and it keeps crashing when it comes across your block "20GOBLT01".  I can't figure out why except that it says it has attributes, but when the program tries to get them its empty and therefore crashes.  I think I can catch the error with
vl-catch-all-apply and then I'll post the revision.

That's a strange one.  Anyone else got any ideas why a block would show a True flag for attributes, but then wouldn't have any?    

Will,
The block is one created by Arch-T. The attribute has a tag 'Go-Bolt' which
displays on the screen and was used to make a slide so the slide has a
visible label in the original drawing but will not be displayed when inserted
as the attribute is empty.
That is my understanding of it anyway.
CAB

[CAB]

Command: tfar
Enter search phrase?  trusses @16" oc

That seemed to work, although case sensitive.

Command: tfar
Enter search phrase?  trusses @ 16" oc

C:\Program Files\ACAD2000\=Active Projects\Steve Carter\4225 Morrison\4225
Morrison Master 1.DWG
0 text entities matched your phrase.
0 mtext entities matched your phrase.
0 attribute reference entities matched your phrase.

Command:
Command:
Command:
Command: _open
Command: tfar
Enter search phrase?  PRE MFG TRUSSES @ 16" OC

C:\Program Files\ACAD2000\=Active Projects\Steve Carter\4225 Morrison\4225
Morrison Master 1.DWG
3 text entities matched your phrase.
0 mtext entities matched your phrase.
0 attribute reference entities matched your phrase.

Command:
Command: PRE PREVIEW
Press ESC or ENTER to exit, or right-click to display shortcut menu.

Command: tfar
Enter search phrase?  TRUSSES @ 16" OC

C:\Program Files\ACAD2000\=Active Projects\Steve Carter\4225 Morrison\4225
Morrison Master 1.DWG
3 text entities matched your phrase.
0 mtext entities matched your phrase.
0 attribute reference entities matched your phrase.

Command:

Message when file was open:

Command: tfar
Enter search phrase?  trusses @16" oc

C:\Program Files\ACAD2000\=Active Projects\Steve Carter\4225 Morrison\4225
Morrison Master 1.DWG
File was read only.

[whdjr]

Glad that worked for you.