Topic: Auto load ARX

[77077]

Hi all
Operating system contains 32 and 64 - bit version , autoCAD contains  R15~ R20 version .

How to automatically load matching arx ?

Code: [Select]

(defun S::STARTUP ()
  (cond
    ((= (atoi (substr (getvar "acadver") 1 2))17)
      (if (not (member "OpenDCL.17.arx" (arx)))
        (if (findfile "OpenDCL.17.arx")
          (arxload "OpenDCL.17.arx")
        )
      )
    )
    ((= (atoi (substr (getvar "acadver") 1 2))18)
      (if (not (member "OpenDCL.18.arx" (arx)))
        (if (findfile "OpenDCL.18.arx")
          (arxload "OpenDCL.18.arx")
        )
      )
    )
  )
)

I need for my CAD and OS ,Automatically select the appropriate ARX.

and written this ARX patch & name  to the  acad.rx

Is possible?

[tombu]

I'd put acad.rx files in the paths of each version.  Best way to autoload arx files.

[ronjonp]

I don't use open dcl but maybe this .. not sure if the arx names vary per architecture.
Yup .. looks like it does.

Code - Auto/Visual Lisp: [Select]

1. (defun s::startup (/ odcl)
2.   (and (setq odcl (strcat "OPENDCL." (substr (getvar "acadver") 1 2) ".ARX"))
3.        (not (member odcl (mapcar 'strcase (arx))))
4.        (findfile odcl)
5.        (arxload odcl)
6.   )
7. )

[77077]

I'd put acad.rx files in the paths of each version.  Best way to autoload arx files.

Yes , two methods ,1. Write the registry 2. Write to acad.rx

I need to choose which one need load for my cad and OS

[77077]

I don't use open dcl but maybe this .. not sure if the arx names vary per architecture.
Yup .. looks like it does.

Code - Auto/Visual Lisp: [Select]

1. (defun s::startup (/ odcl)
2.   (and (setq odcl (strcat "OPENDCL." (substr (getvar "acadver") 1 2) ".ARX"))
3.        (not (member odcl (mapcar 'strcase (arx))))
4.        (findfile odcl)
5.        (arxload odcl)
6.   )
7. )

Thanks ,But I can't understand. If my OS is 64bit ?

I need for my CAD and OS ,Automatically select the appropriate ARX.

and written this ARX patch & name  to the  acad.rx

Is possible?

[ronjonp]

Look at the link in my previous post .. detecting the architecture is fairly easy like so:

Code - Auto/Visual Lisp: [Select]

1. (if (vl-string-search "64" (getenv "PROCESSOR_ARCHITECTURE"))
2.   "x64"
3.   "x32"
4. )

[jbuzbee]

(command "OpenDCL")

[77077]

(command "OpenDCL")

I'm not use for opendcl

[77077]

Look at the link in my previous post .. detecting the architecture is fairly easy like so:

Code - Auto/Visual Lisp: [Select]

1. (if (vl-string-search "64" (getenv "PROCESSOR_ARCHITECTURE"))
2.   "x64"
3.   "x32"
4. )

Thanks ronjonp
XLRX_API.R16.x32.arx is for cad2004~2006
XLRX_API.R2005.arx is for cad2005
SO if my cad version is cad2005 , that need load XLRX_API.R2005.arx  not XLRX_API.R16.x32.arx  ?
I'm a Newt ,I need a fish ,  can you give me ?

[ronjonp]

Just thinking outside the box but .. why don't you rename those earlier versions to match the naming convention that uses (substr (getvar "acadver") 1 2) .. that would simplify things.

This should work for the file list you posted above .. but I'd still recommend using a standard naming convention.

Code - Auto/Visual Lisp: [Select]

1. (defun s::startup (/ a f v v2)
2.   (and (setq a (if (vl-string-search "64" (getenv "PROCESSOR_ARCHITECTURE"))
3.                  ".X64.ARX"
4.                  ".X32.ARX"
5.                )
6.        )
7.        (setq v (substr (ver) 13 4))
8.        (setq v2 (substr (getvar "acadver") 1 2))
9.        (setq f (strcat "XLRX_API.R"
10.                        (cond ((wcmatch v "2005,2006") (strcat v ".ARX"))
11.                              ((= v "2008") (strcat v a))
12.                              ((strcat v2 a))
13.                        )
14.                )
15.        )
16.        (findfile f)
17.        (not (member (strcase f) (mapcar 'strcase (arx))))
18.        (arxload f)
19.   )
20. )

[irneb]

XLRX_API.R16.x32.arx is for cad2004~2006
XLRX_API.R2005.arx is for cad2005
SO if my cad version is cad2005 , that need load XLRX_API.R2005.arx  not XLRX_API.R16.x32.arx  ?
I'm a Newt ,I need a fish ,  can you give me ?

Agreed about renaming ... Can you rename the ARX files to use ACad's internal version numbers instead of those external 20## numbers?


If not you could build the possible version numbers using this:

Code - Auto/Visual Lisp: [Select]

1. (defun get-acadversions (/ r i j L a)
2.   (setq r (atof (getvar "acadver"))
3.         i (atoi (rtos r))
4.         j (atoi (rtos (* 10 (- r i))))
5.         L (list (itoa i) (strcat (itoa i) "." (itoa j))))
6.   (if (>= i 15)
7.     (setq L (cons
8.               (cond ((= i 15)
9.                      (strcat "200" (cond ((= j 1) "1i") (t (itoa j)))))
10.                     ((< i 19)
11.                      (itoa (+ 2004 (* (- i 16) 3) j)))
12.                     (t
13.                      (itoa (+ 2013 (* (- i 19) 2) j))))
14.               L)))
15.   (append L (mapcar '(lambda (s) (strcat "r" s)) L)))

Then use a function to search for the first file found using those numbers. Something like this:

Code - Auto/Visual Lisp: [Select]

1. (defun find-by-ver (pre post)
2.   (vl-remove 'nil (mapcar '(lambda (v) (findfile (strcat pre v post)))
3.                           (get-acadversions))))

You could call it thus in your scenario:

Code - Auto/Visual Lisp: [Select]

1. (if (setq found (find-by-ver
2.                   "XLRX_API."
3.                   (strcat (if (vl-string-search "64" (getenv "PROCESSOR_ARCHITECTURE"))
4.                             "x64"
5.                             "x32")
6.                           ".arx")))
7.   (arxload (car found)))

[Lee Mac]

Nice idea & code Irné - I see you have cracked the AutoCAD release numbering pattern

Perhaps another way to write it to avoid the reliance on Autodesk being consistent...

Code - Auto/Visual Lisp: [Select]

1. (defun acadversions ( / a b c d )
2.     (setq a (getvar 'dimzin)
3.           b (atof (getvar 'acadver))
4.     )
5.     (setvar 'dimzin 0)
6.     (setq c (list (substr (ver) 13 (- (strlen (ver)) 17)) (rtos b 2 0) (rtos b 2 1))
7.           d (append c (mapcar 'strcat '("r" "r" "r") c))
8.     )
9.     (setvar 'dimzin a)
10.     d
11. )

[ronjonp]

Nice Lee .. this is the way I'd write it.

Code - Auto/Visual Lisp: [Select]

1.  
2. (defun acadversions (/ l m a c)
3.   (setq l (getvar 'dimzin)
4.         m (atof (getvar 'acadver))
5.   )
6.   (setvar 'dimzin 0)
7.   (setq a (list (substr (ver) 13 (- (strlen (ver)) 17)) (rtos m 2 0) (rtos m 2 1))
8.         c (append a (mapcar 'strcat '("r" "r" "r") a))
9.   )
10.   (setvar 'dimzin l)
11.   c
12. )
13. (acadversions)
14.  

[Lee Mac]

Haha! 

Thanks Ron 

[alanjt]

Here's my lazy method...

Code: [Select]

;; DosLib
(vl-some (function (lambda (dos)
                     (or (vl-position dos (arx))
                         (not (vl-catch-all-error-p (vl-catch-all-apply 'arxload (list dos))))
                     )
                   )
         )
         (vl-directory-files "C:\\alan\\arx\\" "DOSLIB*ARX")
)