Print Page - Autolisp Open Multiple Files and Run LISP

Code Red => AutoLISP (Vanilla / Visual) => Topic started by: mailmaverick on May 28, 2019, 12:25:08 AM

Title: Autolisp Open Multiple Files and Run LISP
Post by: mailmaverick on May 28, 2019, 12:25:08 AM

Hi,

Is is possible within AutoLISP to Open selected Multiple AutoCAD Files, Run a given LISP, Save and Close the files, one by one.
If yes then how ?
Thanks.

Title: Re: Autolisp Open Multiple Files and Run LISP
Post by: kpblc on May 28, 2019, 12:54:48 AM

I think you can't do it by simple lisp. Use script or ObjectDBX.

Title: Re: Autolisp Open Multiple Files and Run LISP
Post by: MP on May 28, 2019, 01:05:35 AM

You can do it by invoking a vba routine from lisp.

Title: Re: Autolisp Open Multiple Files and Run LISP
Post by: MSTG007 on May 28, 2019, 06:55:50 AM

I went from scripts (scriptpro) to using the acaddoc.lsp. Works great for me.

Title: Re: Autolisp Open Multiple Files and Run LISP
Post by: vincent.r on May 28, 2019, 10:51:57 AM

@MSTG007 can you please explain ? I tried it some days back but was not successful.

Title: Re: Autolisp Open Multiple Files and Run LISP
Post by: MSTG007 on May 28, 2019, 11:03:35 AM

Hopefully this will make more sense. At least it works for me.

Code: [Select]

(defun c:Batch_Via_ACADDOC_LSP ()

;;Load this acaddoc.lsp within a support path.
;;If  ;;  is in front of the line, it will not work when opening drawings.
;;Remove  ;;  this to get command to work on each drawing it opens.


;;Place Code Below
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;

;;(command "-layout" "set" "")

;;(command "-layer" "set" "0" "freeze" "*SEAL*" "")

;;(command "purge" "a" "" "n")

;;(command "purge" "regapps" "" "n")

;;(command "purge" "a" "" "n")

;;(command "_.close" "");;Closes Drawing with Saving

;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;;Keep Bottom Code
)
(c:Batch_Via_ACADDOC_LSP)
(princ)

Title: Re: Autolisp Open Multiple Files and Run LISP
Post by: kpblc on May 28, 2019, 11:39:53 AM

mailmaverick, what kind of lisp you wnat to run? If this lisp uses only activex methods, it could be run in ObjectDBX mode.

Title: Re: Autolisp Open Multiple Files and Run LISP
Post by: mailmaverick on May 29, 2019, 04:31:21 AM

Quote from: kpblc on May 28, 2019, 11:39:53 AM

mailmaverick, what kind of lisp you wnat to run? If this lisp uses only activex methods, it could be run in ObjectDBX mode.

I have to run normal LISP which shall put particular objects in given layers, such as all Dimensions in "DIM" Layer, all Texts in "TEXT" layer and then Save the File, Close and Proceed to next File.

If its possible in ObjectDBX, please let me know how to do it. Thanks.

Title: Re: Autolisp Open Multiple Files and Run LISP
Post by: kpblc on May 29, 2019, 04:53:33 AM

Without any testing:

Code - Auto/Visual Lisp: [Select]

(defun change-prop-in-dwgs (dwg-list / odbx conn layers)
  (foreach file dwg-list
    (if (findfile file)
      (progn (vl-file-copy file (strcat (vl-filename-directory file) "\\" (vl-filename-base file) "_dbx.bak"))
             (setq conn   (vla-open (vla-getinterfaceobject (vlax-get-acad-object)
                                                            (strcat "ObjectDBX.AxDbDocument." (itoa (atoi (getvar "acadver"))))
                                                            ) ;_ end of vla-getinterfaceobject
                                    file
                                    ) ;_ end of vla-open
                   layers nil
                   ) ;_ end of setq
             (vlax-for item (vla-get-layers conn)
               (setq layers (cons (cons item
                                        (mapcar (function (lambda (x / tmp)
                                                            (setq tmp (vlax-get-property item x))
                                                            (vl-catch-all-apply (function (lambda () (vlax-put-property item x :vlax-false))))
                                                            (cons x tmp)
                                                            ) ;_ end of lambda
                                                          ) ;_ end of function
                                                '("freeze" "lock")
                                                ) ;_ end of mapcar
                                        ) ;_ end of cons
                                  layers
                                  ) ;_ end of cons
                     ) ;_ end of setq
               ) ;_ end of vlax-for
             (foreach item '("TEXT" "DIM")
               (if (vl-catch-all-error-p
                     (vl-catch-all-apply (function (lambda () (vla-item (vla-get-layers conn) item))))
                     ) ;_ end of vl-catch-all-error-p
                 (vla-add (vla-get-layers conn) item)
                 ) ;_ end of if
               ) ;_ end of foreach
             (vlax-for def (vla-get-blocks conn)
               (vlax-for ent def
                 (cond ((wcmatch (strcase (vla-get-objectname ent) "*TEXT")) (vla-put-layer ent "TEXT"))
                       ((wcmatch (strcase (vla-get-objectname ent) "ACDB*DIM*")) (vla-put-layer ent "DIM"))
                       ) ;_ end of cond
                 ) ;_ end of vlax-for
               ) ;_ end of vlax-for
             (foreach item layers
               (foreach pr (cdr item)
                 (vl-catch-all-apply (function (lambda () (vlax-put-property item (car pr) (cdr pr)))))
                 ) ;_ end of foreach
               ) ;_ end of foreach
             (vlax-invoke conn 'saveas file)
             (vl-catch-all-apply (function (lambda () (vlax-release-object conn))))
             (setq conn nil)
             ) ;_ end of progn
      ) ;_ end of if
    ) ;_ end of foreach
  ) ;_ end of defun

Title: Re: Autolisp Open Multiple Files and Run LISP
Post by: mailmaverick on May 29, 2019, 05:58:25 AM

Thanks a lot. That should get me going !!!!

Title: Re: Autolisp Open Multiple Files and Run LISP
Post by: kdub_nz on May 29, 2019, 06:48:35 PM

kpblc
I like that you save/archive the file before you work on it.

TheSwamp

Code Red => AutoLISP (Vanilla / Visual) => Topic started by: mailmaverick on May 28, 2019, 12:25:08 AM