Topic: delete block in all layout.

[Andrea]

Hi all...

I'm trying to find a routine who can delete a specific block name in ALL LAYOUT
without changing layout..

I know it's possible....but to much work here...
so if you can give me a hand...it will be appreciated..

thanks

[kpblc]

Code: [Select]

(defun test (/ block_name)
  (if (and (setq block_name (getstring t "\nBlock Name : "))
   (tblobjname "block" block_name)
   ) ;_ end of and
    (foreach item
  (mapcar
    'vlax-ename->vla-object
    (vl-remove-if
      'listp
      (mapcar
'cadr
(ssnamex
  (ssget "_X"
(list '(0 . "INSERT")
       '(410 . "~model")
       (cons 2 block_name)
       ) ;_ end of list
) ;_ end of ssget
  ) ;_ end of ssnamex
) ;_ end of mapcar
      ) ;_ end of vl-remove-if
    ) ;_ end of mapcar
      (vla-erase item)
      ) ;_ end of foreach
    ) ;_ end of if
  ) ;_ end of defun

[CADmium]

a function in ActivX :

Code: [Select]

(defun blockrefdelete(Blockname / Block)
  (vlax-for layout(vla-get-layouts(vla-get-activedocument(vlax-get-acad-object)))
    (vlax-for ITEM (vla-get-block Layout)
      (if(and(member(strcase(vla-get-objectname  ITEM))
                   '("ACDBBLOCKREFERENCE" "ACDBMINSERTBLOCK")
             )
             (=(strcase(vla-get-name ITEM))(strcase BLOCKNAME))
         )
        (vla-delete ITEM)
      ) 
    )
  )
)

or try

Code: [Select]

(defun blockrefdelete(BLOCKNAME / LISTE)
  (if(and(setq BLOCK (tblobjname "block" BLOCKNAME))   
         (setq LISTE(entget(cdr (assoc 330 (entget BLOCK)))))
         (setq LISTE(cdr(reverse(cdr(member(assoc 102 LISTE)LISTE)))))
     )
    (mapcar '(lambda(X)
               (not(vl-catch-all-error-p
                     (vl-catch-all-apply
                       'vla-delete
                       (list X)
                     )
                   )
               )
             )
             (vl-remove-if-not '(lambda(Y) Y)       
                (mapcar '(lambda(X) (vlax-ename->vla-object  X))
                        (mapcar '(lambda(X) (cdr X)) LISTE)
                )
             )   
    )             
  )
)


and you can call both functions

(blockrefdelete (cdr(assoc 2(entget(ssname (ssget "_:S" '((0 . "INSERT")))0)))))

[Patrick_35]

Hi
An another

Code: [Select]

(defun c:delb(/ bloc bls bl ent)
  (if (setq bloc (getstring T "\nBlock name : "))
    (if (tblsearch "block" bloc)
      (progn
        (setq bls (vla-get-blocks (vla-get-activedocument (vlax-get-acad-object))))
        (vlax-for bl bls
          (vlax-for ent bl
            (if (eq (vla-get-objectname ent) "AcDbBlockReference")
              (if (eq (strcase (vla-get-name ent)) (strcase bloc))
                (vla-delete ent)
              )
            )
          )
        )
      )
      (princ (strcat "\nBlock " bloc " don't exist"))
    )
  )
  (princ)
)
@+

[kpblc]

Your code will erase block definition, not reference (i think). And anyway you're working with block collection (not insertions)

[Patrick_35]

There is an trick. Test it

@+

[CAB]

This is an oldie I created. May not be what you want.
Deletes a list of block names and purges them.

<edit: removed code as it does not work as planed>

[ElpanovEvgeniy]

This is an oldie I created. May not be what you want.
Deletes a list of block names and purges them.

Today, my morning began from such program and coffee...
Your program deletes all blocks only in the last page

[CAB]

Thanks Evgeniy

Checking the code, you are correct.
Back then I was using one layout drawings & switched to xrefs & multi tabs
and left that code behind. I'll put it in the trash bin and use yours.

[ElpanovEvgeniy]

I have deleted the last post...
Has rechecked it is it does not work: (

[CAB]

kpblc & Evgeniy

If I may be so bold, I took your routines & modified for my subroutine like this.

Code: [Select]

(defun delblock_1 (bnames / ss)
  (if (setq ss
             (ssget
               "_X"
               (list
                 '(0 . "INSERT")
                 (cons 2
                       (substr
                         (apply
                           (function strcat)
                           (mapcar (function (lambda (x) (strcat "," x)))
                                   bnames
                           )
                         )
                         2
                       ) ;_  substr
                 )
               ) ;_ end of list
             ) ;_ end of ssget
      )
    (foreach item
                  (mapcar
                    'vlax-ename->vla-object
                    (vl-remove-if 'listp (mapcar 'cadr (ssnamex ss)))
                  ) ;_ end of mapcar
      (vla-erase item)
    ) ;_ end of foreach
  )
) ;_ end of defun

Code: [Select]

(delblock_1 '("Aproved Title Block D" "Aproved Title Block"))

[Andrea]

Woo !   

thanks all for the quick response..

[whdjr]

This is my favorite however I am partial.   

[Andrea]

nice one wh...

[ELOQUINTET]

I just happened to come across this post in a search and was wondering if anyone has a lisp that I could run in a batch script to get rid of a specified block from all layouts without picking it. It would also be splendid if it then purged the block out of the drawing. I know this is available just haven't had the time to do a full sweep of the forum today.

[ronjonp]

Dan,

You could use this:

Code: [Select]

(defun eblock (bname / ss)
  (if (setq ss (ssget "_X" (list (cons 2 bname))))
    (progn
      (mapcar 'entdel (mapcar 'cadr (ssnamex ss)))
      (vla-purgeall
(vla-get-activedocument (vlax-get-acad-object))
      )
    )
  )
)
(eblock)

To use in your script: (eblock "yourblockname")

Ron

[T.Willey]

If you don't want to purge everything, you can just try and erase the blocks definition from the block collection.

Code: [Select]

(if
 (not
  (vl-catch-all-error-p
   (setq BlkObj
    (vl-catch-all-apply
     'vla-Item
     (list
      (vla-get-Blocks (vla-get-ActiveDocument (vlax-get-Acad-Object)))
      bname
     )
    )
   )
  )
 )
 (vl-catch-all-error-p 'vla-Delete (list BlkObj))
)


[Jeff_M]

Code: [Select]

.
 .....
      (mapcar 'entdel (mapcar 'cadr (ssnamex ss)))
 ....
.
Ron

Ron,
I, too, thought this would work until I was recently advised that (entdel) only works for Modelspace and the most recently active Layout. Changing the code to use ActiveX's Delete method will solve this and work for all Layouts.

Code: [Select]

(mapcar '(lambda (x)
                (vla-delete
                  (vlax-ename->vla-object x)
                 )
                )
   (mapcar 'cadr (ssnamex ss)))


[ronjonp]

Good to know Jeff. Thanks.

Ron

[CAB]

ditto
Thanks Jeff

[Joe Burke]

I wonder if anyone else thinks a program which tries to delete a block from a drawing should offer an option? Either expode all the references, including nested, and then delete the definition. Or simply delete the references and pugre the block definition.

I wrote something recently which deals with that question. I definitely felt a need to offer that option.

[ELOQUINTET]

basically i have updated our titleblock and need to go into our library and delete the old one and purge it out because when i insert the new one it is being overriden. ron i tried yours and it works great but i have a few more questions. how can i modify this so it looks for several blocks or should i repeat it in my script looking for a different eblock name? also another thing i didn't think about is that some but not all of our files are read only. i'm wondering how i can find which files are then make my changes then reset them to read only afterwards. anyone know how to do this via script?

[ronjonp]

basically i have updated our titleblock and need to go into our library and delete the old one and purge it out because when i insert the new one it is being overriden. ron i tried yours and it works great but i have a few more questions. how can i modify this so it looks for several blocks or should i repeat it in my script looking for a different eblock name? also another thing i didn't think about is that some but not all of our files are read only. i'm wondering how i can find which files are then make my changes then reset them to read only afterwards. anyone know how to do this via script?

Per Jeff M...you should use this variant:

Code: [Select]

(defun eblock (bname / ss)
  (if (setq ss (ssget "_X" (list (cons 2 bname))))
    (progn
      (mapcar '(lambda (x)
(vla-delete
   (vlax-ename->vla-object x)
)
       )
      (mapcar 'cadr (ssnamex ss))
      )
      (vla-purgeall
(vla-get-activedocument (vlax-get-acad-object))
      )
    )
  )
)
(eblock)
As far as filtering for different block names:

(eblock "blocknm1,blocknm2")

Ron

[ELOQUINTET]

thanks ron and jeff i will give this a try when i have a moment