Topic: Help Needed with Grey Out.

[MvdP]

I need some help with this piece of code.And this is what i am trying to achieve.
I want the AL_lagen button greyed out when i select 1:1000 or 1:2000  in my list_schaal popup_list.
But it ain't working what am i doing wrong here. I am getting a to many arguments error.

DCL Code

Code: [Select]

:popup_list { key = "list_schaal"; allow_accept = true; width = 13 ; fixed_width = true; height=14;}
:radio_button { label = "Alle Lagen"     ; mnemonic = "A"; key = "Al_lagen"; width = 8;}
LSP Code

Code: [Select]


 (start_list "list_schaal")
  (setq displistschaal
(list
   "   1:1                    00"
   "   1:2                    01"
   "   1:5                    02"
   "   1:10                   03"
   "   1:20                   04"
   "   1:50                   05"
   "   1:100                  06"
   "   1:200                  07"
   "   1:500                  08"
   "   1:1000                 09"
   "   1:2000                 10"
   "   1:5000                 11"
   "   1:10000                12"
  )
  )
  (mapcar 'add_list displistschaal)
  (end_list)

(action_tile "Al_lagen"     "(progn (setq Milagen 1)(setq Stlagen 1)(setq Allagen 1))"  )
(action_tile "list_schaal" "(setq schaalecht (nth (atoi $value) displistschaal))(schaalid)"
"(if
(or
(= (atoi $value) (vl-position \"   1:500                  08\" list_schaal))
(= (atoi $value) (vl-position \"   1:1000                 09\" list_schaal))
(= (atoi $value) (vl-position \"   1:2000                 10\" list_schaal))
(= (atoi $value) (vl-position \"   1:5000                 11\" list_schaal))
(= (atoi $value) (vl-position \"   1:10000                12\" list_schaal))
)
(mode_tile \"Al_lagen\" 1) (mode_tile \"Al_lagen\" 0)
)"
)





[Kerry]

Can you provide a "working" version of the code and DCL. ?  That may make problem solving a little more attractive proposition.

The first thing I would do is write all the code you have in the action_tiles into callable routines.

I am getting a to many arguments error.

Have you tried to trace the error in the VLIDE ?

[MvdP]

I can provide a working dcl and lsp but most of it is in Dutch.And the only thing i added in my code it this piece.

Code: [Select]

"(if
(or
(= (atoi $value) (vl-position \"   1:500                  08\" list_schaal))
(= (atoi $value) (vl-position \"   1:1000                 09\" list_schaal))
(= (atoi $value) (vl-position \"   1:2000                 10\" list_schaal))
(= (atoi $value) (vl-position \"   1:5000                 11\" list_schaal))
(= (atoi $value) (vl-position \"   1:10000                12\" list_schaal))
)
(mode_tile \"Al_lagen\" 1) (mode_tile \"Al_lagen\" 0)
)"

After adding this in my working code i am getting the to manny arguments error as mentioned before.

And what do you mean with this 

write all the code you have in the action_tiles into callable routines" .?

And no i did not tried the Trace in visual lisp.becasuse i don't know how this works.!!!

[Kerry]

Please post your code, I'll have a look

[Kerry]

And you MUST learn to debug from the VLisp Editor ... it will teach you a lot about coding.


The help file has all the information you need to get started.

[Kerry]

Try this perhaps < PROGN added > ..

Code: [Select]

(ACTION_TILE
  "list_schaal"
  (PROGN
    "(setq schaalecht (nth (atoi $value) displistschaal))(schaalid)"
    "(if
(or
(= (atoi $value) (vl-position \"   1:500                  08\" list_schaal))
(= (atoi $value) (vl-position \"   1:1000                 09\" list_schaal))
(= (atoi $value) (vl-position \"   1:2000                 10\" list_schaal))
(= (atoi $value) (vl-position \"   1:5000                 11\" list_schaal))
(= (atoi $value) (vl-position \"   1:10000                12\" list_schaal))
)
(mode_tile \"Al_lagen\" 1) (mode_tile \"Al_lagen\" 0)
)")
)

BUT it looks like the or statement is faulty ...

[MvdP]

Kerry here is the code.
(Not all the files that are needed with this code are attached.)

[MvdP]

Kerry i added your code and the to manny arguments error is gone but the button is not grey-ed out and the variables in this line

Code: [Select]

"(setq schaalecht (nth (atoi $value) displistschaal))(schaalid)"are not set.
And i sure will take a look in the help file about debugging.

[Kerry]

Marcel, Try this for an idea ..

Code: [Select]

opzet_1 :dialog {

label = "Test for MvdP";

:popup_list {
key = "list_schaal";
allow_accept = true;
width = 30 ;
fixed_width = true;
height=14;
}
:radio_button {
label = "Alle Lagen"     ;
mnemonic = "A";
key = "Al_lagen";
width = 8;
}
ok_cancel_help;
}

Code: [Select]

(DEFUN c:opzet_1 (/)
  ;;
  ;;
  (DEFUN list_schaal_action (v)   
    (IF (MEMBER v '("9" "10"))
      (MODE_TILE "Al_lagen" 1)
      (MODE_TILE "Al_lagen" 0)
    )
  )
  ;;
  ;;
  (SETQ dcl_id (LOAD_DIALOG "opzet_1.dcl"))
  (IF (NOT (NEW_DIALOG "opzet_1" dcl_id))
    (EXIT)
  )
  (START_LIST "list_schaal")
  (SETQ displistschaal (LIST
                         "   1:1"
                         "   1:2"
                         "   1:5"
                         "   1:10"
                         "   1:20"
                         "   1:50"
                         "   1:100"
                         "   1:200"
                         "   1:500"
                         "   1:1000"
                         "   1:2000"
                         "   1:5000"
                         "   1:10000"
                        )
  )
  (MAPCAR 'ADD_LIST displistschaal)
  (END_LIST)
  ;;
  ;;
  (ACTION_TILE "list_schaal" "( list_schaal_action $value )")
  (SETQ what_next (START_DIALOG))
)

[Kerry]

I've left the variables open for testing.

If you don't understand what I've done with the code changes, just ask .

the
(DEFUN list_schaal_action (v)
is what I meant by 'move code you have in the action_tiles into callable routines '

[MvdP]

Thanks Kerry i added list_schaal_action to my code and it is working great .
Thank you very much for your trime.

[Kerry]

My pleasure.

[sinc]

And you MUST learn to debug from the VLisp Editor ... it will teach you a lot about coding.

Most definitely.  A debugger is a programmer's best friend.