Topic: Challenge - Real number precision?

[CAB]

If you get user input for a real number, how would you determine the precision of the number entered?
Examples of  user enters:
0.007   
1.05
.1

[sinc]

If you get user input for a real number, how would you determine the precision of the number entered?
Examples of  user enters:
0.007   
1.05
.1

How about the precision of:

10
579000
579000.0

Are those included in the challenge?   _{(not that I'll have time to work on it..)}

[CAB]

Sure, and I wish you had the time.

[Derwin]

my solution:

Code: [Select]

; ----------------------------------------------------------------------------
; memeeng 031106 returns precision of given number
;
(defun whatprec ( VAL )
  (if (= 0 (- VAL (fix VAL)))
    0
    (progn
      (setq SVAL (rtos VAL 2))
      (setq SVAL (substr SVAL (+ 2(vl-string-search "." SVAL))))
      ;strip off RH '0'
      (while (= "0" (substr SVAL (strlen SVAL) 1))
(setq SVAL (substr SVAL 1 (1-(strlen SVAL)) )) )
      (strlen SVAL)
    );endPROGN
  );endIF
)


[Derwin]

hmm, one thing:

the result will only go as high as "LUPREC" will allow, ACAD2004=8 places.
  ie: (setvar "LUPREC"

maybe for deeper precision a set of comparrisons with .000000001, .0000000001 etc would work better..

[MP]

In my opinion you will not be able to determine the input precision of values obtained via getreal.

For example, what is the precision of the following input values --

1.0
1.00
1.000
...
?

If I understood your original post the precisions would be 1, 2 and 3 respectively, but you'd not be able to discern that from the value getreal would return, which would be 1.0.

If you opt for a customized input routine that exploits getstring or grread you'll be able to determine how many characters are input after the decimal point, otherwise I think you're hooped.

On the other hand if you are simply trying to determine how many non zero values exist after the decimal point that's easy, though one has to be mindful of the limits of <computer> numerical precision.

<busy week/miss this place!>

[CAB]

Give that man a cigar! Figuratively speaking.

Yes, I agree. My soultion involved getstring.

[Keith™]

Here is my solution ... take it for what it is ... no error checking ...

argument is a string

I looked at doing a test on real numbers, but the problems encountered required more programming than it was worth and only worked when the user was actually typing in the number and not passing it as an argument.

I have another unique solution that I will post later

Code: [Select]

(defun prec (val / fnd ndx repval)
  (setq ndx 0
repval (strlen val))
  (repeat repval
    (setq ndx (1+ ndx))
    (if (= (substr val ndx 1) ".")
      (setq val (substr val (1+ ndx) (strlen val))
    ndx 0 fnd T)
    )
  )
  (if fnd ndx 0)
)


[CAB]

Thanks Keith, looking forward to it.
And thanks to to Derwin.

Here is mine.

Code: [Select]

(defun prec (str / pos)
  (if (setq pos (vl-string-position 46 str))
    (- (strlen str) pos 1)
    0
  )
)

[Keith™]

I should have known there was a shorter solution .. but for whatever reason, I couldn't see it .. I am not awake yet ...

[Keith™]

Ok .. here is another way ...
much faster and shorter

Code: [Select]

(defun prec (str)
  (1-(strlen (vl-string-left-trim "-1234567890" str)))
)


[CAB]

I should have known there was a shorter solution .. but for whatever reason, I couldn't see it .. I am not awake yet ...

I spend half my life that way & only sleep 6 hour a night.

nice soultion!

[CAB]

This is a excerpt from the routine I am working on.
I just set this up as a test & example to display the results.

Code: [Select]

;;  Get user entry of a number & return the number & the precision of the entry
(defun c:test (/ incstr incvalue getnum)
  (defun getnum (str / num typ)
    (cond ((setq num (distof str 2)) (setq typ 2))
          ((setq num (distof str 1)) (setq typ 1))
          ((setq num (distof str 5)) (setq typ 5))
          ((setq num (distof str 3)) (setq typ 3))
          ((setq num (distof str 4)) (setq typ 4))
          ((setq num (read str))
           ;;  (setq typ 6)  return nil for this type
          )
    )
    (if typ (list num typ))
  )

  ;;  get user input of a number
  (while
    (progn
      (setq incstr
             (vl-string-trim " \t\n" (getstring t "\nEnter a real number: ")))
      (cond
        ((= incstr "")
         (prompt "\n***  User quit.  ***")
         nil ; exit loop
        )
        ((not (setq incvalue (car (getnum incstr))))
         (prompt "\n***  Not a valid number, try again.  ***")
         t ; stay in loop
        )
        ;;  get precision of entry  10.005 = 3  [thanks Keith]
        ((setq prec (1- (strlen (vl-string-left-trim "+-1234567890" incstr))))
         nil
        )
      ) ; end cond stmt
    )
  )  ; end while

  (and incvalue
       (print (rtos incvalue 2 prec))
       (print prec)
  )
  (princ)
)

[MP]

Here's a quick bash to add to your things to play with Alan --

Code: [Select]

(defun _GetNumber ( msg )
    (   (lambda ( input / result fixed )
            (vl-some
               '(lambda ( base ) (setq result (distof input base)))
               '(2 1 5 3 4)
            )
            (if result
                (if (vl-string-position 46 input)
                    result ;; assume result is a real
                    (if (eq result (setq fixed (fix result)))
                        fixed  ;; assume result is an integer
                        result ;; assume result is a real
                    )
                )
            )
        )
        (getstring (if (eq 'str (type msg)) msg))
    )
)
If you don't care for the lambda thing --

Code: [Select]

(defun _GetNumber ( msg / input result fixed )

    (setq input (getstring (if (eq 'str (type msg)) msg)))

    (vl-some
       '(lambda ( base ) (setq result (distof input base)))
       '(2 1 5 3 4)
    )

    (if result
        (if (vl-string-position 46 input)
            result ;; assume result is a real
            (if (eq result (setq fixed (fix result)))
                fixed  ;; assume result is an integer
                result ;; assume result is a real
            )
        )
    )
)

[CAB]

Oh, more play toys!

Thanks

[pmvliet]

You guys are amazing!!

Throw out an idea and get a few answers...
Each answer then seems to involve less and less code.

Just shows me that less is more in a lot of ways!

I need to start learning more of this stuff!!

Thanks for the insight

Pieter