« previous next »
Pages: [1] 2  All |   Go Down

Author Topic: Data replacement  (Read 5911 times)

0 Members and 1 Guest are viewing this topic.

myloveflyer

  • Newt
  • Posts: 152
Data replacement
« on: December 03, 2011, 03:50:27 AM »
According to sj.dat data to replace sjold.dat which specify the location of the data, and then generate a new sjx.dat, please help，Thanks!
Logged
Never give up !

myloveflyer

  • Newt
  • Posts: 152
Re: Data replacement
« Reply #1 on: December 03, 2011, 04:12:39 AM »
sj.dat
8 -8.25; 12 -3.18; 151 -1.84

sjold.dat
     0.00     0.00     0.00     0.00     0.00     0.00     0.00     0.00     0.00     0.00
     0.00     0.00     0.00     0.00     0.00     0.00     0.00     0.00     0.00     0.00
     0.00     0.00     0.00     0.00     0.00     0.00     0.00     0.00     0.00     0.00
     0.00     0.00     0.00     0.00     0.00     0.00     0.00     0.00     0.00     0.00
     0.00     0.00     0.00     0.00     0.00     0.00     0.00     0.00     0.00     0.00
     0.00     0.00     0.00     0.00     0.00     0.00     0.00     0.00     0.00     0.00
     0.00     0.00     0.00     0.00     0.00     0.00     0.00     0.00     0.00     0.00
     0.00     0.00     0.00     0.00     0.00     0.00     0.00     0.00     0.00     0.00
     0.00     0.00     0.00     0.00     0.00     0.00     0.00     0.00     0.00     0.00
     0.00     0.00     0.00     0.00     0.00     0.00     0.00     0.00     0.00     0.00
     0.00     0.00     0.00     0.00     0.00     0.00     0.00     0.00     0.00     0.00
     0.00     0.00     0.00     0.00     0.00     0.00     0.00     0.00     0.00     0.00
     0.00     0.00     0.00     0.00     0.00     0.00     0.00     0.00     0.00     0.00
     0.00     0.00     0.00     0.00     0.00     0.00     0.00     0.00     0.00     0.00
     0.00     0.00     0.00     0.00     0.00     0.00     0.00     0.00     0.00     0.00
     0.00

According to sj.dat and sjold.dat to generate sjx.dat

     0.00     0.00     0.00     0.00     0.00     0.00     0.00    -8.25     0.00     0.00
     0.00    -3.18     0.00     0.00     0.00     0.00     0.00     0.00     0.00     0.00
     0.00     0.00     0.00     0.00     0.00     0.00     0.00     0.00     0.00     0.00
     0.00     0.00     0.00     0.00     0.00     0.00     0.00     0.00     0.00     0.00
     0.00     0.00     0.00     0.00     0.00     0.00     0.00     0.00     0.00     0.00
     0.00     0.00     0.00     0.00     0.00     0.00     0.00     0.00     0.00     0.00
     0.00     0.00     0.00     0.00     0.00     0.00     0.00     0.00     0.00     0.00
     0.00     0.00     0.00     0.00     0.00     0.00     0.00     0.00     0.00     0.00
     0.00     0.00     0.00     0.00     0.00     0.00     0.00     0.00     0.00     0.00
     0.00     0.00     0.00     0.00     0.00     0.00     0.00     0.00     0.00     0.00
     0.00     0.00     0.00     0.00     0.00     0.00     0.00     0.00     0.00     0.00
     0.00     0.00     0.00     0.00     0.00     0.00     0.00     0.00     0.00     0.00
     0.00     0.00     0.00     0.00     0.00     0.00     0.00     0.00     0.00     0.00
     0.00     0.00     0.00     0.00     0.00     0.00     0.00     0.00     0.00     0.00
     0.00     0.00     0.00     0.00     0.00     0.00     0.00     0.00     0.00     0.00
    -1.84
Logged
Never give up !

mkweaver

  • Bull Frog
  • Posts: 352
Re: Data replacement
« Reply #2 on: December 03, 2011, 08:28:42 AM »
Logged

ribarm

  • Gator
  • Posts: 3285
  • Marko Ribar, architect
Re: Data replacement
« Reply #3 on: December 03, 2011, 01:37:04 PM »
Here is my attempt... Just don't know how to remove last zero from real negative numbers, so I shortened spaces by one place...

Code: [Select]
(defun c:sjupdate ( / ASSPOS ASSPOSS ASSVAL K M N SJD SJDAT SJDL SJDL1 SJDL1ASSOC SJDL1POS SJDL1VAL SJDLASSLST SJDLN SJNEWD SJNEWDAT SJNEWDL SJOLDD SJOLDDAT SJOLDDL SJOLDDE X )
(setq sjdat (getfiled "Select sj.dat file" "" "dat" 16))
(setq sjd (open sjdat "r"))
(setq sjdl (read-line sjd))
(setq sjdln (strlen sjdl))
(while (< (if (/= (vl-string-position (ascii ";") sjdl) nil) (vl-string-position (ascii ";") sjdl) 0) sjdln)
  (setq sjdl1 (substr sjdl 1 (vl-string-position (ascii ";") sjdl)))
  (setq sjdl (vl-string-left-trim sjdl1 sjdl))
  (if (= (vl-string-position (ascii ";") sjdl) 0) (setq sjdl (vl-string-left-trim "; " sjdl)) )
  (setq sjdln (strlen sjdl))
  (setq sjdl1pos (read sjdl1))
  (setq sjdl1val (if sjdl1pos (read (vl-string-left-trim (itoa sjdl1pos) sjdl1))))
  (setq sjdl1assoc (if sjdl1pos (cons sjdl1pos sjdl1val)))
  (setq sjdlasslst (if sjdl1pos (cons sjdl1assoc sjdlasslst)))
)
(setq sjdlasslst (reverse sjdlasslst))
(close sjd)
(setq sjolddat (getfiled "Select sjold.dat file" "" "dat" 16))
(setq sjoldd (open sjolddat "r"))
(setq sjnewdat (getfiled "Select sjnew.dat file to save data into" "" "dat" 1))
(setq sjnewd (open sjnewdat "w"))
(setq n 0)
(while (read-line sjoldd)
  (setq n (1+ n))
)
(close sjoldd)
(setq sjoldd (open sjolddat "r"))
(setq m -1)
(repeat n
  (setq m (1+ m))
  (setq sjolddl (read-line sjoldd))
  (mapcar '(lambda (x) (if (and (< (* m 10) (car x)) (<= (car x) (* (+ m 1) 10))) (setq assposs (cons (car x) assposs)))) sjdlasslst)
  (setq assposs (reverse assposs))
  (setq k -1)
  (repeat (length assposs)
    (setq assval (cdr (assoc (setq asspos (nth (setq k (1+ k)) assposs)) sjdlasslst)))
    (setq assval (strcat "  " (rtos assval 2 2)))
    (if (= k 0) (setq sjnewdl ""))
    (setq sjnewdl (strcat sjnewdl (substr sjolddl (+ (strlen sjnewdl) 1) (- (+ (* (- (- asspos (* 10 m)) 1) 9) 1) (strlen sjnewdl)))))
    (setq sjnewdl (strcat sjnewdl assval))
  )
  (if asspos (setq sjoldde (substr sjolddl (* (- asspos (* 10 m)) 9) (strlen sjolddl))))
  (if (and sjnewdl sjoldde) (setq sjnewdl (strcat sjnewdl sjoldde)))
  (if (/= (length assposs) 0) (write-line sjnewdl sjnewd) (write-line sjolddl sjnewd))
  (setq asspos nil)
  (setq sjoldde nil)
  (setq sjnewdl nil)
  (setq sjolddl nil)
  (setq assposs nil)
)
(close sjnewd)
(close sjoldd)
(princ)
)

Hope this helps, M.R.
:)

Code was updated to accept more inputs in a row...
« Last Edit: December 03, 2011, 04:42:31 PM by ribarm »
Logged
Marko Ribar, d.i.a. (graduated engineer of architecture)

:)

M.R. on Youtube

myloveflyer

  • Newt
  • Posts: 152
Re: Data replacement
« Reply #4 on: December 04, 2011, 02:09:35 AM »
Ribarm

Thank you.

Program treats negative can run normally, and the data in a row.

But I want to deal with much data, and had positive and negative, there is data in multiple rows, can modify the number of rows and data, and no limit.

For example ( this is only an example, actual data to many ):


sj.dat
1 -10;8 -8.25; 12 -3.18; 30 -1.97; 151 -1.84
11 -10;81 8.25; 121 3.18; 35 -1.97
28 15; 101 -78
Logged
Never give up !

ribarm

  • Gator
  • Posts: 3285
  • Marko Ribar, architect
Re: Data replacement
« Reply #5 on: December 04, 2011, 03:46:45 AM »
Here is my latest one :

Code: [Select]
(defun c:sjupdate ( / ASSPOS ASSPOSS ASSVAL K M N SJD SJDAT SJDL SJDL1 SJDL1ASSOC SJDL1POS SJDL1VAL SJDLASSLST SJDLN SJNEWD SJNEWDAT SJNEWDL SJOLDD SJOLDDAT SJOLDDL SJOLDDE X )
(setq sjdat (getfiled "Select sj.dat file" "" "dat" 16))
(setq sjd (open sjdat "r"))
(setq n 0)
(while (read-line sjd)
  (setq n (1+ n))
)
(close sjd)
(setq sjd (open sjdat "r"))
(repeat n
  (setq sjdl (read-line sjd))
  (setq sjdln (strlen sjdl))
  (while (< (if (/= (vl-string-position (ascii ";") sjdl) nil) (vl-string-position (ascii ";") sjdl) 0) sjdln)
    (setq sjdl1 (substr sjdl 1 (vl-string-position (ascii ";") sjdl)))
    (setq sjdl (vl-string-left-trim sjdl1 sjdl))
    (if (= (vl-string-position (ascii ";") sjdl) 0) (setq sjdl (vl-string-left-trim "; " sjdl)) )
    (setq sjdln (strlen sjdl))
    (setq sjdl1pos (read sjdl1))
    (setq sjdl1val (if sjdl1pos (read (vl-string-left-trim (itoa sjdl1pos) sjdl1))))
    (setq sjdl1assoc (if sjdl1pos (cons sjdl1pos sjdl1val)))
    (setq sjdlasslst (if sjdl1pos (cons sjdl1assoc sjdlasslst)))
  )
)
(setq sjdlasslst (reverse sjdlasslst))
(setq sjdlasslst (vl-sort sjdlasslst '(lambda (a b) (< (car a) (car b))) ))
(close sjd)
(setq sjolddat (getfiled "Select sjold.dat file" "" "dat" 16))
(setq sjoldd (open sjolddat "r"))
(setq sjnewdat (getfiled "Select sjnew.dat file to save data into" "" "dat" 1))
(setq sjnewd (open sjnewdat "w"))
(setq n 0)
(while (read-line sjoldd)
  (setq n (1+ n))
)
(close sjoldd)
(setq sjoldd (open sjolddat "r"))
(setq m -1)
(repeat n
  (setq m (1+ m))
  (setq sjolddl (read-line sjoldd))
  (mapcar '(lambda (x) (if (and (< (* m 10) (car x)) (<= (car x) (* (+ m 1) 10))) (setq assposs (cons (car x) assposs)))) sjdlasslst)
  (setq assposs (reverse assposs))
  (setq k -1)
  (repeat (length assposs)
    (setq assval (cdr (assoc (setq asspos (nth (setq k (1+ k)) assposs)) sjdlasslst)))
    (setq assval (strcat "   " (rtos assval 2 2)))
    (if (= k 0) (setq sjnewdl ""))
    (setq sjnewdl (strcat sjnewdl (substr sjolddl (+ (strlen sjnewdl) 1) (- (+ (* (- (- asspos (* 10 m)) 1) 9) 1) (strlen sjnewdl)))))
    (setq sjnewdl (strcat sjnewdl assval))
  )
  (if asspos (setq sjoldde (substr sjolddl (+ (* (- asspos (* 10 m)) 9) 1) (strlen sjolddl))))
  (if (and sjnewdl sjoldde) (setq sjnewdl (strcat sjnewdl sjoldde)))
  (if (/= (length assposs) 0) (write-line sjnewdl sjnewd) (write-line sjolddl sjnewd))
  (setq asspos nil)
  (setq sjoldde nil)
  (setq sjnewdl nil)
  (setq sjolddl nil)
  (setq assposs nil)
)
(close sjnewd)
(close sjoldd)
(princ)
)

I used sj.dat :
15 -3.16; 4 -5.25; 8 -8.25; 12 -3.18; 151 -1.84
25 -4.32; 32 -9.13
43 -5.42; 38 10.18

And get this :
     0.00     0.00     0.00    -5.25     0.00     0.00     0.00    -8.25     0.00     0.00
     0.00    -3.18     0.00     0.00    -3.16     0.00     0.00     0.00     0.00     0.00
     0.00     0.00     0.00     0.00    -4.32     0.00     0.00     0.00     0.00     0.00
     0.00    -9.13     0.00     0.00     0.00     0.00     0.00    10.18     0.00     0.00
     0.00     0.00    -5.42     0.00     0.00     0.00     0.00     0.00     0.00     0.00
     0.00     0.00     0.00     0.00     0.00     0.00     0.00     0.00     0.00     0.00
     0.00     0.00     0.00     0.00     0.00     0.00     0.00     0.00     0.00     0.00
     0.00     0.00     0.00     0.00     0.00     0.00     0.00     0.00     0.00     0.00
     0.00     0.00     0.00     0.00     0.00     0.00     0.00     0.00     0.00     0.00
     0.00     0.00     0.00     0.00     0.00     0.00     0.00     0.00     0.00     0.00
     0.00     0.00     0.00     0.00     0.00     0.00     0.00     0.00     0.00     0.00
     0.00     0.00     0.00     0.00     0.00     0.00     0.00     0.00     0.00     0.00
     0.00     0.00     0.00     0.00     0.00     0.00     0.00     0.00     0.00     0.00
     0.00     0.00     0.00     0.00     0.00     0.00     0.00     0.00     0.00     0.00
     0.00     0.00     0.00     0.00     0.00     0.00     0.00     0.00     0.00     0.00
    -1.84

I've removed trailing zeros and made number positions like you showed in your first post. So 10.25 is possible, also 10.00, but not -10.25 and not -10.00; possible is -9.25 and 9.25 will be shown as 9.25 and that will reorder remaining 0.00 so this isn't advice (note that for numbers you have 4 digits not counting delimiter (.) and it is your how will you arrange them)...
(note also that in your sj.dat :
sj.dat
1 -10;8 -8.25; 12 -3.18; 30 -1.97; 151 -1.84
11 -10;81 8.25; 121 3.18; 35 -1.97
28 15; 101 -78

you should have one space after ; so it should be :
sj.dat
1 -10; 8 -8.25; 12 -3.18; 30 -1.97; 151 -1.84
11 -10; 81 8.25; 121 3.18; 35 -1.97
28 15; 101 -78
)

Sincerely, M.R.
:)
« Last Edit: December 04, 2011, 04:48:09 AM by ribarm »
Logged
Marko Ribar, d.i.a. (graduated engineer of architecture)

:)

M.R. on Youtube

myloveflyer

  • Newt
  • Posts: 152
Re: Data replacement
« Reply #6 on: December 04, 2011, 05:30:32 AM »
ribarm
Thanks!COOL!
Has been basically can achieve the purpose, I'll revise, because of the need to deal with such data, our first test, if there do not understand to ask you.

Logged
Never give up !

ribarm

  • Gator
  • Posts: 3285
  • Marko Ribar, architect
Re: Data replacement
« Reply #7 on: December 04, 2011, 05:48:51 AM »
Here is my final version... Now it doesn't matter how big number is, or is it negative or not... Only thing that matters is that you separate number associations with ; and one space character behind it...

Code - Auto/Visual Lisp: [Select]
  1. (defun c:sjupdate ( / ASSPOS ASSPOSS ASSVAL K M N SJD SJDAT SJDL SJDL1 SJDL1ASSOC SJDL1POS SJDL1VAL SJDLASSLST SJDLN SJNEWD SJNEWDAT SJNEWDL SJOLDD SJOLDDAT SJOLDDL SJOLDDE X )
  2. (setq sjdat (getfiled "Select sj.dat file" "" "dat" 16))
  3. (setq sjd (open sjdat "r"))
  4. (setq n 0)
  6.   (setq n (1+ n))
  7. )
  8. (close sjd)
  9. (setq sjd (open sjdat "r"))
  11.   (setq sjdl (read-line sjd))
  12.   (setq sjdln (strlen sjdl))
  13.   (while (< (if (/= (vl-string-position (ascii ";") sjdl) nil) (vl-string-position (ascii ";") sjdl) 0) sjdln)
  14.     (setq sjdl1 (substr sjdl 1 (vl-string-position (ascii ";") sjdl)))
  15.     (setq sjdl (vl-string-left-trim sjdl1 sjdl))
  16.     (if (= (vl-string-position (ascii ";") sjdl) 0) (setq sjdl (vl-string-left-trim "; " sjdl)) )
  17.     (setq sjdln (strlen sjdl))
  18.     (setq sjdl1pos (read sjdl1))
  19.     (setq sjdl1val (if sjdl1pos (read (vl-string-left-trim (itoa sjdl1pos) sjdl1))))
  20.     (setq sjdl1assoc (if sjdl1pos (cons sjdl1pos sjdl1val)))
  21.     (setq sjdlasslst (if sjdl1pos (cons sjdl1assoc sjdlasslst)))
  22.   )
  23. )
  24. (setq sjdlasslst (reverse sjdlasslst))
  25. (setq sjdlasslst (vl-sort sjdlasslst '(lambda (a b) (< (car a) (car b))) ))
  26. (close sjd)
  27. (setq sjolddat (getfiled "Select sjold.dat file" "" "dat" 16))
  28. (setq sjoldd (open sjolddat "r"))
  29. (setq sjnewdat (getfiled "Select sjnew.dat file to save data into" "" "dat" 1))
  30. (setq sjnewd (open sjnewdat "w"))
  31. (setq n 0)
  32. (while (read-line sjoldd)
  33.   (setq n (1+ n))
  34. )
  35. (close sjoldd)
  36. (setq sjoldd (open sjolddat "r"))
  37. (setq m -1)
  39.   (setq m (1+ m))
  40.   (setq sjolddl (read-line sjoldd))
  41.   (mapcar '(lambda (x) (if (and (< (* m 10) (car x)) (<= (car x) (* (+ m 1) 10))) (setq assposs (cons (car x) assposs)))) sjdlasslst)
  42.   (setq assposs (reverse assposs))
  43.   (setq k -1)
  44.   (repeat (length assposs)
  45.     (setq assval (cdr (assoc (setq asspos (nth (setq k (1+ k)) assposs)) sjdlasslst)))
  46.     (setq assval
  47.     (cond ((= (strlen (rtos assval 2 2)) 4) (strcat "    " (rtos assval 2 2)))
  48.           ((= (strlen (rtos assval 2 2)) 5) (strcat "   " (rtos assval 2 2)))
  49.           ((= (strlen (rtos assval 2 2)) 6) (strcat "  " (rtos assval 2 2)))
  50.           ((= (strlen (rtos assval 2 2)) 7) (strcat " " (rtos assval 2 2)))
  51.     )
  52.     )
  53.     (if (= k 0) (setq sjnewdl ""))
  54.     (setq sjnewdl (strcat sjnewdl (substr sjolddl (+ (strlen sjnewdl) 1) (- (+ (* (- (- asspos (* 10 m)) 1) 9) 1) (strlen sjnewdl)))))
  55.     (setq sjnewdl (strcat sjnewdl assval))
  56.   )
  57.   (if asspos (setq sjoldde (substr sjolddl (+ (* (- asspos (* 10 m)) 9) 1) (strlen sjolddl))))
  58.   (if (and sjnewdl sjoldde) (setq sjnewdl (strcat sjnewdl sjoldde)))
  59.   (if (/= (length assposs) 0) (write-line sjnewdl sjnewd) (write-line sjolddl sjnewd))
  60.   (setq asspos nil)
  61.   (setq sjoldde nil)
  62.   (setq sjnewdl nil)
  63.   (setq sjolddl nil)
  64.   (setq assposs nil)
  65. )
  66. (close sjnewd)
  67. (close sjoldd)
  69. )
  70.  

M.R.
« Last Edit: December 09, 2011, 08:31:20 AM by ribarm »
Logged
Marko Ribar, d.i.a. (graduated engineer of architecture)

:)

M.R. on Youtube

Lee Mac

  • Seagull
  • Posts: 12916
  • London, England
Re: Data replacement
« Reply #8 on: December 04, 2011, 12:51:59 PM »
Here is my version:

Code - Auto/Visual Lisp: [Select]
  1. (defun c:test ( / i line lst1 lst2 rf1 rf2 rfile1 rfile2 str wf1 wfile1 )
  2.  
  3.     (setq rfile1 "sj.dat"
  4.           rfile2 "sjold.dat"
  5.           wfile1 "sjx.dat"
  6.     )
  7.  
  8.     (defun _StringParser ( string delim / pos )
  9.         (if (setq pos (vl-string-search delim string))
  10.             (vl-remove ""
  11.                 (cons
  12.                     (substr string 1 pos)
  13.                     (_StringParser (substr string (+ pos 1 (strlen delim))) delim)
  14.                 )
  15.             )
  16.             (list string)
  17.         )
  18.     )
  19.  
  20.     (defun _ParseFile ( file delim / data line )
  21.         (cond
  22.             (   (setq file (open file "r"))
  23.                 (while (setq line (read-line file))
  24.                     (setq data (cons (_StringParser line delim) data))
  25.                 )
  26.                 (close file)
  27.                 (reverse data)
  28.             )
  29.         )
  30.     )
  31.  
  32.     (defun _PadLeft ( string char len )
  33.         (if (< (strlen string) len)
  34.             (_PadLeft (strcat char string) char len)
  35.             string
  36.         )
  37.     )
  38.  
  39.     (cond
  40.         (   (null
  41.                 (and
  42.                     (setq rf1 (findfile rfile1))
  43.                     (setq rf2 (findfile rfile2))
  44.                 )
  45.             )
  46.             (princ (strcat "\n" rfile1 " or " rfile2 " could not be found."))
  47.         )
  48.         (   (null
  49.                 (and
  50.                     (setq lst1
  51.                         (vl-sort
  52.                             (apply 'append
  53.                                 (mapcar
  54.                                     (function
  55.                                         (lambda ( a )
  56.                                             (mapcar
  57.                                                 (function
  58.                                                     (lambda ( b )
  59.                                                         (setq b (_StringParser b " "))
  60.                                                         (list (atoi (car b)) (cadr b))
  61.                                                     )                                                
  62.                                                 )
  63.                                                 a
  64.                                             )
  65.                                         )
  66.                                     )
  67.                                     (_ParseFile rf1 ";")
  68.                                 )
  69.                             )
  70.                            '(lambda ( a b ) (< (car a) (car b)))
  71.                         )
  72.                     )
  73.                     (setq lst2 (_ParseFile rf2 "     "))
  74.                 )
  75.             )
  76.             (princ (strcat "\nEither " rfile1 " or " rfile2 " is empty."))
  77.         )
  78.         (   (null (setq wf1 (open (setq wfile1 (strcat (vl-filename-directory rf1) "\\" wfile1)) "w")))
  79.             (princ (strcat "\nUnable to open " wfile1 " for writing."))
  80.         )
  81.         (   t
  82.             (setq i 0)
  83.             (while (setq line (car lst2))
  84.                 (setq str "")
  85.                 (foreach item line
  86.                     (if (and lst1 (= (setq i (1+ i)) (caar lst1)))
  87.                         (setq str  (strcat str (_PadLeft (cadar lst1) " " 9))
  88.                               lst1 (cdr lst1)
  89.                         )
  90.                         (setq str (strcat str (_PadLeft item " " 9)))
  91.                     )
  92.                 )
  93.                 (write-line str wf1)
  94.                 (setq lst2 (cdr lst2))
  95.             )            
  96.             (close wf1)
  97.             (startapp "notepad" wfile1)
  98.         )
  99.     )
  100.     (princ)
  101. )
Logged

alanjt

  • Needs a day job
  • Posts: 5352
  • Standby for witty remark...
Re: Data replacement
« Reply #9 on: December 04, 2011, 12:59:45 PM »
Quote from: Lee Mac on December 04, 2011, 12:51:59 PM
Here is my version:
Is this the new option for code formatting? :-o Takes up quite a bit of screen space just to display functions and strings in a different color.
Logged
Civil 3D 2019 ~ Windohz 7 64bit
Dropbox

Lee Mac

  • Seagull
  • Posts: 12916
  • London, England
Re: Data replacement
« Reply #10 on: December 04, 2011, 01:13:36 PM »
Quote from: alanjt on December 04, 2011, 12:59:45 PM
Quote from: Lee Mac on December 04, 2011, 12:51:59 PM
Here is my version:
Is this the new option for code formatting? :-o Takes up quite a bit of screen space just to display functions and strings in a different color.

http://www.theswamp.org/index.php?topic=39358.msg455449#msg455449

http://www.theswamp.org/index.php?topic=32153.msg455444#msg455444

I don't understand what you mean about 'screen space' though?
Logged

alanjt

  • Needs a day job
  • Posts: 5352
  • Standby for witty remark...
Re: Data replacement
« Reply #11 on: December 04, 2011, 01:37:25 PM »
Quote from: Lee Mac on December 04, 2011, 01:13:36 PM
Quote from: alanjt on December 04, 2011, 12:59:45 PM
Quote from: Lee Mac on December 04, 2011, 12:51:59 PM
Here is my version:
Is this the new option for code formatting? :-o Takes up quite a bit of screen space just to display functions and strings in a different color.

http://www.theswamp.org/index.php?topic=39358.msg455449#msg455449

http://www.theswamp.org/index.php?topic=32153.msg455444#msg455444

I don't understand what you mean about 'screen space' though?
Yeah, I saw the thread. Seems like a lot of fuss over function highlighting.
I've attached a partial screen shot to for my comment about screen space.
Logged
Civil 3D 2019 ~ Windohz 7 64bit
Dropbox

Lee Mac

  • Seagull
  • Posts: 12916
  • London, England
Re: Data replacement
« Reply #12 on: December 04, 2011, 06:53:26 PM »
Oh from your screenshot, I see what you mean about the space - it only displays up to line 35 for me [using FF8.0 W7], which is similar to the existing code panes so I couldn't see what you were getting at initially.
Logged

myloveflyer

  • Newt
  • Posts: 152
Re: Data replacement
« Reply #13 on: December 04, 2011, 08:20:49 PM »
ribarm
Thanks,you final version is very nice!

LEE
COOL！Processing speed is very fast，But the results of processing, integer bit behind" . 00", but the calculation results have no effect.

Finally, thank you in his busy schedule to help me.

Logged
Never give up !

alanjt

  • Needs a day job
  • Posts: 5352
  • Standby for witty remark...
Re: Data replacement
« Reply #14 on: December 04, 2011, 09:21:55 PM »
Quote from: Lee Mac on December 04, 2011, 06:53:26 PM
Oh from your screenshot, I see what you mean about the space - it only displays up to line 35 for me [using FF8.0 W7], which is similar to the existing code panes so I couldn't see what you were getting at initially.
Odd, I looked at it with FF8.0+Win7. I also upgraded today to 8.0.1 and it still doesn't condense the code. Even 35 lines is a lot.
Logged
Civil 3D 2019 ~ Windohz 7 64bit
Dropbox
Pages: [1] 2  All |   Go Up
« previous next »