Topic: random extrude

[dussla]

hello friend again
i thought   idea  all at once , so i am writing help message  again

 

my idea is  random extrude

there are many closed polyline , i would like to extrude condition below

wanted   routine
1. select  closed polylines ( rectangles   , circle , ... closed polyline....)
2. write wanteded  number for extude height range  (ex :  100~ 1000   )
3. step   ( ex: 50)
4 ,result  :   random extruded polylines heights ( ex: 150 , 200 , 350 , 450   .................950  )1000 )
like image below


there is no random function in lisp ~
dear  friends  , is that possible ?

[Didge]

Here's a pseudo-random snippet that may help.

Code: [Select]

;****************************************************************************************
; RAND  Function to return a random number between 1 and the supplied integer.          *
; ====                                                                                  *
;       (rand 49) will return a pseudo-random number somewhere between 0-49 inclusive.  *
;****************************************************************************************
(defun RAND (fact / modulus multiplier increment random)
  (if (not seed) (setq seed (getvar "DATE")))
  (setq modulus 65536 multiplier 25173 increment 13849
seed (rem (+ (* multiplier seed) increment) modulus)
random (/ seed modulus)
  )
  (fix (* random (1+ fact)))
)

[KewlToyZ]

I think people here need more information from you as well.
Are you looking for choices in specific polygon designations to apply heights on?
Are you looking for some sort of DCL interface to accomplish your goals on the client side?

[dussla]

dear friends ~
i don't need dcl interface
only simple  code ~  that's all  only
 

[DEVITG]

hello friend again
i thought   idea  all at once , so i am writing help message  again

 

my idea is  random extrude

there are many closed polyline , i would like to extrude condition below

wanted   routine
1. select  closed polylines ( rectangles   , circle , ... closed polyline....)
2. write wanteded  number for extude height range  (ex :  100~ 1000   )
3. step   ( ex: 50)
4 ,result  :   random extruded polylines heights ( ex: 150 , 200 , 350 , 450   .................950  )1000 )
like image below
there is no random function in lisp ~
dear  friends  , is that possible ?

Could you upload a sample DWG , the  150 , 200 , 350 , 450   .................950  )1000    will be fixed and used  randomly??

What is the idea , to build a city wit random height buildings??

 

[dussla]

DEVITG  ~ yes   your reply is correct anwser~~
can you see my attatched file ~

[gile]

Hi,

Something like this:

Code: [Select]

(defun rng (/ modulus multiplier increment random)
  (if (not seed)
    (setq seed (getvar "DATE"))
  )
  (setq modulus    4294967296.0
multiplier 1664525
increment  1
seed    (rem (+ (* multiplier seed) increment) modulus)
random    (/ seed modulus)
  )
)

(defun c:random-extrude (/ ss reg)
  (vl-load-com)
  (or *acdoc*
      (setq *acdoc* (vla-get-ActiveDocument (vlax-get-acad-object)))
  )
  (setq sp (vla-get-ModelSpace *acdoc*))
  (if (ssget '((0 . "CIRCLE,LWPOLYLINE")))
    (progn
      (vla-StartUndoMark *acdoc*)
      (vlax-for obj (vla-get-ActiveSelectionSet *acdoc*)
(setq reg (vl-catch-all-apply
    'vlax-invoke
    (list sp 'addRegion(list obj)))
)
(or (vl-catch-all-error-p reg)
    (and
      (vla-addExtrudedSolid
sp
(car reg)
(* 50 (fix (+ 2 (* 18 (rng)))))
0.0
      )
      (vla-delete (car reg))
    )
)
      )
      (vla-EndUndoMark *acdoc*)
    )
  )
  (princ)
)

[DEVITG]

Hi , could you upload the RNG ??

[gile]

Ooopss !!!

I forgoted to join it, the upper code is now updated.

[dussla]

gile , thank you  good code
but 
i need    range  and   step options  for my wanted heights

2. write wanteded  number for extude height range  (ex between  :  100~ 1000   )   ex: ( 3000 ~ 6000) 
3. step   ( ex: 50)  (ex: 100) .....

is that possible ?

[gile]

EDIT corrected the random height calculus

EDIT 2: have to use round instead of fix

Code: [Select]

(defun rng (/ modulus multiplier increment random)
  (if (not seed)
    (setq seed (getvar "DATE"))
  )
  (setq modulus    4294967296.0
multiplier 1664525
increment  1
seed    (rem (+ (* multiplier seed) increment) modulus)
random    (/ seed modulus)
  )
)

(defun round (num prec)
  (* prec
     (fix ((if (minusp num)
     -
     +
   )
    (/ num prec)
    0.5
  )
     )
  )
)

(defun c:random-extrude (/ minht maxht step ss reg)
  (vl-load-com)
  (or *acdoc*
      (setq *acdoc* (vla-get-ActiveDocument (vlax-get-acad-object)))
  )
  (setq sp (vla-get-ModelSpace *acdoc*))
  (initget 7)
  (setq minht (getdist "\nSpecify the minimum height: "))
  (while
    (not
      (and (setq maxht (getdist "\nSpecify the maximum height: "))
   (< minht maxht)
      )
    )
     (princ
       (strcat "\nThe value must be greater than " (rtos minht))
     )
  )
  (while
    (not
      (and (setq step (getdist "\nSpecify the step: "))
   (< step (- maxht minht))
      )
    )
     (princ
       (strcat "\nThe value must be lower than " (rtos minht))
     )
  )
  (if (ssget '((0 . "CIRCLE,LWPOLYLINE")))
    (progn
      (vla-StartUndoMark *acdoc*)
      (vlax-for obj (vla-get-ActiveSelectionSet *acdoc*)
(setq reg (vl-catch-all-apply
    'vlax-invoke
    (list sp 'addRegion(list obj)))
)
(or (vl-catch-all-error-p reg)
    (and
      (vla-addExtrudedSolid
sp
(car reg)
                 (+ minht (* step (round (* (/ (- maxht minht ) step) (rng)) 1)))
0.0
      )
      (vla-delete (car reg))
    )
)
      )
      (vla-EndUndoMark *acdoc*)
    )
  )
  (princ)
)

[dussla]

gile  , you are very very nice man
i think that is some difficult , you done it
always thank you , thank you very much , thank you very much ~

and other firends ~~ thank you  also ~