Topic: Looking for help with this code

[AVCAD]

Code: [Select]

(defun c:xlayer_on (/)
  (vlax-map-collection
    (vla-get-layers
      (vla-get-activedocument (vlax-get-acad-object))
    )
    '(lambda (x)
       (if (or (= (vla-get-color x 9)
       (= (vla-get-color x 8)
   )
(progn
   (vl-catch-all-error-p
     (vl-catch-all-apply 'vla-put-freeze (list x :vlax-false))
   )
   (vla-put-layeron x :vlax-true)
   (vla-put-lock x :vlax-false)
   (vla-put-plottable x :vlax-true)
)
       )
     )
  )
  (princ)
)

All I want it to do is grab the layers that are color 9 and 8 and make sure that they are completely viewable.

its not working and I am not sure why...

I think it has something to do with the

Code: [Select]

(vl-catch-all-apply 'vla-put-freeze (list x :vlax-false))
Thanks in advance for your help.

[CAB]

Maybe this will work for you.

Code - Auto/Visual Lisp: [Select]

1. (defun c:xlayer_on (/ active_layer lname)
2.   (vl-load-com)
3.   (or *doc* (setq *doc* (vla-get-activedocument (vlax-get-acad-object))))
4.   (setq active_layer (vla-get-activelayer *doc*))
5.   (vla-startundomark *doc*)
6.   (vlax-for lname (vla-get-layers *doc*)
7.     (if (and (vl-position (vla-get-color lname) '(8 9))
8.              (not (equal active_layer item)))
9.       (vl-catch-all-apply
10.         '(lambda ()
11.            (vla-put-freeze lname :vlax-false)
12.            (vla-put-layeron lname :vlax-true)
13.            (vla-put-lock lname :vlax-false)
14.            (vla-put-plottable lname :vlax-true)
15.          )
16.       )
17.     )
18.   )
19.   (vla-regen *doc* acactiveviewport)
20.   (princ)
21. )

[Lee Mac]

The issue with the code was in these expressions:

Code: [Select]

(if (or (= (vla-get-color x 9)
           (= (vla-get-color x 8))

The vla-get-* functions will only accept a single argument (the VLA-Object whose property is to be retrieved), and you are also missing some closing parentheses.

In addition to CAB's excellent suggestion, here is another variation:

Code - Auto/Visual Lisp: [Select]

1. (defun c:xlayer_on ( )
2.     (vlax-for x (vla-get-layers (vla-get-activedocument (vlax-get-acad-object)))
3.         (if (< 7 (vla-get-color x) 10)
4.             (progn
5.                 (vl-catch-all-apply 'vla-put-freeze (list x :vlax-false))
6.                 (vla-put-layeron   x :vlax-true)
7.                 (vla-put-lock      x :vlax-false)
8.                 (vla-put-plottable x :vlax-true)
9.             )
10.         )
11.     )
12.     (princ)
13. )
14. (vl-load-com) (princ)

[David Bethel]

Or maybe:

Code - Auto/Visual Lisp: [Select]

1. (defun c:l89 (/ td ll)
2.   (while (setq td (tblnext "LAYER" (not td)))
3.          (if (member (abs (cdr (assoc 62 td))) '(8 9))
4.              (setq ll (cons (cdr (assoc 2 td)) ll))))
5.   (command "_.LAYER")
6.   (foreach l ll
7.     (command "_Unlock" l "_Thaw" l "_On" l))
8.   (command "")
9.   (prin1))
10.  

Q:   In a vl call, does it strip the negative from the color number if the layer is off ?

-David

[Lee Mac]

Q:   In a vl call, does it strip the negative from the color number if the layer is off ?

The color property will always return an integer between 0-256 (0=acbyblock; 256=acbylayer).
The on/off status is determined by the layeron ActiveX property 

[AVCAD]

Thanks, Works perfectly CAB! I can always count on you guy!

[David Bethel]

The color property will always return an integer between 0-256 (0=acbyblock; 256=acbylayer).
The on/off status is determined by the layeron ActiveX property 

I think I'll stick with the TABLEs  -David

[Lee Mac]

I think I'll stick with the TABLEs  -David

In this case, I actually feel that the ActiveX route is more logical, i.e.:

Code: [Select]

(vla-get-color   <Layer-Object>) --> Layer Color
(vla-get-layeron <Layer-Object>) --> true = Layer is ON, false = Layer is OFF
In Vanilla, we have:

Code: [Select]

(cdr (assoc 62 <Layer-DXF-data>)) --> Absolute value = Layer Color; if negative Layer is OFF
I personally don't see the logic of a negative Layer color indicating that the Layer is OFF - these two properties are not related in any way. I would think it more logical to include the Layer ON/OFF property as an additional bit-code in DXF group 70 (along with frozen / locked).

Also, by combining the properties into a single DXF group, it necessitates the use of abs when retrieving the Layer color.

[MP]

I personally don't see the logic of a negative Layer color indicating that the Layer is OFF ...

Not to be combative, but it makes sense to me. Layers that are off do not display, but still hide -- objects are "there", they just don't appear, yet the space they occupy is recognized -- it's crazy -- it's like their color is negative or something.

[Lee Mac]

I personally don't see the logic of a negative Layer color indicating that the Layer is OFF ...

Not to be combative, but it makes sense to me. Layers that are off do not display, but still hide -- objects are "there", they just don't appear, yet the space they occupy is recognized -- it's crazy -- it's like their color is negative or something.

I guess that's one way of making sense of it - an interesting idea MP.
I still think the on/off status should be part of DXF Group 70; though, I'm not expecting it to change