Topic: Mtext Word wrap removal

[Biscuits]

I'm looking for a routine/macro to remove word wrap on existing mtext without all the properties changing in the mtext dialogue box. Looking for a system variable change, lisp or VBA. It can be global or through a single selection. Does anyone have any ideas?
Using ACAD2002 on Windows 2000. Thanks

[Mark]

Not perfect! Might fall down if you have a lot of formatting in your MTEXT.

Code: [Select]




(defun c:blastReturns (/ rm-returns ent entlst str new_str)

  (defun rm-returns (str)
    (while (wcmatch str "*\\P*")
      (setq str (vl-string-subst " " "\\P" str))
    )
    str
  )

  (if (setq ent (car (entsel "\nSelect MTEXT: ")))
    (progn

      (setq entlst  (entget ent)
   str    (cdr (assoc 1 entlst))
   new_str (rm-returns str)
      )

      (setq entlst
    (subst (cons 1 new_str) (assoc 1 entlst) entlst)
      )
      (entmod entlst)
    )
  )

  (princ)
)


[Mark]

Newer version, more error checking.

Code: [Select]


(defun c:blastReturns (/ rm-returns ent entlst str new_str)

  (defun rm-returns (str)
    (while (wcmatch str "*\\P*")
      (setq str (vl-string-subst " " "\\P" str))
    )
    str
  )

  (if (setq ent (car (entsel "\nSelect MTEXT: ")))
    (progn
      (setq entlst (entget ent))
      (if (= (cdr (assoc 0 entlst)) "MTEXT")
(progn
 (setq str (cdr (assoc 1 entlst))
new_str (rm-returns str)
entlst (subst (cons 1 new_str) (assoc 1 entlst) entlst)
 )
 (entmod entlst)
); progn
(princ "\nThat wasn't MTEXT was it!!")
      ); if
    )
  )

  (princ)
)


[Jeff_M]

While Mark's removes hard returns in Mtext, I understood that Biscuit wanted to remove the auto word wrap when the text doesn't fit all on one line. The following does that.

Code: [Select]


(defun c:nowrap (/ doc ss)
  (vl-load-com)
  (setq doc (vla-get-activedocument (vlax-get-acad-object)))
  (if (ssget '((0 . "MTEXT")))
    (progn
      (setq ss (vla-get-activeselectionset doc))
      (vlax-for ent ss
(vla-put-width ent 0)
)
      )
    )
  (princ)
  )


[Biscuits]

Thank you. I really appreciate the effort but what I need to accomplish is to change the mtext width property to (no wrap) on existing mtext. I'm not code-literate enough to understand what your routine does, but it doesn't change this property value.

[daron]

Check out Jeff's code B.

[Biscuits]

Thankyou Jeff that hit the spot. You guys are awsome. The drinks are on me you guys. That is if you don't mind sunny beaches, white sands, an ocean breeze, etc...... Oh and little umbrellas in your drink, beach bunnies, more etc......

[daron]

Where you getting all these things being in Omaha? You dreamin' again? Wake up. Get back to work.

[Biscuits]

No man we have an olympic size ocean

[daron]

Oooh. With sand and all. Nice.

[CAB]

While Jeff solved Biscuit's problem I can use the NoReturns lisp, thanks Mark.

[Krushert]

While Jeff solved Biscuit's problem I can use the NoReturns lisp, thanks Mark.

Same here.  It will save me and a few others in my office from lynching a Knot-Head.   :pissed:

Hey Bar Tender, a round for Jeff and Mark. 

[CADaver]

ohh, like 'em both

[GDF]

Here is another one...

Code: [Select]

;;;srink mtext spacing
(defun c:FixMtext  (/ sset en el ymt nmt mtwidth mtcont)
  ;;requires ai_util.lsp
  (prompt "\n* Fix Mtext Spacing *")
  (setq sset (ai_aselect))
  (if (null sset)
    (progn (princ "\n* No objects selected *") (exit)))
  (setq COUNT 0)
  (setq ymt 0)
  (setq nmt 0)
  (if (/= sset nil)
    (setq EN (ssname sset COUNT))
    (setq EN nil))
  (WHILE (/= EN nil)
    (setq mtcont nil)
    (setq nel nil)
    (setq EL (entget EN))
    (if (= (cdr (assoc 0 EL)) "MTEXT")
      (progn (setq el (entget en '("ACAD")))
             (if (/= (assoc -3 el) nil)
               (progn (setq oheight (assoc 1040 (cdadr (assoc -3 el))))
                      (setq nheight (cons 1040 (cdr (assoc 43 el))))
                      (setq n-3
                             (list (cons -3 (list (subst nheight oheight (cadr (assoc -3 el)))))))
                      (setq el (vl-remove (assoc -3 el) el))
                      (setq el (append el n-3))))
             (entdel (cdr (assoc -1 el)))
             (entmake el)
             (setq COUNT (1+ COUNT))
             (setq EN (SSNAME sset COUNT))
             (setq ymt (1+ ymt)))
      (progn (setq COUNT (1+ COUNT))
             (setq EN (SSNAME sset COUNT))
             (setq nmt (1+ nmt)))))
  (prompt (strcat "\n*"
                  (itoa ymt)
                  " Mtext object(s) were resized, and "
                  (itoa nmt)
                  " object(s) were not Mtext. *"))
  (princ))

Gary

[Krushert]

Okay this blast returns is finicky.  I have a bunch of Mtext in a drawing with hard returns.  The routine only works on about 70% of the Mtext.  The routine is not crashing; it is just not removing the returns.  I turn on the variable watch.  The thing I notice is that it is only looking at the last line text in the Mtext.  I have posted the watch logs below.

From successful runs of the routine.

Code: [Select]


LOG Watch
...............
NEW_STR = "{\\LTYPICAL EXTERIOR WALL ASSEMBLY @ ROOF. }EPDM ROOFING MEMBRANE EXTENDED FULL HEIGHT OF WALL AND ATTACHED & FLASHED TO EXISTING ROOF SYSTEM. 5/8\" APA RATED PLYWOOD SHEATHING. 2x6 WOOD STUDS @ 16\" O.C. W/ CONTINUOUS R19 BATT INSULATION."
STR = "{\\LTYPICAL EXTERIOR WALL ASSEMBLY @ ROOF.\\P}EPDM ROOFING MEMBRANE EXTENDED FULL HEIGHT OF WALL AND ATTACHED & FLASHED TO EXISTING ROOF SYSTEM.\\P5/8\" APA RATED PLYWOOD SHEATHING.\\P2x6 WOOD STUDS @ 16\" O.C. W/ CONTINUOUS R19 BATT INSULATION."
ENTLST = ((-1 . <Entity name: 7e9fca58>) (0 . "MTEXT") (330 . <Entity name: 7efdfcf8>) (5 . "1ACD3") (100 . "AcDbEntity") (67 . 0) (410 . "Model") (8 . "NOTES-N") (100 . "AcDbMText") (10 -175.517 1427.24 0.0) (40 . 3.3) (41 . 157.767) ... )
ENT = <Entity name: 7e9fca58>
...............
...............
LOG Watch
...............
NEW_STR = "{\\LEXTERIOR WALL ASSEMBLY @ ELEVATOR SHAFT: }CEDAR SHINGLES. 15# ASPHALT IMPREGNATED FELT PAPER 5/8\" APA RATED SHEATHING 2x6 WOODS STUDS @ 16\" O.C. WITH R19 BATT INSULATION. 6 MIL POLY VAPOR BARRIER 5/8\" TYPE \"X\" GWB"
STR = "{\\LEXTERIOR WALL ASSEMBLY @ ELEVATOR SHAFT:\\P}CEDAR SHINGLES.\\P15# ASPHALT IMPREGNATED FELT PAPER\\P5/8\" APA RATED SHEATHING\\P2x6 WOODS STUDS @ 16\" O.C. WITH R19 BATT INSULATION.\\P6 MIL POLY VAPOR BARRIER\\P5/8\" TYPE \"X\" GWB"
ENTLST = ((-1 . <Entity name: 7e9fce18>) (0 . "MTEXT") (330 . <Entity name: 7efdfcf8>) (5 . "1AD8B") (100 . "AcDbEntity") (67 . 0) (410 . "Model") (8 . "NOTES-N") (100 . "AcDbMText") (10 49.8375 1270.38 0.0) (40 . 3.3) (41 . 191.933) ... )
ENT = <Entity name: 7e9fce18>
[/size]



From unsuccessful runs of the routine.

Code: [Select]

...............
LOG Watch
...............
NEW_STR = "B SEPERATED BY 1/2\" RESILIENT CHANNEL."
STR = "B SEPERATED BY 1/2\" RESILIENT CHANNEL."
ENTLST = ((-1 . <Entity name: 7e9fc9a8>) (0 . "MTEXT") (330 . <Entity name: 7efdfcf8>) (5 . "1ACAD") (100 . "AcDbEntity") (67 . 0) (410 . "Model") (8 . "NOTES-N") (100 . "AcDbMText") (10 26.1596 1435.93 0.0) (40 . 3.3) (41 . 171.301) ... )
ENT = <Entity name: 7e9fc9a8>
...............
...............
LOG Watch
...............
NEW_STR = ") LAYERS OF 5/8\" TYPE \"X\" GWB SEPERATED BY 1/2\" RESILIENT CHANNEL."
STR = ") LAYERS OF 5/8\" TYPE \"X\" GWB SEPERATED BY 1/2\" RESILIENT CHANNEL."
ENTLST = ((-1 . <Entity name: 7e9fce60>) (0 . "MTEXT") (330 . <Entity name: 7efdfcf8>) (5 . "1AD94") (100 . "AcDbEntity") (67 . 0) (410 . "Model") (8 . "NOTES-N") (100 . "AcDbMText") (10 49.8375 1102.25 0.0) (40 . 3.3) (41 . 123.527) ... )
ENT = <Entity name: 7e9fce60>
...............

BY the way i had a hard time resizing the code text to fit.  Oh well I tried.

[T.Willey]

The problem with Mtext, and dxf codes is that if the string is too long, then you need to check if it has a dxf code of 3 (for continueing the string).  I would reccomend that you use the ActiveX properties to get the text string.
Example using what Mark posted.

Code: [Select]

(defun c:blastReturns (/ rm-returns ent entlst str new_str TxtObj)

 (defun rm-returns (str)
   (while (wcmatch str "*\\P*")
     (setq str (vl-string-subst " " "\\P" str))
   )
   str
 )

 (if (setq ent (car (entsel "\nSelect MTEXT: ")))
   (progn

     (setq entlst  (entget ent)
;   str    (cdr (assoc 1 entlst))
   str (vla-get-TextString (setq TxtObj (vlax-ename->vla-object Ent)))
   new_str (rm-returns str)
     )

;     (setq entlst
;    (subst (cons 1 new_str) (assoc 1 entlst) entlst)
;     )
;     (entmod entlst)
    (vla-put-TextString TxtObj new_str)
   )
 )

 (princ)
)


[Krushert]

.....
     (setq entlst  (entget ent)
;   str    (cdr (assoc 1 entlst))
   str (vla-get-TextString (setq TxtObj (vlax-ename->vla-object Ent)))
   new_str (rm-returns str)
     )

;     (setq entlst
;    (subst (cons 1 new_str) (assoc 1 entlst) entlst)
;     )
;     (entmod entlst)
.......

It works, though I had to remove the Semi-Colans that you had place in the code. 
It as crashing @  line that contain the code [ "new_str (rm-returns str) ]
Don't ask me why    but it works.
Thanks

[T.Willey]

Weird, but as long as you got it working.
You're welcome for the little I did, it's still Mark's code.

[Krushert]

You're welcome for the little I did, it's still Mark's code.

Thanks to all of you.  Everytime I am come here I learn something.  And thanks for some of the cool routines too. :kewl: